$PBExportHeader$uo_produce_cost.sru
forward
global type uo_produce_cost from nonvisualobject
end type
end forward

global type uo_produce_cost from nonvisualobject
end type
global uo_produce_cost uo_produce_cost

type variables
Long uo_billid
String uo_billcode 

end variables

forward prototypes
public function integer save (s_produce_cost arg_s_cost, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg)
public function integer p_getflag (long arg_billid, ref long arg_flag, ref string arg_msg)
public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
public function integer getinfo (long arg_billid, ref s_produce_cost_mx arg_ref_costmx[], ref long arg_arr_cnt, ref string arg_msg)
public function integer updatebegin (long arg_billid, ref string arg_msg)
public function integer audit (long arg_billid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit)
public function integer caudit (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
end prototypes

public function integer save (s_produce_cost arg_s_cost, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);Integer rslt = 1,cnt = 0
DateTime server_dt
Long ll_billid,it_mxbt,i
String ls_sccode,ls_billcode

IF IsNull(arg_s_cost.scid) THEN arg_s_cost.scid = 0
IF IsNull(arg_s_cost.billid) THEN arg_s_cost.billid = 0
IF IsNull(arg_s_cost.billmth) THEN arg_s_cost.billmth = 0
IF IsNull(arg_s_cost.rep) THEN arg_s_cost.rep = ''
IF IsNull(arg_s_cost.dscrp) THEN arg_s_cost.dscrp = ''
IF IsNull(arg_s_cost.wrkgrpid) THEN arg_s_cost.wrkgrpid = 0
IF IsNull(arg_s_cost.billtype) THEN arg_s_cost.billtype = 0
IF IsNull(arg_s_cost.atid) THEN arg_s_cost.atid = 0

IF arg_s_cost.rep = '' THEN
	arg_msg = '请输入经手人'
	rslt = 0
	GOTO ext
END IF

IF arg_s_cost.billtype = 0 THEN
	IF arg_s_cost.wrkgrpid = 0 THEN
		arg_msg = '请选择车间'
		rslt = 0
		GOTO ext
	END IF
END IF

SELECT Top 1 getdate() INTO :server_dt FROM u_user;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	GOTO ext
END IF

it_mxbt = UpperBound(arg_s_cost.arg_s_costmx)

IF it_mxbt <= 0 THEN
	rslt = 0
	arg_msg = "没有正确明细内容"
	GOTO ext
END IF

IF arg_s_cost.billid = 0 THEN
	ll_billid = f_sys_scidentity(0,"u_produce_cost","billid",arg_msg,TRUE,id_sqlca)
	
	IF ll_billid <= 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	IF f_get_sccode(arg_s_cost.scid,sqlca,ls_sccode,arg_msg) = 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	IF arg_s_cost.billtype = 0 THEN
		ls_billcode = getid(arg_s_cost.scid,ls_sccode + 'PF',Date(server_dt),FALSE,sqlca)
	ELSE
		ls_billcode = getid(arg_s_cost.scid,ls_sccode + 'PS',Date(server_dt),FALSE,sqlca)
	END IF
	
	IF ls_billcode = "err" THEN
		rslt = 0
		arg_msg = "无法获取单据编号"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	INSERT INTO u_produce_cost
		(scid,
		billid,
		billcode,
		billdate,
		billmth,
		rep,
		dscrp,
		opdate,
		opemp,
		wrkgrpid,
		billtype,
		atid)
		VALUES
		(:arg_s_cost.scid,
		:ll_billid,
		:ls_billcode,
		:arg_s_cost.billdate,
		:arg_s_cost.billmth,
		:arg_s_cost.rep,
		:arg_s_cost.dscrp,
		getdate(),
		:arg_opemp,
		:arg_s_cost.wrkgrpid,
		:arg_s_cost.billtype,
		:arg_s_cost.atid);
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致建立单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	FOR i = 1 TO it_mxbt
		INSERT INTO u_produce_cost_mx
			(billid,
			printid,
			itemid,
			amt,
			dscrp)
			VALUES
			(:ll_billid,
			:arg_s_cost.arg_s_costmx[i].printid,
			:arg_s_cost.arg_s_costmx[i].itemid,
			:arg_s_cost.arg_s_costmx[i].amt,
			:arg_s_cost.arg_s_costmx[i].dscrp
			);
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = "因网络或其它原因导致插入明细操作失败"+"~n"+sqlca.SQLErrText
			GOTO ext
		END IF
	NEXT
	
	uo_billid = ll_billid
	uo_billcode = ls_billcode
	
ELSE
	UPDATE u_produce_cost
		SET 		billdate = :arg_s_cost.billdate,
		billmth = :arg_s_cost.billmth,
		rep = :arg_s_cost.rep,
		dscrp = :arg_s_cost.dscrp,
		moddate = getdate(),
		modemp = :arg_opemp,
		wrkgrpid = :arg_s_cost.wrkgrpid,
		atid = :arg_s_cost.atid
		WHERE billid = :arg_s_cost.billid
		AND flag = 0 ;
	IF sqlca.SQLCode <> 0 OR sqlca.SQLNRows <= 0   THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致更新单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	DELETE FROM u_produce_cost_mx
		Where billid = :arg_s_cost.billid;
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "删除旧有明细操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	FOR i = 1 TO it_mxbt
		INSERT INTO u_produce_cost_mx
			(billid,
			printid,
			itemid,
			amt,
			dscrp)
			VALUES
			(:arg_s_cost.billid,
			:arg_s_cost.arg_s_costmx[i].printid,
			:arg_s_cost.arg_s_costmx[i].itemid,
			:arg_s_cost.arg_s_costmx[i].amt,
			:arg_s_cost.arg_s_costmx[i].dscrp);
		IF sqlca.SQLCode <> 0 THEN
			rslt = 0
			arg_msg = "因网络或其它原因导致插入明细操作失败"+"~n"+sqlca.SQLErrText
			GOTO ext
		END IF
	NEXT
	
	uo_billid = arg_s_cost.billid
	
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF arg_ifcommit AND  rslt = 1 THEN
	COMMIT;
END IF

RETURN rslt



end function

public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg);
Int rslt = 1
long ll_flag

IF arg_newdescppart = '' THEN
	rslt = 0
	arG_MSG = "要添加内容为空,操作取消"
	GOTO ext
END IF

IF p_getflag(arg_billid,ll_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF ll_flag = 0 THEN
	rslt = 0
	arG_MSG = "待审核状态下不可用"
	GOTO ext
END IF

UPDATE u_produce_cost
	SET DSCRP = DSCRP+' '+:arg_newdescppart
	WHERE u_produce_cost.billid = :arg_billid;
IF SQLCA.SQLCode <> 0 THEN
	rslt = 0
	arG_MSG = "因网络或其它原因导致添加备注操作失败"+"~n"+SQLCA.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 1 THEN
	COMMIT;
ELSE
	ROLLBACK;
END IF


Return (rslt)





end function

public function integer p_getflag (long arg_billid, ref long arg_flag, ref string arg_msg);Int rslt = 1


SELECT flag
	INTO :arg_flag
	FROM u_produce_cost
	WHERE billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	ARG_MSG = '查询单据审核标记失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
RETURN rslt
end function

public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit);int rslt = 1 
long ll_flag

if arg_billid <= 0 then 
	rslt = 0 
	arg_msg = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,ll_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

if ll_flag <> 0 then 
	rslt = 0 
	arg_msg = '单据不是在待审核状态,不能删除'
	GOTO ext
END IF

DELETE FROM u_produce_cost_mx
	WHERE billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除单据明细操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

DELETE FROM u_produce_cost
	WHERE billid = :arg_billid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除单据操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt
end function

public function integer getinfo (long arg_billid, ref s_produce_cost_mx arg_ref_costmx[], ref long arg_arr_cnt, ref string arg_msg);Int rslt = 1
Long i = 1,no_mxcheck = 0

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = '错误单据唯一码'
	GOTO ext
END IF

//用游标读取明细
DECLARE cur_costmx CURSOR FOR
	SELECT u_produce_cost_mx.billid,
	u_produce_cost_mx.itemid,
	u_produce_cost_mx.printid,
	u_produce_cost_mx.amt,
	u_produce_cost_mx.dscrp
	FROM u_produce_cost_mx
	WHERE u_produce_cost_mx.billid = :arg_billid
	Order By u_produce_cost_mx.printid;

OPEN cur_costmx;

FETCH cur_costmx INTO 
   :arg_ref_costmx[i].billid,
	:arg_ref_costmx[i].itemid,:arg_ref_costmx[i].printid,
	:arg_ref_costmx[i].amt,:arg_ref_costmx[i].dscrp;

DO WHILE sqlca.SQLCode = 0
	i++
FETCH cur_costmx INTO 
   :arg_ref_costmx[i].billid,
	:arg_ref_costmx[i].itemid,:arg_ref_costmx[i].printid,
	:arg_ref_costmx[i].amt,:arg_ref_costmx[i].dscrp;
LOOP
CLOSE cur_costmx;

//检验明细是否读入完整
SELECT count(*) INTO :no_mxcheck
	FROM u_produce_cost_mx
	WHERE billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,单据明细数量"
	GOTO ext
END IF

IF i <> (no_mxcheck + 1) THEN
	rslt = 0
	arg_msg = "查询操作失败,单据明细"
	GOTO ext
END IF

arg_arr_cnt = i - 1

ext:

RETURN rslt

end function

public function integer updatebegin (long arg_billid, ref string arg_msg);Int rslt = 1
long li_flag

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,li_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF li_flag = 1 THEN
	rslt = 0
	arg_msg = '单据已经审核,不可以修改,要修改请先撤销审核'
	GOTO ext
END IF

ext:
RETURN rslt



end function

public function integer audit (long arg_billid, string arg_opemp, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
long ll_flag

IF arg_billid <= 0 THEN
	rslt = 0
	ARG_MSG = '错误单据唯一码'
	GOTO ext
END IF

IF p_getflag(arg_billid,ll_flag,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF ll_flag <> 0  THEN
	rslt = 0
	ARG_MSG = '单据不是在待审核状态,不可以再审'
	GOTO ext
END IF

//更新审核标记
UPDATE  u_produce_cost
	SET auditemp = :arg_opemp,
	auditdate = getdate(),
	flag = 1
	WHERE billid = :arg_billid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	ARG_MSG = "因网络或其它原因导致单据审核操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt






end function

public function integer caudit (long arg_billid, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1
Long ll_flag

DateTime null_dt

SetNull(null_dt)

IF arg_billid <= 0 THEN
	rslt = 0
	ARG_MSG = '错误单据唯一码'
	GOTO ext
END IF


IF p_getflag(arg_billid,ll_flag,ARG_MSG) = 0 THEN
	rslt = 0
	GOTO ext
END IF

IF ll_flag <> 1 THEN
	rslt = 0
	ARG_MSG = '单据不是在审核状态,不可以撤审'
	GOTO ext
END IF

//更新审核标记
UPDATE  u_produce_cost
	SET auditemp = '',
	auditdate = :null_dt,
	flag = 0
	Where billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	ARG_MSG = "因网络或其它原因导致单据撤审操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF

RETURN rslt

end function

on uo_produce_cost.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_produce_cost.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on