$PBExportHeader$uo_oa_fj_downsave.sru
forward
global type uo_oa_fj_downsave from nonvisualobject
end type
end forward

global type uo_oa_fj_downsave from nonvisualobject
end type
global uo_oa_fj_downsave uo_oa_fj_downsave

type variables
transaction  ins_tran  //数据commit事务
end variables

forward prototypes
public function integer f_down_fj (long arg_fjid, string arg_fjname, ref blob arg_fjdata, ref string arg_msg)
public function integer f_save_fj (long arg_docid, long arg_annextype, string arg_fjname, blob arg_fjbody, long arg_fjtype, long arg_ifdownfj, long arg_iflookfj, ref string arg_msg, boolean arg_ifcommit, decimal arg_filesize)
end prototypes

public function integer f_down_fj (long arg_fjid, string arg_fjname, ref blob arg_fjdata, ref string arg_msg);Long rslt = 1,cnt
Blob ls_filedata

IF arg_fjid <= 0 THEN
	rslt = 0
	arg_msg = '下载附件失败(错误附件ID)'
	GOTO ext
END IF

IF arg_fjname = '' THEN
	rslt = 0
	arg_msg = '下载附件失败(错误附件名)'
	GOTO ext
END IF

//SELECT count(*)
//	INTO :cnt
//	FROM oa_doc_annex
//	WHERE (oa_doc_annex.AnnexNO = :arg_fjid) AND
//	(oa_doc_annex.Filename = :arg_fjname)
//	USING ins_tran;
//IF ins_tran.SQLCode <> 0 THEN
//	rslt = 0
//	arg_msg = '查询附件信息失败>>'+ins_tran.SQLErrText
//	GOTO ext
//END IF

SELECTBLOB Fileblob
INTO :ls_filedata
FROM oa_doc_annex
Where  (oa_doc_annex.AnnexNO = :arg_fjid) AND
(oa_doc_annex.Filename = :arg_fjname)
USING ins_tran;
IF ins_tran.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '下载附件失败>>'+ins_tran.SQLErrText
	GOTO ext
END IF

arg_fjdata = ls_filedata

ext:
RETURN rslt

end function

public function integer f_save_fj (long arg_docid, long arg_annextype, string arg_fjname, blob arg_fjbody, long arg_fjtype, long arg_ifdownfj, long arg_iflookfj, ref string arg_msg, boolean arg_ifcommit, decimal arg_filesize);//保存附件
Long rslt = 1
Long ls_newid
IF arg_docid <= 0 THEN
	rslt = 0
	arg_msg = '保存附件失败(公文ID)'
	GOTO ext
END IF

IF IsNull(arg_fjname) OR arg_fjname = '' THEN
	rslt = 0
	if IsNull(arg_fjname) then
		arg_msg = '保存附件失败(附件名) null'
	else
		arg_msg = '保存附件失败(附件名) 空'
	end if
	GOTO ext
END IF

ls_newid = f_sys_scidentity(0,"oa_doc_annex","AnnexNO",arg_msg,TRUE,id_sqlca)
IF ls_newid <= 0 THEN
	rslt = 0
	GOTO ext
END IF

INSERT INTO oa_doc_annex
	( docID,
	annextype,
	AnnexNO,
	Filename,
	Opdate,
	Opemp,
	Filetype,
	IFDOWNFJ,
	IFLOOKFJ,
	filesize)
	VALUES ( :arg_docid,
	:arg_annextype,
	:ls_newid,
	:arg_fjname,
	getdate(),
	:publ_operator,
	:arg_fjtype,
	:ARG_IFDOWNFJ,
	:ARG_IFLOOKFJ,
	:arg_filesize)
	USING ins_tran;
IF ins_tran.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '因网络或其它原因保存附件失败>>'+ins_tran.SQLErrText
	GOTO ext
ELSE
	COMMIT USING ins_tran;
END IF

UPDATEBLOB oa_doc_annex
Set Fileblob = :arg_fjbody
Where AnnexNO = :ls_newid USING ins_tran;
IF ins_tran.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '因网络或其它原因保存附件失败>>'+ins_tran.SQLErrText
	GOTO ext
END IF

COMMIT USING ins_tran;

ext:
RETURN rslt



end function

on uo_oa_fj_downsave.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_oa_fj_downsave.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on