FXApp/ws_objects/l1_uo_pc.pbl.src/uo_orderrqmtrl_tree_change.sru

$PBExportHeader$uo_orderrqmtrl_tree_change.sru
forward
global type uo_orderrqmtrl_tree_change from nonvisualobject
end type
end forward

global type uo_orderrqmtrl_tree_change from nonvisualobject
end type
global uo_orderrqmtrl_tree_change uo_orderrqmtrl_tree_change

type variables
Long uo_billid
String uo_billcode

end variables

forward prototypes
public function integer save (s_orderrqmtrl_tree_change arg_s_change, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
public function integer p_getflag (long arg_billid, ref integer arg_flag, ref string arg_msg)
public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
public function integer updatebegin (long arg_billid, ref string arg_msg)
public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit)
public function integer audit (long arg_billid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
end prototypes

public function integer save (s_orderrqmtrl_tree_change arg_s_change, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
DateTime server_dt
Long ll_billid
String ls_sccode,ls_billcode
Long cnt


IF IsNull(arg_s_change.billid) THEN arg_s_change.billid = 0
IF IsNull(arg_s_change.billemp) THEN arg_s_change.billemp = ''
IF IsNull(arg_s_change.relcode) THEN arg_s_change.relcode = ''
IF IsNull(arg_s_change.dscrp) THEN arg_s_change.dscrp = ''
IF IsNull(arg_s_change.scid) THEN arg_s_change.scid = 0
IF IsNull(arg_s_change.orderid) THEN arg_s_change.orderid = 0
IF IsNull(arg_s_change.printid) THEN arg_s_change.printid = 0
IF IsNull(arg_s_change.plantype_ori) THEN arg_s_change.plantype_ori = 0
IF IsNull(arg_s_change.plantype_new) THEN arg_s_change.plantype_new = 0
IF IsNull(arg_s_change.qty_ori) THEN arg_s_change.qty_ori = 0
IF IsNull(arg_s_change.qty_new) THEN arg_s_change.qty_new = 0

IF arg_s_change.orderid = 0 THEN
	arg_msg = '请选择生产计划运算结果'
	rslt = 0
	GOTO ext
END IF

IF arg_s_change.billemp = '' THEN
	arg_msg = '请输入经手人'
	rslt = 0
	GOTO ext
END IF


cnt = 0

SELECT count(*) INTO :cnt
	FROM u_OrderRqMtrl_tree
	WHERE scid = :arg_s_change.scid
	AND orderid = :arg_s_change.orderid
	And printid = :arg_s_change.printid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询生产计划运算结果信息失败,'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '错误的生产计划运算结果'
	GOTO ext
END IF

IF arg_s_change.plantype_ori = arg_s_change.plantype_new THEN
	rslt = 0
	arg_msg = '新处理方式不能与旧处理方式相同,请检查'
	GOTO ext
END IF

IF arg_s_change.qty_new <= 0 THEN
	rslt = 0
	arg_msg = '请输入合理的新处理方式数量'
	GOTO ext
END IF

IF arg_s_change.qty_ori < arg_s_change.qty_new THEN
	rslt = 0
	arg_msg = '新处理方式数量不能大于旧处理方式数量,请检查'
	GOTO ext
END IF


SELECT Top 1 getdate() Into :server_dt From u_user;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	GOTO ext
END IF

IF arg_s_change.billid = 0 THEN
	ll_billid = f_sys_scidentity(0,"u_orderrqmtrl_tree_change","billid",arg_msg,True,id_sqlca)
	
	IF ll_billid <= 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	IF f_get_sccode(arg_s_change.scid,sqlca,ls_sccode,arg_msg) = 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	ls_billcode = getid(arg_s_change.scid,ls_sccode + 'TC',Date(server_dt),False,sqlca)
	
	
	INSERT INTO u_orderrqmtrl_tree_change
		(billid,
		billcode,
		billdate,
		billemp,
		relcode,
		dscrp,
		scid,
		orderid,
		printid,
		plantype_ori,
		plantype_new,
		qty_ori,
		qty_new,
		opdate,
		opemp)
		VALUES (:ll_billid,
		:ls_billcode,
		:arg_s_change.billdate,
		:arg_s_change.billemp,
		:arg_s_change.relcode,
		:arg_s_change.dscrp,
		:arg_s_change.scid,
		:arg_s_change.orderid,
		:arg_s_change.printid,
		:arg_s_change.plantype_ori,
		:arg_s_change.plantype_new,
		:arg_s_change.qty_ori,
		:arg_s_change.qty_new,
		:server_dt,
		:arg_opemp)	 ;
		
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致建立单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	uo_billid = ll_billid
	uo_billcode = ls_billcode
ELSE
	UPDATE u_orderrqmtrl_tree_change
		SET billdate = :arg_s_change.billdate,
		billemp = :arg_s_change.billemp,
		relcode = :arg_s_change.relcode,
		dscrp = :arg_s_change.dscrp,
		scid = :arg_s_change.scid,
		orderid = :arg_s_change.orderid,
		printid = :arg_s_change.printid,
		plantype_ori = :arg_s_change.plantype_ori,
		plantype_new = :arg_s_change.plantype_new,
		qty_ori = :arg_s_change.qty_ori,
		qty_new = :arg_s_change.qty_new,
		moddate = :server_dt,
		modemp = :arg_opemp
		Where billid  = :arg_s_change.billid;
	IF sqlca.SQLCode <> 0 Or sqlca.SQLNRows <= 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致更新单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	uo_billid = arg_s_change.billid
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF arg_ifcommit And  rslt = 1 THEN
	COMMIT;
END IF

RETURN rslt


end function

public function integer p_getflag (long arg_billid, ref integer arg_flag, ref string arg_msg);Int rslt = 1

SELECT flag
	INTO :arg_flag
	FROM u_orderrqmtrl_tree_change
	WHERE billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	ARG_MSG = '查询单据审核标记失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
RETURN rslt

end function

public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
Int li_flag

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,li_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF li_flag = 1 THEN
	rslt = 0
	arg_msg = '单据不是在待审状态,不可以删除'
	GOTO ext
END IF


DELETE FROM u_orderrqmtrl_tree_change
	WHERE billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除单据操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF


ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt
end function

public function integer updatebegin (long arg_billid, ref string arg_msg);Int rslt = 1
Int li_flag
Long cnt

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,li_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF li_flag = 1 THEN
	rslt = 0
	arg_msg = '单据已经审核,不可以再修改'
	GOTO ext
END IF

ext:

RETURN rslt

end function

public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
Int li_flag

IF arg_newdescppart = '' THEN
	rslt = 0
	arG_MSG = "要添加内容为空,操作取消"
	GOTO ext
END IF

IF p_getflag(arg_billid,li_flag,arG_MSG) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF li_flag = 0 THEN
	rslt = 0
	arG_MSG = "待审核状态下不可用"
	GOTO ext
END IF

UPDATE u_orderrqmtrl_tree_change
	SET DSCRP = DSCRP+' '+:arg_newdescppart
	WHERE u_orderrqmtrl_tree_change.billid = :arg_billid;
IF SQLCA.SQLCode <> 0 THEN
	rslt = 0
	arG_MSG = "因网络或其它原因导致添加备注操作失败"+"~n"+SQLCA.SQLErrText
	GOTO ext
END IF

ext:

IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

Return (rslt)

end function

public function integer audit (long arg_billid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);int rslt = 1 
int li_flag

IF arg_billid <= 0 THEN
	rslt = 0
	ARG_MSG = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,li_flag,ARG_MSG) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF li_flag <> 0  THEN
	rslt = 0
	ARG_MSG = '单据不是在待审核状态,不可以再审'
	GOTO ext
END IF

UPDATE u_orderrqmtrl_tree_change
	SET auditemp = :arg_opemp,
	auditdate = getdate(),
	flag = 1
	WHERE billid = :arg_billid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	ARG_MSG = "因网络或其它原因导致单据审核操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
ELSEIF sqlca.SQLNRows = 0 THEN
	rslt = 0
	ARG_MSG = "单据正在审核,请稍后查询。"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt
end function

on uo_orderrqmtrl_tree_change.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_orderrqmtrl_tree_change.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on