FXApp/ws_objects/l1_uo.pbl.src/uo_getbar.sru

$PBExportHeader$uo_getbar.sru
forward
global type uo_getbar from nonvisualobject
end type
end forward

global type uo_getbar from nonvisualobject
end type
global uo_getbar uo_getbar

type variables
Long uo_getbarid
String uo_getbarcode


end variables

forward prototypes
public function integer updatebegin (long arg_getbarid, ref string arg_msg)
public function integer p_change_barcode (long arg_getbarid, boolean arg_ifcommit, ref string arg_msg)
public function integer p_c_change_barcode (long arg_getbarid, boolean arg_ifcommit, ref string arg_msg)
public function integer p_getinfo (long arg_getbarid, ref s_getbar arg_s_gb, ref string arg_msg)
public function integer auditing (long arg_getbarid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
public function integer save (s_getbar arg_s_gb, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
public function integer uof_barcode_inuse (string arg_barcode, integer arg_isuse, boolean arg_ifcommit, ref string arg_msg)
public function integer uof_barcode_out (string arg_barcode, integer arg_outflag, boolean arg_ifcommit, ref string arg_msg)
public function integer uof_barcode_mtrlwareid (string arg_barcode, long arg_scid, long arg_mtrlwareid, boolean arg_ifcommit, ref string arg_msg)
public function integer getinfo (long arg_getbarid, ref s_mtrlware_mx arg_gbmx[], ref string arg_msg)
public function integer add_dscrp (long arg_getbarid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit)
public function integer mod_dscrp (long arg_getbarid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit)
public function integer del (long arg_getbarid, ref string arg_msg, boolean arg_ifcommit)
public function integer c_auditing (long arg_getbarid, boolean arg_ifauto, ref string arg_msg, boolean arg_ifcommit)
public function integer uof_barcode_in (string arg_barcode, long arg_scid, long arg_mtrlwareid, string arg_relbillcode, long arg_relbillid, long arg_relprintid, integer arg_inflag, integer arg_ifth, boolean arg_ifcommit, ref string arg_msg)
public function integer uof_barcode_fp (string arg_barcode, string arg_relbillcode, long arg_relbillid, long arg_relprintid, ref string arg_msg, boolean arg_ifcommit)
public function integer mod_dscrp2 (long arg_getbarid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit)
end prototypes

public function integer updatebegin (long arg_getbarid, ref string arg_msg);Int rslt = 1
Long cnt = 0
s_getbar arg_s_gb

IF arg_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误条码生成单唯一码'
	GOTO ext
END IF

IF p_getinfo(arg_getbarid,arg_s_gb,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF arg_s_gb.flag = 1 THEN
	rslt = 0
	arg_msg = "条码生成单已经审核,操作取消"
	GOTO ext
END IF

//检查明细条码是否已被打印
cnt = 0
SELECT count(*) INTO :cnt
	FROM u_mtrlware_mx
	WHERE u_mtrlware_mx.getbarid = :arg_getbarid
	And u_mtrlware_mx.printnum > 0;
IF sqlca.SQLCode <> 0 THEN cnt = 0
IF cnt > 0 THEN
	arg_msg = '单据对应条码已打印,不能修改,请检查!'
	rslt = 0
	GOTO ext
END IF

//检查明细条码是否已被扫描
cnt = 0
SELECT count(*) INTO :cnt
	FROM u_getbar,u_mtrlware_mx
	WHERE u_getbar.getbarid = u_mtrlware_mx.getbarid
	AND u_getbar.getbarid = :arg_getbarid
	AND u_mtrlware_mx.barcode IN
	(SELECT barcode From U_inwaremx_mx_barcode);
IF sqlca.SQLCode <> 0 THEN cnt = 0

IF cnt > 0 THEN
	arg_msg = '单据对应条码已扫描进仓,不能修改,请检查!'
	rslt = 0
	GOTO ext
END IF

ext:

RETURN rslt


end function

public function integer p_change_barcode (long arg_getbarid, boolean arg_ifcommit, ref string arg_msg);Long cnt = 0,i
Int rslt = 1
//Long chc
//Long rst_outwareid //出仓id
//Long rst_inwareid //进仓id
//Long s_scid
//Long o_scid
//Long lay_storageid[]
//
//datetime server_dt
//SELECT Top 1 getdate() INTO :server_dt FROM u_user;
////取得系统时间,借用操作员表
//IF sqlca.SQLCode <> 0 THEN
//	rslt = 0
//	arg_msg = "查询操作失败,日期 "
//	GOTO ext
//END IF
//uo_inware uo_in
//uo_outware uo_out
//
//uo_in = CREATE uo_inware
//uo_in.commit_transaction = sqlca
//uo_in.if_getid_ture = FALSE
//
//uo_out = CREATE uo_outware
//uo_out.commit_transaction = sqlca
//uo_out.if_getid_ture = FALSE
//
//IF getbarid = 0 THEN
//	rslt = 0
//	arg_msg = "没有转换对象"
//	GOTO ext
//END IF
//
//if getinfo(arg_getbarid,arg_msg) = 0 then
//	rslt = 0
//	GOTO ext
//END IF
//
//IF it_newbegin OR it_updatebegin THEN
//	rslt = 0
//	arg_msg = "编辑状态下不可以执行审核"
//	GOTO ext
//END IF
//
//IF flag = 0 THEN
//	rslt = 0
//	arg_msg = "单据还未审核，不能进行转换！"
//	GOTO ext
//END IF
//
////1.原事务生成出仓单
//SELECT scid INTO :s_scid
//	FROM u_storage
//	Where storageid = :storageid;
//IF sqlca.SQLCode <> 0 THEN
//	arg_msg = '查询调出仓库所属分部资料失败'
//	rslt = 0
//	GOTO ext
//END IF
//	
//IF uo_out.newbegin(s_scid,8,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//
//uo_out.relid = getbarid
//uo_out.outdate = server_dt
//uo_out.outrep  = ''
//uo_out.part   = getbarcode
//uo_out.dscrp  = dscrp
//uo_out.cusname  = '条码转换出仓'
//uo_out.storageid  = storageid
//
//long ll_mtrlwareid
//SELECT mtrlwareid
//into :ll_mtrlwareid
//FROM u_mtrlware
//where  mtrlid = :mtrlid and
//      storageid = :storageid and 
//		plancode=:plancode and
//		Status=:status and 
//		woodcode=:woodcode and
//		pcode = :pcode and 
//		scid = :s_scid;
//IF sqlca.SQLCode <> 0 THEN
//	arg_msg = '查询库存唯一码失败》'+sqlca.sqlerrtext
//	rslt = 0
//	GOTO ext
//END IF
//
//IF uo_out.acceptmx(ll_mtrlwareid,&
//	qty,0,1,&
//	dscrp,1,arg_msg,0,0,0,0,0,'','',0) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//	
//IF uo_out.Save(FALSE,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//	
//rst_outwareid = uo_out.outwareid
//	
////2.原事务审核出仓单
//IF uo_out.getinfo(s_scid,rst_outwareid,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//	
//IF uo_out.auditing(FALSE,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//eND IF
//	
//SELECT scid INTO :o_scid
//	FROM u_storage
//	Where storageid = :storageid;
//IF sqlca.SQLCode <> 0 THEN
//	arg_msg = '查询调进仓库所属分部资料失败'
//	rslt = 0
//	GOTO ext
//END IF
//		
//IF uo_in.newbegin(o_scid,8,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//
//uo_in.relid = getbarid
//uo_in.indate = server_dt
//uo_in.inrep  = ''
//uo_in.part   = getbarcode
//uo_in.dscrp  = dscrp
//uo_in.storageid  = storageid
//uo_in.sptname = '条码包装转换进仓'
//		
//
//FOR i = 1 TO it_mxbt
//	IF uo_in.acceptmx(i,&
//		mtrlid,&
//		mtrlcode,&
//		getbarmx[i].barcode,&
//		status,&
//		1,&
//		0,&
//		1,&
//		getbarmx[i].dscrpmx,&
//		arg_msg,&
//		0,0,0,woodcode,pcode,0,'',1) = 0 THEN
//		rslt = 0
//		GOTO ext
//	END IF
//NEXT
//
//IF uo_in.Save(FALSE,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//		
//rst_inwareid = uo_in.inwareid
//		
////4.原事务审核进仓单
//IF uo_in.getinfo(o_scid,rst_inwareid,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//		
//IF uo_in.auditing(FALSE,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
//
//ext:
//IF rslt = 0 THEN
//	ROLLBACK;
//ELSEIF arg_ifcommit AND rslt = 1 THEN
//	COMMIT;
//END IF
//
//DESTROY uo_in
//DESTROY uo_out

RETURN rslt


end function

public function integer p_c_change_barcode (long arg_getbarid, boolean arg_ifcommit, ref string arg_msg);Long cnt = 0,i
Int rslt = 1
//Long chc
//Long in_out
//Long rst_outwareid[],out_i = 1 //出仓id
//Long rst_inwareid[],in_i = 1 //进仓id
//Long s_scid
//Long o_scid
//
//DateTime null_dt
//
//SetNull(null_dt)
//
//uo_inware uo_in
//uo_outware uo_out
//
//uo_in = CREATE uo_inware
//uo_in.commit_transaction = sqlca
//uo_in.if_getid_ture = FALSE
//
//uo_out = CREATE uo_outware
//uo_out.commit_transaction = sqlca
//uo_out.if_getid_ture = FALSE
//
//IF getbarid = 0 THEN
//	rslt = 0
//	arg_msg = "没有反转换单据"
//	GOTO ext
//END IF
//
//if getinfo(arg_getbarid,arg_msg) = 0 then
//	rslt = 0
//	GOTO ext
//END IF
//
//IF it_newbegin OR it_updatebegin THEN
//	rslt = 0
//	arg_msg = "编辑状态下不可以执行审核"
//	GOTO ext
//END IF
//
//IF flag = 0 THEN
//	rslt = 0
//	arg_msg = "单据未审核"
//	GOTO ext
//END IF
//
////1.查询单相关的出仓单,撤审,删除
//SELECT scid INTO :s_scid
//	FROM u_storage
//	Where storageid = :storageid;
//IF sqlca.SQLCode <> 0 THEN
//	arg_msg = '查询调出仓库所属分部资料失败'
//	rslt = 0
//	GOTO ext
//END IF
//	
//DECLARE cur_out_2 CURSOR FOR
//	SELECT outwareid
//	FROM u_outware
//WHERE scid = :s_scid
//AND relid = :getbarid
//AND billtype = 8;
//		
//OPEN cur_out_2;
//FETCH cur_out_2 INTO :rst_outwareid[out_i];
//DO WHILE sqlca.SQLCode = 0
//	out_i++
//	FETCH cur_out_2 INTO :rst_outwareid[out_i];
//LOOP
//out_i = out_i - 1
//CLOSE cur_out_2;
//	
//IF out_i = 0  THEN
//	arg_msg = '查询该转换单相关出仓单失败,'+sqlca.SQLErrText
//	rslt = 0
//	GOTO ext
//END IF
//	
//FOR in_out = 1 TO out_i
//	//撤审出仓单,再删除
//	IF uo_out.getinfo(s_scid,rst_outwareid[in_out],arg_msg) = 0 THEN
//		rslt = 0
//		GOTO ext
//	END IF
//		
//	IF uo_out.c_auditing(FALSE,arg_msg) = 0 THEN
//		rslt = 0
//		GOTO ext
//	END IF
//		
//	IF uo_out.del(s_scid,rst_outwareid[in_out],arg_msg,FALSE) = 0 THEN
//		rslt = 0
//		GOTO ext
//	END IF
//NEXT
//	
//SELECT scid INTO :o_scid
//	FROM u_storage
//	Where storageid = :storageid;
//IF sqlca.SQLCode <> 0 THEN
//	arg_msg = '查询调出仓库所属分部资料失败'
//	rslt = 0
//	GOTO ext
//END IF
//		
//DECLARE cur_in_2 CURSOR FOR
//	SELECT inwareid
//	FROM u_inware
//	WHERE scid = :o_scid
//	AND relid = :getbarid
//	AND billtype = 8;
//			
//OPEN cur_in_2;
//FETCH cur_in_2 INTO :rst_inwareid[in_i];
//DO WHILE sqlca.SQLCode = 0
//	in_i++
//	FETCH cur_in_2 INTO :rst_inwareid[in_i];
//LOOP
//in_i = in_i - 1
//CLOSE cur_in_2;
//		
//IF in_i = 0  THEN
//	arg_msg = '查询该转换单相关入仓单失败,'+sqlca.SQLErrText
//	rslt = 0
//	GOTO ext
//END IF
//		
//FOR in_out = 1 TO in_i
//	//撤审入仓单,再删除
//	IF uo_in.getinfo(o_scid,rst_inwareid[in_out],arg_msg) = 0 THEN
//		rslt = 0
//		GOTO ext
//	END IF
//			
//	IF uo_in.c_auditing(FALSE,arg_msg) = 0 THEN
//		rslt = 0
//		GOTO ext
//	END IF
//			
//	IF uo_in.del(o_scid,rst_inwareid[in_out],arg_msg,FALSE) = 0 THEN
//		rslt = 0
//		GOTO ext
//	END IF
//NEXT
//
//ext:
//
//IF rslt = 0 THEN
//	ROLLBACK;
//ELSEIF arg_ifcommit AND rslt = 1 THEN
//	COMMIT;
//END IF
//
//DESTROY uo_in
//DESTROY uo_out

RETURN rslt


end function

public function integer p_getinfo (long arg_getbarid, ref s_getbar arg_s_gb, ref string arg_msg);Int rslt = 1

SELECT u_getbar.getbarcode,
	u_getbar.mtrlid,
	u_getbar.status,
	u_getbar.plancode,
	u_getbar.woodcode,
	u_getbar.pcode,
	u_getbar.qty,
	u_getbar.ifrel,
	u_getbar.orderid,
	u_getbar.dscrp,
	u_getbar.mtrlcuscode,
	u_getbar.location,
	u_getbar.flag,
	u_getbar.getbardate,
	u_getbar.storageid,
	u_getbar.cusid,
	u_mtrldef.mtrlcode,
	u_mtrldef.unit,
	u_getbar.relbillid,
	u_getbar.scid
	INTO :arg_s_gb.getbarcode,
	:arg_s_gb.mtrlid,
	:arg_s_gb.status,
	:arg_s_gb.plancode,
	:arg_s_gb.woodcode,
	:arg_s_gb.pcode,
	:arg_s_gb.qty,
	:arg_s_gb.ifrel,
	:arg_s_gb.orderid,
	:arg_s_gb.dscrp,
	:arg_s_gb.mtrlcuscode,
	:arg_s_gb.location,
	:arg_s_gb.flag,
	:arg_s_gb.getbardate,
	:arg_s_gb.storageid,
	:arg_s_gb.cusid,
	:arg_s_gb.mtrlcode,
	:arg_s_gb.unit,
	:arg_s_gb.relbillid,
	:arg_s_gb.scid
	FROM u_getbar,u_mtrldef
	WHERE u_getbar.mtrlid = u_mtrldef.mtrlid AND
	u_getbar.getbarid = :arg_getbarid USING sqlca;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	ARG_MSG = '查询条码成生单内容失败(错误条码生成单唯一码)'+sqlca.SQLErrText
	GOTO ext
END IF

ext:
RETURN rslt



end function

public function integer auditing (long arg_getbarid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
Long j
s_getbar arg_s_gb
s_mtrlware_mx arg_s_gbmx[]


uo_inware_py uo_gb_py
uo_gb_py = Create uo_inware_py
uo_gb_py.commit_transaction = sqlca
uo_gb_py.if_getid_ture = False
uo_gb_py.if_py_check_barcode = False
uo_gb_py.if_py_update_barcode = True

uo_inware_buy uo_in_buy
uo_in_buy = Create uo_inware_buy
uo_in_buy.commit_transaction = sqlca


IF arg_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误条码生成单唯一码'
	GOTO ext
END IF

IF p_getinfo(arg_getbarid,arg_s_gb,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF getinfo(arg_getbarid,arg_s_gbmx,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF arg_s_gb.flag = 1 THEN
	rslt = 0
	arg_msg = "条码生成单已经审核,操作取消"
	GOTO ext
END IF

UPDATE u_getbar
	SET flag = 1,
	auditingrep = :arg_opemp,
	auditingdate = getdate()
	Where u_getbar.getbarid = :arg_getbarid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新条码生成单审核状态失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
ELSEIF sqlca.SQLNRows = 0 THEN
	rslt = 0
	arg_msg = '单据正在审核,请稍后重试'
	GOTO ext
END IF

IF arg_s_gb.ifrel = 7 THEN
	IF uo_gb_py.newbegin(arg_s_gb.scid,9,arg_msg) = 0 THEN
		arg_msg = 'error!/盘盈单'+arg_msg
		rslt = 0
		GOTO ext
	END IF
	
	uo_gb_py.indate = DateTime(Date(Today()),Time(0))
	uo_gb_py.inrep  = arg_opemp
	uo_gb_py.part   = arg_s_gb.getbarcode
	uo_gb_py.dscrp  = '条码单生成的'+arg_s_gb.getbarcode+'的盘盈单'
	uo_gb_py.storageid  = arg_s_gb.storageid
	uo_gb_py.relid = arg_getbarid
	
	IF uo_gb_py.acceptmx(1,&
		arg_s_gb.mtrlid,&
		arg_s_gb.mtrlcode,&
		arg_s_gb.plancode,&
		arg_s_gb.status,&
		0,&
		0,&
		1,&
		'',&
		arg_msg,0,0,0,&
		arg_s_gb.woodcode,&
		arg_s_gb.pcode,&
		arg_s_gb.cusid,&
		arg_s_gb.unit,&
		1,&
		0,&
		0,0,'','',0,0,&
		arg_s_gb.mtrlcuscode,&
		arg_s_gb.Location,&
		0,&
		0) = 0 THEN
		arg_msg = 'error!/盘盈单'+arg_msg
		rslt = 0
		GOTO ext
	END IF
	
	IF uo_gb_py.Save(False,arg_msg) = 0 THEN
		arg_msg = 'error!/盘盈单'+arg_msg
		rslt = 0
		GOTO ext
	END IF
	
	FOR j = 1 To UpperBound(arg_s_gbmx) - 1
		IF uo_gb_py.uof_inbarcode_add(9,arg_s_gb.scid,uo_gb_py.inwareid,0,&
			arg_s_gbmx[j].barcode,arg_s_gbmx[j].qty,arg_msg,False) = 0 THEN
			arg_msg = 'error!/盘盈单'+arg_msg
			rslt = 0
			GOTO ext
		END IF
	NEXT
	
	IF uo_gb_py.getinfo(arg_s_gb.scid,uo_gb_py.inwareid,arg_msg) = 0 THEN
		arg_msg = 'error!/盘盈单'+arg_msg
		rslt = 0
		GOTO ext
	END IF
	
	IF uo_gb_py.auditing(False,arg_msg) = 0 THEN
		arg_msg = 'error!/盘盈单'+arg_msg
		rslt = 0
		GOTO ext
	END IF
ELSEIF arg_s_gb.ifrel = 8 THEN
	FOR j = 1 To UpperBound(arg_s_gbmx) - 1
		IF uo_in_buy.uof_inbarcode_add(1,arg_s_gb.scid,arg_s_gb.orderid,0,&
			arg_s_gbmx[j].barcode,arg_s_gbmx[j].qty,arg_msg,False) = 0 THEN
			arg_msg = 'error!/采购收货单'+arg_msg
			rslt = 0
			GOTO ext
		END IF
	NEXT
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 And arg_ifcommit THEN
	COMMIT;
END IF

Destroy uo_gb_py
Destroy uo_in_buy

RETURN rslt










end function

public function integer save (s_getbar arg_s_gb, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);Integer rslt = 1
Int li_ifpackpro,li_ifpackpro_uc,li_ifpack_uc
Decimal ld_Sonscale
Long cnt = 0,i
DateTime server_dt
Long ll_newid,ll_it_mxbt,ll_mtrlid_buytask
String ls_sccode,ls_getbarcode
Decimal ld_sum_mxqty,ld_otherqty,ld_orderqty

IF IsNull(arg_s_gb.scid) THEN arg_s_gb.scid = 0
IF IsNull(arg_s_gb.getbarid) THEN arg_s_gb.getbarid = 0
IF IsNull(arg_s_gb.ifrel) THEN arg_s_gb.ifrel = 0
IF IsNull(arg_s_gb.orderid) THEN arg_s_gb.orderid = 0
IF IsNull(arg_s_gb.storageid) THEN arg_s_gb.storageid = 0
IF IsNull(arg_s_gb.mtrlid) THEN arg_s_gb.mtrlid = 0
IF IsNull(arg_s_gb.cusid) THEN arg_s_gb.cusid = 0
IF IsNull(arg_s_gb.plancode) THEN arg_s_gb.plancode = ''
IF IsNull(arg_s_gb.status) THEN arg_s_gb.status = ''
IF IsNull(arg_s_gb.woodcode) THEN arg_s_gb.woodcode = ''
IF IsNull(arg_s_gb.pcode) THEN arg_s_gb.pcode = ''
IF IsNull(arg_s_gb.mtrlcuscode) THEN arg_s_gb.mtrlcuscode = ''
IF IsNull(arg_s_gb.Location) THEN arg_s_gb.Location = ''
IF IsNull(arg_s_gb.qty) THEN arg_s_gb.qty = 0
IF IsNull(arg_s_gb.dscrp) THEN arg_s_gb.dscrp = ''
IF IsNull(arg_s_gb.dscrp2) THEN arg_s_gb.dscrp2 = ''
IF IsNull(arg_s_gb.reason) THEN arg_s_gb.reason = ''

IF IsNull(arg_s_gb.relbillid) THEN arg_s_gb.relbillid = 0
IF IsNull(arg_s_gb.relbillprintid) THEN arg_s_gb.relbillprintid = 0

IF IsNull(arg_s_gb.uqty) THEN arg_s_gb.uqty = 0
IF IsNull(arg_s_gb.packuqty) THEN arg_s_gb.packuqty = 0
IF IsNull(arg_s_gb.rate) THEN arg_s_gb.rate = 0


SELECT Top 1 getdate() Into :server_dt From u_user;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	GOTO ext
END IF

//检查物料
IF arg_s_gb.mtrlid = 0 THEN
	arg_msg = '请选择物料'
	rslt = 0
	GOTO ext
ELSE
	SELECT ifpackpro,ifpack INTO :li_ifpackpro_uc,:li_ifpack_uc
		FROM u_mtrldef
		Where mtrlid = :arg_s_gb.mtrlid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询物料资料是否包件产品失败,请检查物料资料,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	IF li_ifpackpro_uc = 1 THEN
		arg_msg = '通用包件产品不能开条码生成单,请检查物料资料'
		rslt = 0
		GOTO ext
	END IF
	
	IF li_ifpackpro_uc = 2 THEN
		arg_msg = "物料为个性包件产品,不能开条码生成单,请检查"
		rslt = 0
		GOTO ext
	END IF
	
	IF li_ifpack_uc = 2 And Trim(arg_s_gb.mtrlcuscode) = '' THEN
		arg_msg = "物料为个性包件,但没有产品批号,请检查"
		rslt = 0
		GOTO ext
	END IF
	
	IF li_ifpackpro_uc = 4 And Trim(arg_s_gb.mtrlcuscode) = '' THEN
		arg_msg = "物料为组合配置整排散进包件产品,但没有产品批号,请检查"
		rslt = 0
		GOTO ext
	END IF
END IF

//检查仓库
IF arg_s_gb.storageid = 0 THEN
	arg_msg = '请选择仓库'
	rslt = 0
	GOTO ext
ELSE
	cnt = 0
	SELECT count(*) INTO :cnt
		FROM u_storage
		Where storageid = :arg_s_gb.storageid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询仓库资料失败,请检查仓库资料'
		rslt = 0
		GOTO ext
	END IF
	
	IF cnt = 0 THEN
		arg_msg = '仓库资料不存在,请检查'
		rslt = 0
		GOTO ext
	END IF
	
	IF cnt > 1 THEN
		arg_msg = '仓库资料重复,请检查'
		rslt = 0
		GOTO ext
	END IF
END IF

//检查指令
IF arg_s_gb.ifrel = 1 THEN
	IF arg_s_gb.orderid = 0 THEN
		arg_msg = '请选择计划'
		rslt = 0
		GOTO ext
	END IF
	
	SELECT orderqty - stopqty INTO :ld_orderqty
		FROM u_order_ml
		WHERE scid = :arg_s_gb.scid
		And orderid = :arg_s_gb.orderid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询指令数量失败,请检查指令资料,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	SELECT isnull(sum(u_mtrlware_mx.packqty * u_mtrlware_mx.qty),0)
		INTO :ld_otherqty
		FROM u_getbar INNER JOIN
		u_mtrlware_mx ON u_getbar.getbarid = u_mtrlware_mx.getbarid
		WHERE u_getbar.scid = :arg_s_gb.scid
		AND u_getbar.orderid = :arg_s_gb.orderid
		AND u_getbar.getbarid <> :arg_s_gb.getbarid
		AND u_getbar.ifrel = 1
		And u_mtrlware_mx.isuse = 1;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询相关指令其它已开单数失败,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	IF ld_otherqty + arg_s_gb.qty > ld_orderqty THEN
		arg_msg = '超指令开单,指令未安排数:' + String(ld_orderqty,'##,#0.##########') + ',已开单数:'+String(ld_otherqty,'##,#0.##########') + ',本次开单数:'+String(arg_s_gb.qty,'##,#0.##########')
		rslt = 0
		GOTO ext
	END IF
ELSEIF arg_s_gb.ifrel = 2 THEN
	cnt = 0
	SELECT count(*) INTO :cnt
		FROM u_getbar
		WHERE u_getbar.scid = :arg_s_gb.scid
		AND u_getbar.getbarid <> :arg_s_gb.getbarid
		And u_getbar.ifrel = 8;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询是否有使用<采购进仓|按采购收货单>的条码生成单失败,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	IF cnt > 0 THEN
		arg_msg = '系统有使用<采购进仓|按采购收货单>的条码生成单,不能使用本类型建立条码生成单'
		rslt = 0
		GOTO ext
	END IF
	
	IF arg_s_gb.orderid = 0 THEN
		arg_msg = '请选择采购订单'
		rslt = 0
		GOTO ext
	END IF
	
	SELECT u_buytaskmx.qty,u_mtrldef.ifpackpro,u_buytaskmx.mtrlid
		INTO :ld_orderqty,:li_ifpackpro,:ll_mtrlid_buytask
		FROM u_buytaskmx,u_mtrldef
		WHERE u_buytaskmx.mtrlid = u_mtrldef.mtrlid
		AND u_buytaskmx.scid = :arg_s_gb.scid
		AND u_buytaskmx.taskid = :arg_s_gb.orderid
		And u_buytaskmx.printid = :arg_s_gb.buytaskprintid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询订单数量失败,请检查订单资料,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	IF li_ifpackpro = 1 THEN
		SELECT u_PrdPF.Sonscale INTO :ld_Sonscale
			FROM u_PrdPF,u_mtrl_pf
			WHERE u_PrdPF.mtrlid = u_mtrl_pf.mtrlid
			AND u_PrdPF.pfcode = u_mtrl_pf.pfcode
			AND u_mtrl_pf.ifdft = 1
			AND u_PrdPF.mtrlid = :ll_mtrlid_buytask
			And u_PrdPF.sonmtrlid = :arg_s_gb.mtrlid;
		IF sqlca.SQLCode <> 0 THEN
			arg_msg = '查询相关订单包件明细组成数失败,'+sqlca.SQLErrText
			rslt = 0
			GOTO ext
		END IF
	ELSE
		ld_Sonscale = 1
	END IF
	
	ld_orderqty = ld_orderqty * ld_Sonscale
	
	SELECT isnull(sum(u_mtrlware_mx.packqty * u_mtrlware_mx.qty),0) INTO :ld_otherqty
		FROM u_getbar INNER JOIN
		u_mtrlware_mx ON u_getbar.getbarid = u_mtrlware_mx.getbarid
		WHERE u_getbar.scid = :arg_s_gb.scid
		AND u_getbar.orderid = :arg_s_gb.orderid
		AND u_getbar.buytaskprintid = :arg_s_gb.buytaskprintid
		AND u_getbar.mtrlid = :arg_s_gb.mtrlid
		AND u_getbar.getbarid <> :arg_s_gb.getbarid
		AND u_getbar.ifrel = 2
		And u_mtrlware_mx.isuse = 1;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询相关订单其它已开单数失败,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	IF ld_otherqty + arg_s_gb.qty > ld_orderqty THEN
		arg_msg = '超订单开单,订货数:' + String(ld_orderqty,'##,#0.##########') + ',已开单数:'+String(ld_otherqty,'##,#0.##########') + ',本次开单数:'+String(arg_s_gb.qty,'##,#0.##########')
		rslt = 0
		GOTO ext
	END IF
ELSEIF arg_s_gb.ifrel = 8 THEN
	cnt = 0
	SELECT count(*) INTO :cnt
		FROM u_getbar
		WHERE u_getbar.scid = :arg_s_gb.scid
		AND u_getbar.getbarid <> :arg_s_gb.getbarid
		And (u_getbar.ifrel = 2 Or u_getbar.ifrel = 3);
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询是否有使用<采购进仓|按采购订单>或<采购进仓|非采购订单>的条码生成单失败,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	IF cnt > 0 THEN
		arg_msg = '系统有使用<采购进仓|按采购订单>或<采购进仓|非采购订单>的条码生成单,不能使用本类型建立条码生成单'
		rslt = 0
		GOTO ext
	END IF
	
	IF arg_s_gb.orderid = 0 THEN
		arg_msg = '请选择采购收货单'
		rslt = 0
		GOTO ext
	END IF
	
	SELECT u_inwaremx_mx.qty
		INTO :ld_orderqty
		FROM u_inwaremx_mx
		WHERE u_inwaremx_mx.scid = :arg_s_gb.scid
		AND u_inwaremx_mx.inwareid = :arg_s_gb.orderid
		And u_inwaremx_mx.mxprintid = :arg_s_gb.buytaskprintid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询采购收货单包件明细数量失败,请检查采购收货单资料,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	SELECT isnull(sum(u_mtrlware_mx.packqty * u_mtrlware_mx.qty),0) INTO :ld_otherqty
		FROM u_getbar INNER JOIN
		u_mtrlware_mx ON u_getbar.getbarid = u_mtrlware_mx.getbarid
		WHERE u_getbar.scid = :arg_s_gb.scid
		AND u_getbar.orderid = :arg_s_gb.orderid
		AND u_getbar.buytaskprintid = :arg_s_gb.buytaskprintid
		AND u_getbar.getbarid <> :arg_s_gb.getbarid
		AND u_getbar.ifrel = 8
		And u_mtrlware_mx.isuse = 1;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询相关收货单其它已开单数失败,'+sqlca.SQLErrText
		rslt = 0
		GOTO ext
	END IF
	
	IF ld_otherqty + arg_s_gb.qty > ld_orderqty THEN
		arg_msg = '超收货单开单,收货数:' + String(ld_orderqty,'##,#0.##########') + ',已开单数:'+String(ld_otherqty,'##,#0.##########') + ',本次开单数:'+String(arg_s_gb.qty,'##,#0.##########')
		rslt = 0
		GOTO ext
	END IF
END IF

//检查客户
IF arg_s_gb.cusid > 0 THEN
	cnt = 0
	SELECT count(*) INTO :cnt
		FROM u_cust
		Where cusid = :arg_s_gb.cusid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询客户资料失败,请检查客户资料'
		rslt = 0
		GOTO ext
	END IF
	
	IF cnt = 0 THEN
		arg_msg = '客户资料不存在,请检查'
		rslt = 0
		GOTO ext
	END IF
	
	IF cnt > 1 THEN
		arg_msg = '客户资料重复,请检查'
		rslt = 0
		GOTO ext
	END IF
END IF

//检查数量
IF arg_s_gb.qty <= 0 THEN
	arg_msg = '错误的物料数量,请检查'
	rslt = 0
	GOTO ext
END IF


//检查明细
ll_it_mxbt = UpperBound(arg_s_gb.arg_s_mx)

IF ll_it_mxbt = 0 THEN
	rslt = 0
	arg_msg = "没有正确条码生成单明细内容"
	GOTO ext
END IF

FOR i = 1 To ll_it_mxbt
	IF Trim(arg_s_gb.arg_s_mx[i].barcode) = '' THEN
		arg_msg = '行:'+String(i)+',没有条码,请检查'
		rslt = 0
		GOTO ext
	END IF
	
	IF arg_s_gb.arg_s_mx[i].packqty <= 0 THEN
		arg_msg = '行:'+String(i)+',错误的包装基数,请检查'
		rslt = 0
		GOTO ext
	END IF
	
	
	IF arg_s_gb.arg_s_mx[i].qty <= 0 THEN
		arg_msg = '行:'+String(i)+',错误的条码数,请检查'
		rslt = 0
		GOTO ext
	END IF
	
	ld_sum_mxqty += arg_s_gb.arg_s_mx[i].packqty * arg_s_gb.arg_s_mx[i].qty
NEXT

IF ld_sum_mxqty <> arg_s_gb.qty THEN
	arg_msg = '单据数量:'+string(arg_s_gb.qty,'#,##0.00########')+',与明细数量:'+string(ld_sum_mxqty,'#,##0.00########')+',不相符,请检查'
	rslt = 0
	GOTO ext
END IF

IF arg_s_gb.getbarid = 0 THEN
	ll_newid = f_sys_scidentity(0,"u_getbar","getbarid",arg_msg,True,id_sqlca)
	IF ll_newid <= 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	IF f_get_sccode(arg_s_gb.scid,sqlca,ls_sccode,arg_msg) = 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	ls_getbarcode = getid(0,ls_sccode + "TM",Date(server_dt),False,sqlca) //取得新单据编号
	IF ls_getbarcode = "err" THEN
		rslt = 0
		arg_msg = "无法获取条码生成单编号"
		GOTO ext
	END IF
	
	INSERT INTO u_getbar(
		scid,
		getbarid,
		getbarcode,
		mtrlid,
		status,
		plancode,
		woodcode,
		pcode,
		qty,
		ifrel,
		orderid,
		dscrp,
		dscrp2,
		flag,
		opemp,
		opdate,
		getbardate,
		mtrlcuscode,
		location,
		storageid,
		cusid,
		reason,
		buytaskprintid,
		packqty,
		relbillid,
		relbillprintid,
		uqty,
		packuqty,
		rate)
		VALUES (
		:arg_s_gb.scid,
		:ll_newid,
		:ls_getbarcode,
		:arg_s_gb.mtrlid,
		:arg_s_gb.status,
		:arg_s_gb.plancode,
		:arg_s_gb.woodcode,
		:arg_s_gb.pcode,
		:arg_s_gb.qty,
		:arg_s_gb.ifrel,
		:arg_s_gb.orderid,
		:arg_s_gb.dscrp,
		:arg_s_gb.dscrp2,
		0,
		:arg_opemp,
		:server_dt,
		:arg_s_gb.getbardate,
		:arg_s_gb.mtrlcuscode,
		:arg_s_gb.location,
		:arg_s_gb.storageid,
		:arg_s_gb.cusid,
		:arg_s_gb.reason,
		:arg_s_gb.buytaskprintid,
		:arg_s_gb.packqty,
		:arg_s_gb.relbillid,
		:arg_s_gb.relbillprintid,
		:arg_s_gb.uqty,
		:arg_s_gb.packuqty,
		:arg_s_gb.rate);
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致插入操作失败>>"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	FOR i = 1 To ll_it_mxbt
		INSERT INTO u_mtrlware_mx
			(getbarid,
			barcode,
			mxdscrp,
			mxdscrp2,
			mxdscrp3,
			mxdscrp4,
			inflag,
			outflag,
			qty,
			packqty,
			isuse,
			scid,
			storageid,
			mtrlid,
			sptid,
			status,
			woodcode,
			pcode,
			plancode,
			mtrlcuscode,
			location,
			ifrel,
			orderid,
			buytaskprintid,
			packuqty,
			rate)
			VALUES (:ll_newid,
			:arg_s_gb.arg_s_mx[i].barcode,
			:arg_s_gb.arg_s_mx[i].mxdscrp,
			:arg_s_gb.arg_s_mx[i].mxdscrp2,
			:arg_s_gb.arg_s_mx[i].mxdscrp3,
			:arg_s_gb.arg_s_mx[i].mxdscrp4,
			0,
			0,
			:arg_s_gb.arg_s_mx[i].qty,
			:arg_s_gb.arg_s_mx[i].packqty,
			1,
			:arg_s_gb.scid,
			:arg_s_gb.storageid,
			:arg_s_gb.mtrlid,
			:arg_s_gb.cusid,
			:arg_s_gb.status,
			:arg_s_gb.woodcode,
			:arg_s_gb.pcode,
			:arg_s_gb.plancode,
			:arg_s_gb.mtrlcuscode,
			:arg_s_gb.Location,
			:arg_s_gb.ifrel,
			:arg_s_gb.orderid,
			:arg_s_gb.buytaskprintid,
			:arg_s_gb.arg_s_mx[i].packuqty,
			:arg_s_gb.arg_s_mx[i].rate) Using sqlca;
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = "因网络或其它原因导致插入明细操作失败"+"~n"+sqlca.SQLErrText
			GOTO ext
		END IF
	NEXT
	
	uo_getbarid = ll_newid
	uo_getbarcode = ls_getbarcode
ELSE
	UPDATE u_getbar
		SET mtrlid = :arg_s_gb.mtrlid,
		status = :arg_s_gb.status,
		plancode = :arg_s_gb.plancode,
		woodcode = :arg_s_gb.woodcode,
		pcode = :arg_s_gb.pcode,
		qty = :arg_s_gb.qty,
		ifrel = :arg_s_gb.ifrel,
		orderid = :arg_s_gb.orderid,
		dscrp = :arg_s_gb.dscrp,
		dscrp2 = :arg_s_gb.dscrp2,
		getbardate = :arg_s_gb.getbardate,
		mtrlcuscode = :arg_s_gb.mtrlcuscode,
		location = :arg_s_gb.location,
		storageid = :arg_s_gb.storageid,
		cusid = :arg_s_gb.cusid,
		reason = :arg_s_gb.reason,
		buytaskprintid = :arg_s_gb.buytaskprintid,
		packqty = :arg_s_gb.packqty,
		moddate = getdate(),
		Modemp = :arg_opemp,
		relbillid = :arg_s_gb.relbillid,
		relbillprintid = :arg_s_gb.relbillprintid,
		uqty = :arg_s_gb.uqty,
		packuqty = :arg_s_gb.packuqty,
		rate = :arg_s_gb.rate
		WHERE u_getbar.getbarid = :arg_s_gb.getbarid
		And flag = 0;
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致更新单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	ELSEIF sqlca.SQLNRows = 0 THEN
		arg_msg = '单据正在更新,请稍后重试'
		rslt = 0
		GOTO ext
	END IF
	
	//删除原有明细
	DELETE FROM u_mtrlware_mx
		Where u_mtrlware_mx.getbarid = :arg_s_gb.getbarid;
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "删除旧有明细操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	FOR i = 1 To ll_it_mxbt
		INSERT INTO u_mtrlware_mx
			(getbarid,
			barcode,
			mxdscrp,
			mxdscrp2,
			mxdscrp3,
			mxdscrp4,
			inflag,
			outflag,
			qty,
			packqty,
			isuse,
			scid,
			storageid,
			mtrlid,
			sptid,
			status,
			woodcode,
			pcode,
			plancode,
			mtrlcuscode,
			location,
			ifrel,
			orderid,
			buytaskprintid,
			packuqty,
			rate)
			VALUES (:arg_s_gb.getbarid,
			:arg_s_gb.arg_s_mx[i].barcode,
			:arg_s_gb.arg_s_mx[i].mxdscrp,
			:arg_s_gb.arg_s_mx[i].mxdscrp2,
			:arg_s_gb.arg_s_mx[i].mxdscrp3,
			:arg_s_gb.arg_s_mx[i].mxdscrp4,
			0,
			0,
			:arg_s_gb.arg_s_mx[i].qty,
			:arg_s_gb.arg_s_mx[i].packqty,
			1,
			:arg_s_gb.scid,
			:arg_s_gb.storageid,
			:arg_s_gb.mtrlid,
			:arg_s_gb.cusid,
			:arg_s_gb.status,
			:arg_s_gb.woodcode,
			:arg_s_gb.pcode,
			:arg_s_gb.plancode,
			:arg_s_gb.mtrlcuscode,
			:arg_s_gb.Location,
			:arg_s_gb.ifrel,
			:arg_s_gb.orderid,
			:arg_s_gb.buytaskprintid,
			:arg_s_gb.arg_s_mx[i].packuqty,
			:arg_s_gb.arg_s_mx[i].rate) Using sqlca;
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = "因网络或其它原因导致插入明细操作失败"+"~n"+sqlca.SQLErrText
			GOTO ext
		END IF
	NEXT
	
	uo_getbarid = arg_s_gb.getbarid
END IF


ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 And arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt















end function

public function integer uof_barcode_inuse (string arg_barcode, integer arg_isuse, boolean arg_ifcommit, ref string arg_msg);Int rslt = 1
Int li_isuse
Int li_inflag,li_outflag
Long ll_getbarid
Int li_flag

SELECT getbarid,
	isuse,
	inflag,
	outflag
	INTO :ll_getbarid,
	:li_isuse,
	:li_inflag,
	:li_outflag
	FROM u_mtrlware_mx
	Where barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码:'+arg_barcode+',状态失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF ll_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误的条形码单唯一码'
	GOTO ext
END IF

SELECT flag INTO :li_flag
	FROM u_getbar
	Where getbarid = :ll_getbarid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码单审核标记失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF li_flag = 0 THEN
	rslt = 0
	arg_msg = "条码单未审核,不能操作,请检查"
	GOTO ext
END IF

IF li_isuse = 0 AND arg_isuse = 0 THEN
	rslt = 0
	arg_msg = '条码:'+arg_barcode+',已经作废,请检查'
	GOTO ext
END IF

IF li_isuse = 1 AND arg_isuse = 1 THEN
	rslt = 0
	arg_msg = '条码:'+arg_barcode+',已经有效,不能取消作废,请检查'
	GOTO ext
END IF

IF li_inflag = 1 OR li_outflag = 1 THEN
	rslt = 0
	arg_msg = '操作失败,条码:'+arg_barcode+',已经进仓或出仓'
	GOTO  ext
END IF

UPDATE u_mtrlware_mx
	SET isuse = :arg_isuse
	Where barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '更新条码:'+arg_barcode+',状态操作失败,'+sqlca.SQLErrText
	GOTO  ext
END IF


ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 0 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt
end function

public function integer uof_barcode_out (string arg_barcode, integer arg_outflag, boolean arg_ifcommit, ref string arg_msg);Int rslt = 1
Int li_isuse
Int li_inflag,li_outflag
Long ll_getbarid
Int li_flag
Int li_outflag_update

SELECT getbarid,
	isuse,
	inflag,
	outflag
	INTO :ll_getbarid,
	:li_isuse,
	:li_inflag,
	:li_outflag
	FROM u_mtrlware_mx
	Where barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码:'+arg_barcode+',状态失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF ll_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误的条形码单唯一码'
	GOTO ext
END IF

SELECT flag INTO :li_flag
	FROM u_getbar
	Where getbarid = :ll_getbarid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码单审核标记失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF li_flag = 0 THEN
	rslt = 0
	arg_msg = "条码单未审核,不能操作,请检查"
	GOTO ext
END IF

IF li_isuse = 0 THEN
	rslt = 0
	arg_msg = '条码:'+arg_barcode+',已经作废,不能操作,请检查'
	GOTO ext
END IF


IF arg_outflag = 1 THEN
	IF li_inflag = 0 THEN
		rslt = 0
		arg_msg = '操作失败,条码:'+arg_barcode+',未进仓'
		GOTO  ext
	END IF
	
	IF li_inflag - li_outflag = 0 THEN
		rslt = 0
		arg_msg = '操作失败,条码:'+arg_barcode+',已经出仓'
		GOTO  ext
	END IF
	
	li_outflag_update = 1
ELSE
	IF li_inflag - li_outflag = 1 THEN
		rslt = 0
		arg_msg = '操作失败,条码:'+arg_barcode+',未出仓,不能取消出仓'
		GOTO  ext
	END IF
	
	li_outflag_update = -1
END IF

UPDATE u_mtrlware_mx
	SET outflag = outflag + :li_outflag_update
	Where barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '更新条码:'+arg_barcode+',出仓标记操作失败,'+sqlca.SQLErrText
	GOTO  ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 0 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt






end function

public function integer uof_barcode_mtrlwareid (string arg_barcode, long arg_scid, long arg_mtrlwareid, boolean arg_ifcommit, ref string arg_msg);Int rslt = 1
Int li_isuse
Int li_inflag,li_outflag
Long ll_getbarid
Int li_flag

SELECT getbarid,
	isuse,
	inflag,
	outflag
	INTO :ll_getbarid,
	:li_isuse,
	:li_inflag,
	:li_outflag
	FROM u_mtrlware_mx
	Where barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码:'+arg_barcode+',状态失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF ll_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误的条形码单唯一码'
	GOTO ext
END IF

SELECT flag INTO :li_flag
	FROM u_getbar
	Where getbarid = :ll_getbarid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码单审核标记失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF li_flag = 0 THEN
	rslt = 0
	arg_msg = "条码单未审核,不能操作,请检查"
	GOTO ext
END IF

IF li_isuse = 0 THEN
	rslt = 0
	arg_msg = '条码:'+arg_barcode+',已经作废,不能操作,请检查'
	GOTO ext
END IF

IF li_inflag = 0 THEN
	rslt = 0
	arg_msg = '操作失败,条码:'+arg_barcode+',未进仓,不能操作'
	GOTO  ext
END IF

IF li_inflag - li_outflag = 0 THEN
	rslt = 0
	arg_msg = '操作失败,条码:'+arg_barcode+',已经出仓,不能操作'
	GOTO  ext
END IF

UPDATE u_mtrlware_mx
	SET u_mtrlware_mx.scid = :arg_scid,
	u_mtrlware_mx.mtrlwareid = :arg_mtrlwareid,
	u_mtrlware_mx.storageid = u_mtrlware.storageid,
	u_mtrlware_mx.mtrlid = u_mtrlware.mtrlid,
	u_mtrlware_mx.sptid = u_mtrlware.sptid,
	u_mtrlware_mx.status = u_mtrlware.status,
	u_mtrlware_mx.woodcode = u_mtrlware.woodcode,
	u_mtrlware_mx.pcode = u_mtrlware.pcode,
	u_mtrlware_mx.plancode = u_mtrlware.plancode,
	u_mtrlware_mx.mtrlcuscode = u_mtrlware.mtrlcuscode,
	u_mtrlware_mx.location = u_mtrlware.location
	FROM u_mtrlware_mx,u_mtrlware
	WHERE u_mtrlware.scid = :arg_scid
	AND u_mtrlware.mtrlwareid = :arg_mtrlwareid
	And u_mtrlware_mx.barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '更新条码:'+arg_barcode+',库存信息操作失败,'+sqlca.SQLErrText
	GOTO  ext
END IF

//UPDATE u_mtrlware_mx
//	SET scid = :arg_scid,
//	mtrlwareid = :arg_mtrlwareid
//	Where barcode = :arg_barcode;
//IF sqlca.SQLCode <> 0 THEN
//	rslt = 0
//	arg_msg = '更新条码:'+arg_barcode+',进仓标记操作失败,'+sqlca.SQLErrText
//	GOTO  ext
//END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 0 And arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt









end function

public function integer getinfo (long arg_getbarid, ref s_mtrlware_mx arg_gbmx[], ref string arg_msg);Int rslt = 1
Long i = 1,NO_MXCHECK = 0

IF arg_getbarid <= 0 THEN
	rslt = 0
	ARG_MSG = '错误的条码生成单唯一码'
	GOTO ext
END IF

//用游标读取明细
DECLARE cur_getbarmx CURSOR FOR
	SELECT barcode,qty
	FROM u_mtrlware_mx
	WHERE u_mtrlware_mx.getbarid = :arg_getbarid
	Order By barcode;
	
OPEN cur_getbarmx;
FETCH cur_getbarmx Into :arg_gbmx[i].barcode,:arg_gbmx[i].qty;
DO WHILE SQLCA.SQLCode = 0
	i++
	FETCH cur_getbarmx Into :arg_gbmx[i].barcode,:arg_gbmx[i].qty;
LOOP
CLOSE cur_getbarmx;

//检验明细是否读入完整
SELECT COUNT(*) INTO :NO_MXCHECK
	FROM u_mtrlware_mx
	Where u_mtrlware_mx.getbarid = :arg_getbarid;
IF SQLCA.SQLCode <> 0 THEN
	rslt = 0
	ARG_MSG = "查询操作失败,条码生成单明细数量"
	GOTO ext
END IF

IF i <> (NO_MXCHECK+1) THEN
	rslt = 0
	ARG_MSG = "查询操作失败,条码生成单明细数量不相符"
	GOTO ext
END IF

ext:

RETURN rslt




end function

public function integer add_dscrp (long arg_getbarid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
s_getbar arg_s_gb

IF arg_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误条码生成单唯一码'
	GOTO ext
END IF

IF arg_newdescppart = '' THEN
	rslt = 0
	arG_MSG = "要添加内容为空,操作取消"
	GOTO ext
END IF

IF p_getinfo(arg_getbarid,arg_s_gb,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF arg_s_gb.flag = 0 THEN
	rslt = 0
	arg_msg = "条码生成单未审核,操作取消"
	GOTO ext
END IF

UPDATE u_getbar
	SET DSCRP = DSCRP+' '+:arg_newdescppart
	WHERE getbarid = :arg_getbarid;
IF SQLCA.SQLCode <> 0 THEN
	rslt = 0
	arG_MSG = "因网络或其它原因导致添加备注操作失败"+"~n"+SQLCA.SQLErrText
	GOTO ext
END IF

ext:

IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

Return (rslt)

end function

public function integer mod_dscrp (long arg_getbarid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
s_getbar arg_s_gb

IF arg_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误条码生成单唯一码'
	GOTO ext
END IF

IF arg_newdescppart = '' THEN
	rslt = 0
	arG_MSG = "备注内容为空,操作取消"
	GOTO ext
END IF

IF p_getinfo(arg_getbarid,arg_s_gb,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF arg_s_gb.flag = 0 THEN
	rslt = 0
	arg_msg = "条码生成单未审核,操作取消"
	GOTO ext
END IF

UPDATE u_getbar
	SET DSCRP = :arg_newdescppart
	WHERE getbarid = :arg_getbarid;
IF SQLCA.SQLCode <> 0 THEN
	rslt = 0
	arG_MSG = "因网络或其它原因导致添加备注操作失败"+"~n"+SQLCA.SQLErrText
	GOTO ext
END IF

ext:

IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

Return (rslt)

end function

public function integer del (long arg_getbarid, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
Long cnt = 0
s_getbar arg_s_gb

IF arg_getbarid <= 0 THEN
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	GOTO ext
END IF

IF p_getinfo(arg_getbarid,arg_s_gb,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF arg_s_gb.flag = 1 THEN
	rslt = 0
	arg_msg = "条码生成单已经审核,操作取消"
	GOTO ext
END IF

//检查明细条码是否已被打印
cnt = 0
SELECT count(*) INTO :cnt
	FROM u_mtrlware_mx
	WHERE u_mtrlware_mx.getbarid = :arg_getbarid
	And u_mtrlware_mx.printnum > 0;
IF sqlca.SQLCode <> 0 THEN cnt = 0
IF cnt > 0 THEN
	arg_msg = '单据对应条码已打印,不能删除,请检查!'
	rslt = 0
	GOTO ext
END IF

//检查明细条码是否已被扫描
cnt = 0
SELECT count(*) INTO :cnt
	FROM u_getbar,u_mtrlware_mx
	WHERE u_getbar.getbarid = u_mtrlware_mx.getbarid
	AND u_getbar.getbarid = :arg_getbarid
	AND u_mtrlware_mx.barcode IN
	(SELECT barcode From U_inwaremx_mx_barcode);
IF sqlca.SQLCode <> 0 THEN cnt = 0

IF cnt > 0 THEN
	arg_msg = '单据对应条码已扫描进仓,不能删除,请检查!'
	rslt = 0
	GOTO ext
END IF

DELETE From u_mtrlware_mx Where u_mtrlware_mx.getbarid = :arg_getbarid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除条码生成单明细操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

DELETE From u_getbar Where u_getbar.getbarid = :arg_getbarid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除条码生成单操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 and arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt
end function

public function integer c_auditing (long arg_getbarid, boolean arg_ifauto, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
Long cnt = 0,j
DateTime null_dt
SetNull(null_dt)
s_getbar arg_s_gb
s_mtrlware_mx arg_s_gbmx[]

uo_inware_py uo_gb_py
uo_gb_py = Create uo_inware_py
uo_gb_py.commit_transaction = sqlca
uo_gb_py.if_getid_ture = False
uo_gb_py.if_py_check_barcode = False
uo_gb_py.if_py_update_barcode = True

If arg_getbarid <= 0 Then
	rslt = 0
	arg_msg = '错误条码生成单唯一码'
	Goto ext
End If

If p_getinfo(arg_getbarid,arg_s_gb,arg_msg) = 0 Then
	rslt = 0
	Goto ext
End If

If arg_s_gb.flag = 0 Then
	rslt = 0
	arg_msg = "条码生成单还未审核,操作取消"
	Goto ext
End If

If arg_ifauto = False Then
	If arg_s_gb.relbillid > 0 Then
		rslt = 0
		arg_msg = '生产计划包件变更单生成的单据,不能撤审,如需要操作请到生产计划包件变更单处理'
		Goto ext
	End If
End If

If getinfo(arg_getbarid,arg_s_gbmx,arg_msg) = 0 Then
	rslt = 0
	Goto ext
End If

Long ll_scid,ll_inwareid
If arg_s_gb.ifrel = 7 Then
	Select scid,inwareid
		Into :ll_scid,:ll_inwareid
		From u_inware
		Where u_inware.billtype = 9
		And u_inware.part = :arg_s_gb.getbarcode;
	If sqlca.SQLCode = -1 Then
		arg_msg = '查询相关盘盈单失败,'+sqlca.SQLErrText
		rslt = 0
		Goto ext
	ElseIf sqlca.SQLCode = 100 Then
		ll_inwareid = 0
	End If
	
	If ll_inwareid > 0 Then
		If uo_gb_py.getinfo(ll_scid,ll_inwareid,arg_msg) = 0 Then
			arg_msg = 'error!/盘盈单'+arg_msg
			rslt = 0
			Goto ext
		End If
		
		If uo_gb_py.c_auditing(False,arg_msg) = 0 Then
			arg_msg = 'error!/盘盈单'+arg_msg
			rslt = 0
			Goto ext
		End If
		
		If uo_gb_py.del(ll_scid,ll_inwareid,arg_msg,False) = 0 Then
			arg_msg = 'error!/盘盈单'+arg_msg
			rslt = 0
			Goto ext
		End If
	End If
End If

cnt = 0
Select count(*)
	Into :cnt
	From u_mtrlware_mx
	Where u_mtrlware_mx.getbarid = :arg_getbarid
	And u_mtrlware_mx.isuse = 0;
If sqlca.SQLCode <> 0 Then
	rslt = 0
	arg_msg = '查询操作失败,单据明细是否有作废条码,'+sqlca.SQLErrText
	Goto ext
End If

If cnt > 0 Then
	rslt = 0
	arg_msg = '单据已有作废条码,不能撤审'
	Goto ext
End If

cnt = 0
Select count(*)
	Into :cnt
	From u_mtrlware_mx
	Where u_mtrlware_mx.getbarid = :arg_getbarid
	And u_mtrlware_mx.inflag = 1;
If sqlca.SQLCode <> 0 Then
	rslt = 0
	arg_msg = '查询操作失败!单据明细是否有条码已进仓,'+sqlca.SQLErrText
	Goto ext
End If

If cnt > 0 Then
	rslt = 0
	arg_msg = '已有部分条码进仓,不能撤审'
	Goto ext
End If

//检查明细条码是否已被打印
cnt = 0
Select count(*) Into :cnt
	From u_mtrlware_mx
	Where u_mtrlware_mx.getbarid = :arg_getbarid
	And u_mtrlware_mx.printnum > 0;
If sqlca.SQLCode <> 0 Then cnt = 0
If cnt > 0 Then
	arg_msg = '单据对应条码已打印,不能撤审,请检查!'
	rslt = 0
	Goto ext
End If

If arg_s_gb.ifrel = 8 Then
	For j = 1 To UpperBound(arg_s_gbmx) - 1
		Delete From U_inwaremx_mx_barcode
			Where U_inwaremx_mx_barcode.scid = :arg_s_gb.scid
			And U_inwaremx_mx_barcode.inwareid = :arg_s_gb.orderid
			And U_inwaremx_mx_barcode.barcode = :arg_s_gbmx[j].barcode
			And U_inwaremx_mx_barcode.billtype = 1;
		If sqlca.SQLCode <> 0 Then
			arg_msg = '删除采购收货单条码明细失败,条码:'+arg_s_gbmx[j].barcode+','+sqlca.SQLErrText
			rslt = 0
			Goto ext
		End If
	Next
End If

//检查明细条码是否已被扫描
cnt = 0
Select count(*) Into :cnt
	From u_getbar,u_mtrlware_mx
	Where u_getbar.getbarid = u_mtrlware_mx.getbarid
	And u_getbar.getbarid = :arg_getbarid
	And u_mtrlware_mx.barcode In
	(Select barcode From U_inwaremx_mx_barcode);
If sqlca.SQLCode <> 0 Then cnt = 0

If cnt > 0 Then
	arg_msg = '单据对应条码已扫描进仓,不能修改,请检查!'
	rslt = 0
	Goto ext
End If

Update u_getbar
	Set flag = 0 ,
	auditingrep = '',
	auditingdate = :null_dt
	Where u_getbar.getbarid = :arg_getbarid
	And u_getbar.flag = 1 ;
If sqlca.SQLCode <> 0 Then
	rslt = 0
	arg_msg = '更新条码生成单状态失败,原因:'+sqlca.SQLErrText
	Goto ext
ElseIf sqlca.SQLNRows = 0 Then
	rslt = 0
	arg_msg = '单据正在撤审,请稍后重试'
	Goto ext
End If



ext:
If rslt = 0 Then
	Rollback;
ElseIf  rslt = 1 And arg_ifcommit Then
	Commit;
End If

Destroy uo_gb_py


Return rslt


























end function

public function integer uof_barcode_in (string arg_barcode, long arg_scid, long arg_mtrlwareid, string arg_relbillcode, long arg_relbillid, long arg_relprintid, integer arg_inflag, integer arg_ifth, boolean arg_ifcommit, ref string arg_msg);Int rslt = 1
Int li_isuse
Int li_inflag,li_outflag
Long ll_getbarid
Int li_flag
Int li_inflag_update,li_outflag_update

SELECT getbarid,
	isuse,
	inflag,
	outflag
	INTO :ll_getbarid,
	:li_isuse,
	:li_inflag,
	:li_outflag
	FROM u_mtrlware_mx
	Where barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码:'+arg_barcode+',状态失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF ll_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误的条形码单唯一码'
	GOTO ext
END IF

SELECT flag INTO :li_flag
	FROM u_getbar
	Where getbarid = :ll_getbarid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询条码单审核标记失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF li_flag = 0 THEN
	rslt = 0
	arg_msg = "条码单未审核,不能操作,请检查"
	GOTO ext
END IF

IF li_isuse = 0 THEN
	rslt = 0
	arg_msg = '条码:'+arg_barcode+',已经作废,不能操作,请检查'
	GOTO ext
END IF

IF arg_ifth = 0 THEN
	IF arg_inflag = 1 THEN
		IF li_inflag - li_outflag = 1 THEN
			rslt = 0
			arg_msg = '操作失败,条码:'+arg_barcode+',已经进仓,不能重复进仓'
			GOTO  ext
		END IF
		
		li_inflag_update = 1
		
		UPDATE u_mtrlware_mx
			SET u_mtrlware_mx.scid = :arg_scid,
			u_mtrlware_mx.mtrlwareid = :arg_mtrlwareid,
			u_mtrlware_mx.relbillcode = :arg_relbillcode,
			u_mtrlware_mx.relbillid = :arg_relbillid,
			u_mtrlware_mx.relprintid = :arg_relprintid,
			u_mtrlware_mx.inflag = u_mtrlware_mx.inflag + :li_inflag_update,
			u_mtrlware_mx.storageid = u_mtrlware.storageid,
			u_mtrlware_mx.mtrlid = u_mtrlware.mtrlid,
			u_mtrlware_mx.sptid = u_mtrlware.sptid,
			u_mtrlware_mx.status = u_mtrlware.status,
			u_mtrlware_mx.woodcode = u_mtrlware.woodcode,
			u_mtrlware_mx.pcode = u_mtrlware.pcode,
			u_mtrlware_mx.plancode = u_mtrlware.plancode,
			u_mtrlware_mx.mtrlcuscode = u_mtrlware.mtrlcuscode,
			u_mtrlware_mx.location = u_mtrlware.location
			FROM u_mtrlware_mx,u_mtrlware
			WHERE u_mtrlware.scid = :arg_scid
			AND u_mtrlware.mtrlwareid = :arg_mtrlwareid
			And u_mtrlware_mx.barcode = :arg_barcode;
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = '更新条码:'+arg_barcode+',进仓标记操作失败,'+sqlca.SQLErrText
			GOTO  ext
		END IF
	ELSE
		IF li_inflag = 0 THEN
			rslt = 0
			arg_msg = '操作失败,条码:'+arg_barcode+',未进仓,不能取消进仓'
			GOTO  ext
		END IF
		
		IF li_inflag - li_outflag = 0 THEN
			rslt = 0
			arg_msg = '操作失败,条码:'+arg_barcode+',已经出仓,不能取消进仓'
			GOTO  ext
		END IF
		
		li_inflag_update = -1
		
		UPDATE u_mtrlware_mx
			SET u_mtrlware_mx.scid = :arg_scid,
			u_mtrlware_mx.mtrlwareid = :arg_mtrlwareid,
			u_mtrlware_mx.relbillcode = :arg_relbillcode,
			u_mtrlware_mx.relbillid = :arg_relbillid,
			u_mtrlware_mx.relprintid = :arg_relprintid,
			u_mtrlware_mx.inflag = u_mtrlware_mx.inflag + :li_inflag_update
			FROM u_mtrlware_mx
			Where u_mtrlware_mx.barcode = :arg_barcode;
			
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = '更新条码:'+arg_barcode+',进仓标记操作失败,'+sqlca.SQLErrText
			GOTO  ext
		END IF
	END IF
ELSE
	IF arg_inflag = 1 THEN
		IF li_inflag - li_outflag <> 1 THEN
			rslt = 0
			arg_msg = '操作失败,条码:'+arg_barcode+',不是在已进仓状态,不能执行退货审核'
			GOTO  ext
		END IF
		
		li_outflag_update = 1
	ELSE
		IF li_inflag - li_outflag <> 0 THEN
			rslt = 0
			arg_msg = '操作失败,条码:'+arg_barcode+',不是在未进仓状态,不能执行退货撤审'
			GOTO  ext
		END IF
		
		li_outflag_update = -1
	END IF
	
	UPDATE u_mtrlware_mx
		SET outflag = outflag + :li_outflag_update
		Where barcode = :arg_barcode;
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = '更新条码:'+arg_barcode+',出仓标记操作失败,'+sqlca.SQLErrText
		GOTO  ext
	END IF
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 0 And arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt




end function

public function integer uof_barcode_fp (string arg_barcode, string arg_relbillcode, long arg_relbillid, long arg_relprintid, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1

UPDATE u_mtrlware_mx
	SET u_mtrlware_mx.relbillcode = :arg_relbillcode,
	u_mtrlware_mx.relbillid = :arg_relbillid,
	u_mtrlware_mx.relprintid = :arg_relprintid
	FROM u_mtrlware_mx
	Where u_mtrlware_mx.barcode = :arg_barcode;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '更新条码:'+arg_barcode+',订单分配信息失败,'+sqlca.SQLErrText
	GOTO  ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 And arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt





end function

public function integer mod_dscrp2 (long arg_getbarid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
s_getbar arg_s_gb

IF arg_getbarid <= 0 THEN
	rslt = 0
	arg_msg = '错误条码生成单唯一码'
	GOTO ext
END IF

IF arg_newdescppart = '' THEN
	rslt = 0
	arG_MSG = "备注内容为空,操作取消"
	GOTO ext
END IF

IF p_getinfo(arg_getbarid,arg_s_gb,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF arg_s_gb.flag = 0 THEN
	rslt = 0
	arg_msg = "条码生成单未审核,操作取消"
	GOTO ext
END IF

UPDATE u_getbar
	SET DSCRP2 = :arg_newdescppart
	WHERE getbarid = :arg_getbarid;
IF SQLCA.SQLCode <> 0 THEN
	rslt = 0
	arG_MSG = "因网络或其它原因导致修改备注2操作失败"+"~n"+SQLCA.SQLErrText
	GOTO ext
END IF

ext:

IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

Return (rslt)

end function

on uo_getbar.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_getbar.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on