$PBExportHeader$uo_produce_worktime.sru
forward
global type uo_produce_worktime from nonvisualobject
end type
end forward

global type uo_produce_worktime from nonvisualobject
end type
global uo_produce_worktime uo_produce_worktime

type variables
Long uo_billid
String uo_billcode 

end variables

forward prototypes
public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg)
public function integer p_getflag (long arg_billid, ref long arg_flag, ref string arg_msg)
public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
public function integer updatebegin (long arg_billid, ref string arg_msg)
public function integer audit (long arg_billid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
public function integer caudit (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
public function integer save (s_produce_worktime arg_s_worktime, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
end prototypes

public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg);
Int rslt = 1
long ll_flag

IF arg_newdescppart = '' THEN
	rslt = 0
	arG_MSG = "要添加内容为空,操作取消"
	GOTO ext
END IF

IF p_getflag(arg_billid,ll_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF ll_flag = 0 THEN
	rslt = 0
	arG_MSG = "待审核状态下不可用"
	GOTO ext
END IF

UPDATE u_produce_worktime
	SET DSCRP = DSCRP+' '+:arg_newdescppart
	WHERE u_produce_worktime.billid = :arg_billid;
IF SQLCA.SQLCode <> 0 THEN
	rslt = 0
	arG_MSG = "因网络或其它原因导致添加备注操作失败"+"~n"+SQLCA.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 1 THEN
	COMMIT;
ELSE
	ROLLBACK;
END IF


Return (rslt)





end function

public function integer p_getflag (long arg_billid, ref long arg_flag, ref string arg_msg);Int rslt = 1


SELECT flag
	INTO :arg_flag
	FROM u_produce_worktime
	WHERE billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	ARG_MSG = '查询单据审核标记失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
RETURN rslt
end function

public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit);int rslt = 1 
long ll_flag

if arg_billid <= 0 then 
	rslt = 0 
	arg_msg = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,ll_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

if ll_flag <> 0 then 
	rslt = 0 
	arg_msg = '单据不是在待审核状态,不能删除'
	GOTO ext
END IF

DELETE FROM u_produce_worktime_mx
	WHERE billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除单据明细操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

DELETE FROM u_produce_worktime
	WHERE billid = :arg_billid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除单据操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt
end function

public function integer updatebegin (long arg_billid, ref string arg_msg);Int rslt = 1
long li_flag

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,li_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF li_flag = 1 THEN
	rslt = 0
	arg_msg = '单据已经审核,不可以修改,要修改请先撤销审核'
	GOTO ext
END IF

ext:
RETURN rslt



end function

public function integer audit (long arg_billid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
long ll_flag

IF arg_billid <= 0 THEN
	rslt = 0
	ARG_MSG = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,ll_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF ll_flag <> 0  THEN
	rslt = 0
	ARG_MSG = '单据不是在待审核状态,不可以再审'
	GOTO ext
END IF

//更新审核标记
UPDATE  u_produce_worktime
	SET auditemp = :arg_opemp,
	auditdate = getdate(),
	flag = 1
	WHERE billid = :arg_billid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	ARG_MSG = "因网络或其它原因导致单据审核操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt






end function

public function integer caudit (long arg_billid, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
Long ll_flag

DateTime null_dt

SetNull(null_dt)

IF arg_billid <= 0 THEN
	rslt = 0
	ARG_MSG = '错误单据唯一码'
	GOTO ext
END IF


IF p_getflag(arg_billid,ll_flag,ARG_MSG) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF ll_flag <> 1 THEN
	rslt = 0
	ARG_MSG = '单据不是在审核状态,不可以撤审'
	GOTO ext
END IF

//更新审核标记
UPDATE  u_produce_worktime
	SET auditemp = '',
	auditdate = :null_dt,
	flag = 0
	Where billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	ARG_MSG = "因网络或其它原因导致单据撤审操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt

end function

public function integer save (s_produce_worktime arg_s_worktime, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);Integer rslt = 1,cnt = 0
DateTime server_dt
Long ll_billid,it_mxbt,i
String ls_sccode,ls_billcode

IF IsNull(arg_s_worktime.scid) THEN arg_s_worktime.scid = 0
IF IsNull(arg_s_worktime.billid) THEN arg_s_worktime.billid = 0
IF IsNull(arg_s_worktime.rep) THEN arg_s_worktime.rep = ''
IF IsNull(arg_s_worktime.dscrp) THEN arg_s_worktime.dscrp = ''
IF IsNull(arg_s_worktime.wrkgrpid) THEN arg_s_worktime.wrkgrpid = 0

IF arg_s_worktime.rep = '' THEN
	arg_msg = '请输入经手人'
	rslt = 0
	GOTO ext
END IF


IF arg_s_worktime.wrkgrpid = 0 THEN
	arg_msg = '请选择车间'
	rslt = 0
	GOTO ext
END IF


SELECT Top 1 getdate() INTO :server_dt FROM u_user;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	GOTO ext
END IF

it_mxbt = UpperBound(arg_s_worktime.arg_s_worktimemx)

IF it_mxbt <= 0 THEN
	rslt = 0
	arg_msg = "没有正确明细内容"
	GOTO ext
END IF

IF arg_s_worktime.billid = 0 THEN
	ll_billid = f_sys_scidentity(0,"u_produce_worktime","billid",arg_msg,TRUE,id_sqlca)
	
	IF ll_billid <= 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	IF f_get_sccode(arg_s_worktime.scid,sqlca,ls_sccode,arg_msg) = 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	
	ls_billcode = getid(arg_s_worktime.scid,ls_sccode + 'PT',Date(server_dt),FALSE,sqlca)
	
	
	IF ls_billcode = "err" THEN
		rslt = 0
		arg_msg = "无法获取单据编号"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	INSERT INTO u_produce_worktime
		(scid,
		billid,
		billcode,
		billdate,
		rep,
		dscrp,
		opdate,
		opemp,
		wrkgrpid)
		VALUES
		(:arg_s_worktime.scid,
		:ll_billid,
		:ls_billcode,
		:arg_s_worktime.billdate,
		:arg_s_worktime.rep,
		:arg_s_worktime.dscrp,
		getdate(),
		:arg_opemp,
		:arg_s_worktime.wrkgrpid);
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致建立单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	FOR i = 1 TO it_mxbt
		INSERT INTO u_produce_worktime_mx
			(billid,
			empid,
			worktime,
			dscrp,
			printid)
			VALUES
			(:ll_billid,
			:arg_s_worktime.arg_s_worktimemx[i].empid,
			:arg_s_worktime.arg_s_worktimemx[i].worktime,
			:arg_s_worktime.arg_s_worktimemx[i].dscrp,
			:arg_s_worktime.arg_s_worktimemx[i].printid);
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = "因网络或其它原因导致插入明细操作失败"+"~n"+sqlca.SQLErrText
			GOTO ext
		END IF
	NEXT
	
	uo_billid = ll_billid
	uo_billcode = ls_billcode
	
ELSE
	UPDATE u_produce_worktime
		SET 		billdate = :arg_s_worktime.billdate,
		rep = :arg_s_worktime.rep,
		dscrp = :arg_s_worktime.dscrp,
		moddate = getdate(),
		modemp = :arg_opemp,
		wrkgrpid = :arg_s_worktime.wrkgrpid
		WHERE billid = :arg_s_worktime.billid
		AND flag = 0 ;
	IF sqlca.SQLCode <> 0 OR sqlca.SQLNRows <= 0   THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致更新单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	DELETE FROM u_produce_worktime_mx
		Where billid = :arg_s_worktime.billid;
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "删除旧有明细操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	FOR i = 1 TO it_mxbt
		INSERT INTO u_produce_worktime_mx
			(billid,
			empid,
			worktime,
			dscrp,
			printid)
			VALUES
			(:arg_s_worktime.billid,
			:arg_s_worktime.arg_s_worktimemx[i].empid,
			:arg_s_worktime.arg_s_worktimemx[i].worktime,
			:arg_s_worktime.arg_s_worktimemx[i].dscrp,
			:arg_s_worktime.arg_s_worktimemx[i].printid);
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = "因网络或其它原因导致插入明细操作失败"+"~n"+sqlca.SQLErrText
			GOTO ext
		END IF
	NEXT
	
	uo_billid = arg_s_worktime.billid
	
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF arg_ifcommit AND  rslt = 1 THEN
	COMMIT;
END IF

RETURN rslt




end function

on uo_produce_worktime.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_produce_worktime.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on