$PBExportHeader$uo_loanwage.sru
forward
global type uo_loanwage from nonvisualobject
end type
end forward

global type uo_loanwage from nonvisualobject
end type
global uo_loanwage uo_loanwage

type variables
public protectedwrite long billid           //计件单自动增量id
public protectedwrite string billcode       //计件单的唯一编号
public protectedwrite long wagemth          //工资月份
public protectedwrite datetime opdate       //建立时间,自动
public protectedwrite string opemp          //建立人
public protectedwrite datetime moddate       //修改时间,自动
public protectedwrite string modemp          //修改人
public protectedwrite int flag=0            //审核标志
public protectedwrite datetime auditingdate //审核时间
public protectedwrite string auditingrep    //审核操作员

long empid          //员工ID
datetime billdate   //计件日期
decimal loanamt     //金额
long wageid         //工资项目id
string loanreason   //原因
string cardcode     //证件号     
string dscrp=''     //备注
long returndate   //还款日
uo_wage u_wage

private:
boolean it_newbegin=false    //新建标志
boolean it_updatebegin=false//修改标志

end variables

forward prototypes
public function integer p_reset ()
public function integer newbegin (ref string arg_msg)
public function integer updatebegin (long arg_billid, ref string arg_msg)
public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer save (ref string arg_msg, boolean arg_ifcommit)
public function integer del (long arg_billid, ref string arg_msg)
public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg)
public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer auditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
public function integer cauditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
end prototypes

public function integer p_reset ();//INT p_RESET()
//清除对象及其明细
billid=0
billcode=''
opemp=''
auditingrep=''
flag=0
empid=0  
loanamt=0      
loanreason=''
wageid=0    
returndate=0
dscrp=''    
cardcode=''


it_newbegin=FALSE
it_updatebegin=FALSE
RETURN 1
end function

public function integer newbegin (ref string arg_msg);p_reset()
it_newbegin=TRUE
it_updatebegin=FALSE
return 1

end function

public function integer updatebegin (long arg_billid, ref string arg_msg);//====================================================================
// Function: updatebegin(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


int rslt = 1

if arg_billid <= 0 then
	billid = 0
	arg_msg = '错误的单据ID'
	goto ext
end if

select
u_gz_loanwage.billcode,
u_gz_loanwage.billdate,
u_gz_loanwage.wagemth,
u_gz_loanwage.wageid,
u_gz_loanwage.empid,
u_gz_loanwage.loanamt,
u_gz_loanwage.loanreason,
u_gz_loanwage.cardcode,
u_gz_loanwage.returndate,
u_gz_loanwage.dscrp,
u_gz_loanwage.flag

into
:billcode,
:billdate,
:wagemth,
:wageid,
:empid,
:loanamt,
:loanreason,
:cardcode,
:returndate,
:dscrp,
:flag
from u_gz_loanwage where u_gz_loanwage.billid = :arg_billid;
if sqlca.sqlcode <> 0 then
	rslt = 0
	arg_msg = '查询数据操作失败,借支单'+sqlca.sqlerrtext
	goto ext
end if

if flag = 1 then
	rslt = 0
	arg_msg = '单据已经审核,不可以修改'
	goto ext
end if

billid = arg_billid

it_newbegin = false
it_updatebegin = true

ext:
if  rslt = 0 then p_reset()
return rslt


end function

public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);
Long cnt = 0,i
Int rslt = 1
DateTime null_server_dt
SetNull(null_server_dt)

IF f_check_wage_audit(arg_wagemth,-1,arg_msg) = 0 THEN
	rslt = 0
	arg_msg = arg_msg + ',不能撤审'
	GOTO ext
END IF


//检查该月份,该工资项目是否已开工资变更单
cnt = 0

SELECT count(*)
	INTO :cnt
	FROM u_wage_change
	WHERE wageid = :arg_wageid
	AND wagemth = :arg_wagemth;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询该月份该工资项目是否已开工资变更单失败'+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt > 0 THEN
	rslt = 0
	arg_msg = '该月份该工资项目已开工资变更单,不能撤审'
	GOTO ext
END IF


SELECT count(*) INTO :cnt
	FROM u_gz_loanwage
	WHERE wagemth = :arg_wagemth
	AND wageid = :arg_wageid
	AND flag = 1;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询借支单失败,原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '该月的借支单未审核,不用撤审!'
	GOTO ext
END IF

cnt = 0
SELECT  count(*)
	INTO :cnt
	FROM u_gz_wageitem
	WHERE useflag = 1
	AND wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败,原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目,原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF u_wage.f_wage_clear(arg_wageid,arg_wagemth,arg_msg,FALSE) = 0 THEN
	rslt = 0
	GOTO ext
END IF

UPDATE u_gz_loanwage SET
	flag = 0,
	Auditrep = '',
	Auditdate = :null_server_dt
	WHERE  returndate = :arg_wagemth
	AND flag = 1
	AND  wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新借支单失败，原因：'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF




ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF  rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt



end function

public function integer save (ref string arg_msg, boolean arg_ifcommit);Integer rslt = 1,cnt = 0,i
DateTime server_dt
Long ls_newid

IF IsNull(empid)	 THEN empid = 0
IF IsNull(loanamt)	 THEN loanamt = 0
IF IsNull(wageid)	 THEN wageid = 0
IF IsNull(loanreason)	 THEN loanreason = ''
IF IsNull(cardcode)	 THEN cardcode = ''
IF IsNull(dscrp)	 THEN dscrp = ''
IF IsNull(returndate)	 THEN returndate = 0


IF it_newbegin = FALSE AND it_updatebegin = FALSE THEN
	rslt = 0
	arg_msg = "非编辑状态不可以提交"
	GOTO ext
END IF

SELECT count(*) INTO :cnt
	FROM u_rs_empinfo
	Where empid = :empid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询员工资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt = 0 THEN
	arg_msg = '没有选择员工或员工资料不存在'
	rslt = 0
	GOTO ext
ELSEIF cnt > 1 THEN
	arg_msg = '员工资料重复'
	rslt = 0
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM u_gz_wageitem
	Where wageid = :wageid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询工资项目资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt > 1 THEN
	arg_msg = '工资项目重复'
	rslt = 0
	GOTO ext
END IF

IF loanamt <= 0 THEN
	arg_msg = '请输入正确的借款金额'
	rslt = 0
	GOTO ext
END IF

SELECT Top 1 getdate() INTO :server_dt FROM u_user;
//取得系统时间,借用操作员表
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	GOTO ext
END IF

IF returndate <= 0 THEN
	rslt = 0
	arg_msg = '还款月份输入错误'
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM u_gz_loanwage
	WHERE returndate = :returndate
	AND flag = 1;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询还款工资月份:'+String(returndate)+',是否有单据已审失败,'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

IF cnt > 0 THEN
	arg_msg = '还款工资月份:'+String(returndate)+',已有单据已审,不能保存'
	rslt = 0
	GOTO ext
END IF

////////////////////////////////////////////// //开始区分:新建/更新 处理
IF billid = 0 THEN //新建
	ls_newid = f_sys_scidentity(0,"u_gz_loanwage","billid",arg_msg,TRUE,id_sqlca)
	IF ls_newid <= 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	
	billcode = getid(0,"JZ",Date(server_dt),TRUE,sqlca) //取得新单据编号
	IF billcode = "err" THEN
		billcode = ''
		rslt = 0
		arg_msg = "无法获取借支单编号"
		GOTO ext
	END IF
	
	INSERT INTO u_gz_loanwage (
		billid,
		billcode,
		billdate,
		Wagemth,
		wageid,
		empid,
		loanamt,
		loanreason,
		cardcode,
		returndate,
		dscrp,
		opdate,
		opemp)
		VALUES (
		:ls_newid,
		:billcode,
		:billdate,
		:returndate,
		:wageid,
		:empid,
		:loanamt,
		:loanreason,
		:cardcode,
		:returndate,
		:dscrp,
		:server_dt,
		:publ_operator);
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致插入操作失败>>"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	billid = ls_newid
ELSE //////////////////////////////////////////////// //更新
	
	UPDATE u_gz_loanwage
		SET billdate = :billdate,
		wageid = :wageid,
		empid = :empid,
		loanamt = :loanamt,
		loanreason = :loanreason,
		cardcode = :cardcode,
		returndate = :returndate,
		moddate = :server_dt,
		modemp = :modemp,
		dscrp = :dscrp,
		wagemth = :returndate
		WHERE u_gz_loanwage.billid = :billid
		AND flag = 0;
	IF sqlca.SQLCode <> 0 OR sqlca.SQLNRows <= 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致更新单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	
END IF

it_newbegin = FALSE
it_updatebegin = FALSE

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
Return(rslt)





end function

public function integer del (long arg_billid, ref string arg_msg);//====================================================================
// Function: del(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================

int rslt = 1
if arg_billid <= 0 then
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	goto ext
end if

if it_newbegin or it_updatebegin then
	rslt=0
   arg_msg="编辑状态下不可以执行,操作取消"
	goto ext
end if

select u_gz_loanwage.flag
	into :flag
	from u_gz_loanwage
	where u_gz_loanwage.billid = :arg_billid;
if sqlca.sqlcode <> 0  then
	rslt = 0
	arg_msg = '查询借支单操作失败'
	goto ext
end if

if flag = 1 then
	rslt = 0
	arg_msg = "单据已经审核,不可以删除"
	goto ext
end if

delete from u_gz_loanwage where u_gz_loanwage.billid = :arg_billid;
if sqlca.sqlcode <> 0 then
	rslt = 0
	arg_msg = "删除借支单操作失败"+"~n"+sqlca.sqlerrtext
	goto ext
end if

commit;
it_newbegin = false
it_updatebegin = false
ext:
if rslt = 0 then 
	rollback;
	p_reset()
end if


return (rslt)

end function

public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg);Int rslt = 1
arg_newdescppart = Trim(arg_newdescppart)

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	GOTO ext
END IF

IF it_newbegin OR it_updatebegin THEN
	rslt = 0
	arg_msg = "编辑状态下不可以执行,操作取消"
	GOTO ext
END IF

SELECT u_gz_loanwage.flag
	INTO :flag
	FROM u_gz_loanwage
	Where u_gz_loanwage.billid = :arg_billid;
IF sqlca.SQLCode <> 0  THEN
	rslt = 0
	arg_msg = '查询借支单操作失败'
	GOTO ext
END IF

IF flag = 0 THEN
	rslt = 0
	arg_msg = "非审核状态下不可用"
	GOTO ext
END IF

UPDATE u_gz_loanwage
	SET dscrp = dscrp+' '+:arg_newdescppart
	Where u_gz_loanwage.billid = :billid;
IF sqlca.SQLCode <> 0 THEN
	ROLLBACK ;
	rslt = 0
	arg_msg = "因网络或其它原因导致添加单据备注操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

COMMIT;
dscrp = dscrp+' '+arg_newdescppart

ext:
Return (rslt)


end function

public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
Decimal ls_emp_sumwage
datastore ds_emp_sumloanwage

//cnt = 0
//SELECT count(*) INTO :cnt
//	FROM u_gz_loanwage
//	WHERE  wagemth = :arg_wagemth
//	AND wageid = :arg_wageid
//	AND flag = 1;
//IF sqlca.SQLCode <> 0 THEN
//	rslt = 0
//	arg_msg = '查询借支单明细失败！原因：'+sqlca.SQLErrText
//	GOTO ext
//END IF
//
//IF cnt > 0 THEN
//	rslt = 0
//	arg_msg = '该月的借支单已审核,审核前请先执行撤审!'
//	GOTO ext
//END IF
//
cnt = 0
SELECT  count(*) INTO :cnt
	FROM u_gz_wageitem Where useflag = 1 AND wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

ds_emp_sumloanwage = CREATE datastore
ds_emp_sumloanwage.DataObject = 'dw_emp_sumloanwage'
ds_emp_sumloanwage.SetTransObject(sqlca)

IF ds_emp_sumloanwage.Retrieve(arg_wagemth,arg_wageid) <= 0 THEN
	rslt = 0
	arg_msg = '本月没有借支单可审核或查询借支单失败'
	GOTO ext
END IF

FOR i = 1 TO ds_emp_sumloanwage.RowCount()
	ls_emp_sumwage = 0.00
	ls_emp_sumwage = ds_emp_sumloanwage.Object.sumwage[i]
	IF u_wage.f_setwagemxdata(arg_wagemth,ds_emp_sumloanwage.Object.empid[i],arg_wageid,ls_emp_sumwage,arg_msg,FALSE) = 0 THEN
		rslt = 0
		GOTO ext
	END IF
NEXT

UPDATE u_gz_loanwage SET
	flag = 1,
	auditrep = :publ_operator,
	Auditdate = getdate(),
	wagemth = :arg_wagemth
	WHERE returndate = :arg_wagemth
	AND wageid = :arg_wageid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新借支单失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt

end function

public function integer auditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
Decimal ls_emp_sumwage

SELECT flag,returndate,wageid,empid,loanamt
	INTO :flag,:returndate,:wageid,:empid,:loanamt
	FROM u_gz_loanwage
	Where billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询单据内容失败'+sqlca.SQLErrText
	GOTO ext
END IF

IF flag = 1 THEN
	rslt = 0
	arg_msg = '单据已经审核,不能再审,请检查'
	GOTO ext
END IF

IF returndate = 0 THEN
	rslt = 0
	arg_msg = '请输入工资月份'
	GOTO ext
END IF

cnt = 0
SELECT  count(*) INTO :cnt
	FROM u_gz_wageitem Where useflag = 1 AND wageid = :wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF u_wage.f_setwagemxdata(returndate,empid,wageid,loanamt,arg_msg,FALSE) = 0 THEN
	rslt = 0
	GOTO ext
END IF

UPDATE u_gz_loanwage
	SET flag = 1,
	auditrep = :publ_operator,
	auditdate = getdate(),
	wagemth = returndate
	WHERE billid = :arg_billid
	AND flag = 0 ;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新借支单状态失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt


end function

public function integer cauditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
Decimal ls_emp_sumwage
DateTime ls_null
SetNull(ls_null)

SELECT flag,returndate,wageid,empid,loanamt
	INTO :flag,:returndate,:wageid,:empid,:loanamt
	FROM u_gz_loanwage
	Where billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询单据内容失败'+sqlca.SQLErrText
	GOTO ext
END IF

IF flag = 0 THEN
	rslt = 0
	arg_msg = '单据还未审核,不能撤审,请检查'
	GOTO ext
END IF

IF returndate = 0 THEN
	rslt = 0
	arg_msg = '请输入工资月份'
	GOTO ext
END IF

IF f_check_wage_audit(returndate,-1,arg_msg) = 0 THEN
	rslt = 0
	arg_msg = arg_msg + ',不能撤审'
	GOTO ext
END IF


//检查该月份,该工资项目是否已开工资变更单
cnt = 0

SELECT count(*)
	INTO :cnt
	FROM u_wage_change
	WHERE wageid = :wageid
	AND wagemth = :returndate;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询该月份该工资项目是否已开工资变更单失败'+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt > 0 THEN
	rslt = 0
	arg_msg = '该月份该工资项目已开工资变更单,不能撤审'
	GOTO ext
END IF


cnt = 0
SELECT  count(*) INTO :cnt
	FROM u_gz_wageitem Where useflag = 1 AND wageid = :wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF u_wage.f_setwagemxdata(returndate,empid,wageid,0 - loanamt,arg_msg,FALSE) = 0 THEN
	rslt = 0
	GOTO ext
END IF

UPDATE u_gz_loanwage
	SET flag = 0,
	auditrep = '',
	auditdate = :ls_null
	WHERE billid = :arg_billid
	AND flag = 1 ;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新借支单状态失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt


end function

on uo_loanwage.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_loanwage.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

event constructor; u_wage=create uo_wage
end event

event destructor;DESTROY u_wage
end event