$PBExportHeader$uo_award_punish.sru
forward
global type uo_award_punish from nonvisualobject
end type
end forward

global type uo_award_punish from nonvisualobject
end type
global uo_award_punish uo_award_punish

type variables
public protectedwrite long billid           //计件单自动增量id
public protectedwrite string billcode       //计件单的唯一编号
public protectedwrite datetime opdate       //建立时间,自动
public protectedwrite string opemp          //建立人
public protectedwrite datetime moddate       //修改时间,自动
public protectedwrite string modemp          //修改人
public protectedwrite int flag=0            //审核标志
public protectedwrite datetime auditingdate //审核时间
public protectedwrite string auditingrep    //审核操作员

int billtype
long empid          
datetime billdate  
decimal award_punish_amt     
long wageid         
string reason   
long deptid        
string rep='' 
long wagemth
decimal khqty

uo_wage u_wage

private:
boolean it_newbegin=false    //新建标志
boolean it_updatebegin=false//修改标志

end variables

forward prototypes
public function integer p_reset ()
public function integer newbegin (ref string arg_msg)
public function integer updatebegin (long arg_billid, ref string arg_msg)
public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer save (ref string arg_msg, boolean arg_ifcommit)
public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg)
public function integer auditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
public function integer cauditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit)
end prototypes

public function integer p_reset ();//INT p_RESET()
//清除对象及其明细
billtype = 0
billid=0
billcode=''
opemp=''
auditingrep=''
flag=0
empid=0  
award_punish_amt=0      
reason=''
wageid=0    
rep=''    
deptid=0
khqty = 0


it_newbegin=FALSE
it_updatebegin=FALSE
RETURN 1
end function

public function integer newbegin (ref string arg_msg);p_reset()
it_newbegin=TRUE
it_updatebegin=FALSE
return 1

end function

public function integer updatebegin (long arg_billid, ref string arg_msg);//====================================================================
// Function: updatebegin(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


Int rslt = 1

IF arg_billid <= 0 THEN
	billid = 0
	arg_msg = '错误的单据ID'
	GOTO ext
END IF

SELECT u_gz_award_punish.billcode,
u_gz_award_punish.billdate,
u_gz_award_punish.wagemth,
u_gz_award_punish.wageid,
u_gz_award_punish.empid,
u_gz_award_punish.award_punish_amt,
u_gz_award_punish.reason,
u_gz_award_punish.deptid,
u_gz_award_punish.rep,
u_gz_award_punish.billtype,
u_gz_award_punish.flag,
u_gz_award_punish.khqty
Into :billcode,
:billdate,
:wagemth,
:wageid,
:empid,
:award_punish_amt,
:reason,
:deptid,
:rep,
:billtype,
:flag,
:khqty
From u_gz_award_punish 
Where u_gz_award_punish.billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询数据操作失败,奖罚单'+sqlca.SQLErrText
	GOTO ext
END IF

IF flag = 1 THEN
	rslt = 0
	arg_msg = '单据已经审核,不可以修改'
	GOTO ext
END IF

billid = arg_billid

it_newbegin = False
it_updatebegin = True

ext:
IF  rslt = 0 THEN p_reset()
RETURN rslt



end function

public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
DateTime null_server_dt
SetNull(null_server_dt)

IF f_check_wage_audit(arg_wagemth,-1,arg_msg) = 0 THEN
	rslt = 0
	arg_msg = arg_msg + ',不能撤审'
	GOTO ext
END IF

//检查该月份,该工资项目是否已开工资变更单
cnt = 0

SELECT count(*)
	INTO :cnt
	FROM u_wage_change
	WHERE wageid = :arg_wageid
	AND wagemth = :arg_wagemth;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询该月份该工资项目是否已开工资变更单失败'+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt > 0 THEN
	rslt = 0
	arg_msg = '该月份该工资项目已开工资变更单,不能撤审'
	GOTO ext
END IF


SELECT count(*) INTO :cnt
	FROM u_gz_award_punish
	WHERE wagemth = :arg_wagemth
	AND wageid = :arg_wageid
	AND flag = 1;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询奖罚单失败,原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '该月的奖罚单未审核,不用撤审!'
	GOTO ext
END IF

cnt = 0
SELECT  count(*) INTO :cnt FROM u_gz_wageitem Where useflag = 1 AND wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败,原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目,原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF u_wage.f_wage_clear(arg_wageid,arg_wagemth,arg_msg,FALSE) = 0 THEN
	rslt = 0
	GOTO ext
END IF

UPDATE u_gz_award_punish SET
	flag = 0,
	Auditrep = '',
	Auditdate = :null_server_dt
	Where  wagemth = :arg_wagemth AND flag = 1 AND  wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新奖罚单失败，原因：'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF  rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt

end function

public function integer save (ref string arg_msg, boolean arg_ifcommit);//====================================================================
// Function: save(arg_msg,arg_ifcommit)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		reference	string 	arg_msg     		
//		value    	boolean	arg_ifcommit		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


Integer rslt = 1,cnt = 0,i
DateTime server_dt
Long ls_newid

IF IsNull(empid)	 THEN empid = 0
IF IsNull(award_punish_amt)	 THEN award_punish_amt = 0
IF IsNull(wageid)	 THEN wageid = 0
IF IsNull(wagemth)	 THEN wagemth = 0
IF IsNull(reason)	 THEN reason = ''
IF IsNull(deptid)	 THEN deptid = 0
IF IsNull(rep)	 THEN rep = ''
IF IsNull(billtype)	 THEN billtype = 0


IF it_newbegin = FALSE AND it_updatebegin = FALSE THEN
	rslt = 0
	arg_msg = "非编辑状态不可以提交"
	GOTO ext
END IF

IF billtype = 0 THEN
	arg_msg = '单据类形错误,1-奖单,2-罚单'
	rslt = 0
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM u_rs_empinfo
	Where empid = :empid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询员工资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt = 0 THEN
	arg_msg = '没有选择员工或没有该员工资料'
	rslt = 0
	GOTO ext
ELSEIF cnt > 1 THEN
	arg_msg = '员工资料重复'
	rslt = 0
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM u_gz_wageitem
	Where wageid = :wageid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询工资项目资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt > 1 THEN
	arg_msg = '工资项目重复'
	rslt = 0
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM cw_department
	Where  departmentid = :deptid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询部门资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt > 1 THEN
	arg_msg = '部门资料重复'
	rslt = 0
	GOTO ext
END IF

IF wagemth = 0 THEN
	arg_msg = '错误的工资月份'
	rslt = 0
	GOTO ext
END IF



IF award_punish_amt < 0 THEN
	arg_msg = '请输入正确的金额'
	rslt = 0
	GOTO ext
END IF

SELECT Top 1 getdate() INTO :server_dt FROM u_user;
//取得系统时间,借用操作员表
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	GOTO ext
END IF

//IF f_check_inoutdate(0,billdate,FALSE,arG_MSG) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF

////////////////////////////////////////////// //开始区分:新建/更新 处理
IF billid = 0 THEN //新建
	ls_newid = f_sys_scidentity(0,"u_gz_award_punish","billid",arg_msg,TRUE,id_sqlca)
	IF ls_newid <= 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	
	billcode = getid(0,"JF",Date(server_dt),TRUE,sqlca) //取得新单据编号
	IF billcode = "err" THEN
		billcode = ''
		rslt = 0
		arg_msg = "无法获取单据编号"
		GOTO ext
	END IF
	
	INSERT INTO u_gz_award_punish (
		billid,
		billcode,
		billdate,
		Wagemth,
		wageid,
		empid,
		award_punish_amt,
		reason,
		deptid,
		rep,
		billtype,
		opdate,
		opemp,
		khqty)
		VALUES (
		:ls_newid,
		:billcode,
		:billdate,
		:Wagemth,
		:wageid,
		:empid,
		:award_punish_amt,
		:reason,
		:deptid,
		:rep,
		:billtype,
		:server_dt,
		:publ_operator,
		:khqty);
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致插入操作失败>>"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	billid = ls_newid
ELSE //////////////////////////////////////////////// //更新
	
	UPDATE u_gz_award_punish
		SET billdate = :billdate,
		wageid = :wageid,
		empid = :empid,
		award_punish_amt = :award_punish_amt,
		reason = :reason,
		deptid = :deptid,
		rep = :rep,
		moddate = :server_dt,
		modemp = :modemp,
		billtype = :billtype,
		Wagemth = :Wagemth,
		khqty = :khqty
		WHERE u_gz_award_punish.billid = :billid
		AND flag = 0;
	IF sqlca.SQLCode <> 0 OR sqlca.SQLNRows <= 0 THEN
		rslt = 0
		arg_msg = "因网络或其它原因导致更新单据操作失败"+"~n"+sqlca.SQLErrText
		GOTO ext
	END IF
	
	
END IF

it_newbegin = FALSE
it_updatebegin = FALSE

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
Return(rslt)




end function

public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
Decimal ls_emp_sumwage
datastore ds_emp_sumwage

//cnt = 0
//SELECT count(*) INTO :cnt
//	FROM u_gz_award_punish
//	WHERE  wagemth = :arg_wagemth
//	AND wageid = :arg_wageid
//	AND flag = 1;
//IF sqlca.SQLCode <> 0 THEN
//	rslt = 0
//	arg_msg = '查询奖罚单明细失败!原因：'+sqlca.SQLErrText
//	GOTO ext
//END IF
//
//IF cnt > 0 THEN
//	rslt = 0
//	arg_msg = '该月的奖罚单已审核,审核前请先执行撤审!'
//	GOTO ext
//END IF

cnt = 0
SELECT  count(*) INTO :cnt
	FROM u_gz_wageitem Where useflag = 1 AND wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

ds_emp_sumwage = CREATE datastore
ds_emp_sumwage.DataObject = 'dw_emp_sumawardpunishwage'
ds_emp_sumwage.SetTransObject(sqlca)

IF ds_emp_sumwage.Retrieve(arg_wagemth,arg_wageid) <= 0 THEN
	rslt = 0
	arg_msg = '本月没有奖罚单可审核或查询奖罚单失败'
	GOTO ext
END IF

FOR i = 1 TO ds_emp_sumwage.RowCount()
	ls_emp_sumwage = 0.00
	ls_emp_sumwage = ds_emp_sumwage.Object.sumwage[i]
	IF u_wage.f_setwagemxdata(arg_wagemth,ds_emp_sumwage.Object.empid[i],arg_wageid,ls_emp_sumwage,arg_msg,FALSE) = 0 THEN
		rslt = 0
		GOTO ext
	END IF
NEXT

UPDATE u_gz_award_punish SET
	flag = 1,
	auditrep = :publ_operator,
	Auditdate = getdate()
	WHERE wagemth = :arg_wagemth
	AND wageid = :arg_wageid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新奖罚单失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt

end function

public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg);//====================================================================
// Function: add_dscrp(arg_billid,arg_newdescppart,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid      		
//		value    	string	arg_newdescppart		
//		reference	string	arg_msg         		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


Int rslt = 1
arg_newdescppart = Trim(arg_newdescppart)

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	GOTO ext
END IF

IF it_newbegin OR it_updatebegin THEN
	rslt = 0
	arg_msg = "编辑状态下不可以执行,操作取消"
	GOTO ext
END IF

SELECT u_gz_award_punish.flag
	INTO :flag
	FROM u_gz_award_punish
	Where u_gz_award_punish.billid = :arg_billid;
IF sqlca.SQLCode <> 0  THEN
	rslt = 0
	arg_msg = '查询奖罚单操作失败'
	GOTO ext
END IF

IF flag = 0 THEN
	rslt = 0
	arg_msg = "非审核状态下不可用"
	GOTO ext
END IF

UPDATE u_gz_award_punish
	SET reason = reason+' '+:arg_newdescppart
	Where u_gz_award_punish.billid = :billid;
IF sqlca.SQLCode <> 0 THEN
	ROLLBACK ;
	rslt = 0
	arg_msg = "因网络或其它原因导致添加单据备注操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

COMMIT;
reason = reason+' '+arg_newdescppart

ext:
Return (rslt)


end function

public function integer auditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
Decimal ls_emp_sumwage

SELECT flag,wagemth,wageid,empid,award_punish_amt,billtype
	INTO :flag,:wagemth,:wageid,:empid,:award_punish_amt,:billtype
	FROM u_gz_award_punish
	Where billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询单据内容失败'+sqlca.SQLErrText
	GOTO ext
END IF

IF flag = 1 THEN
	rslt = 0
	arg_msg = '单据已经审核,不能再审,请检查'
	GOTO ext
END IF

IF wagemth = 0 THEN
	rslt = 0
	arg_msg = '请输入工资月份'
	GOTO ext
END IF

cnt = 0
SELECT  count(*) INTO :cnt
	FROM u_gz_wageitem Where useflag = 1 AND wageid = :wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF u_wage.f_setwagemxdata(wagemth,empid,wageid,award_punish_amt * billtype,arg_msg,FALSE) = 0 THEN
	rslt = 0
	GOTO ext
END IF

UPDATE u_gz_award_punish
	SET flag = 1,
	auditrep = :publ_operator,
	auditdate = getdate()
	WHERE billid = :arg_billid
	AND flag = 0 ;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新奖罚单状态失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt


end function

public function integer cauditmx (long arg_billid, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
Decimal ls_emp_sumwage
DateTime ls_null
SetNull(ls_null)

SELECT flag,wagemth,wageid,empid,award_punish_amt,billtype
	INTO :flag,:wagemth,:wageid,:empid,:award_punish_amt,:billtype
	FROM u_gz_award_punish
	Where billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询单据内容失败'+sqlca.SQLErrText
	GOTO ext
END IF

IF flag = 0 THEN
	rslt = 0
	arg_msg = '单据还未审核,不能撤审'
	GOTO ext
END IF

IF wagemth = 0 THEN
	rslt = 0
	arg_msg = '请输入工资月份'
	GOTO ext
END IF

IF f_check_wage_audit(wagemth,-1,arg_msg) = 0 THEN
	rslt = 0
	arg_msg = arg_msg + ',不能撤审'
	GOTO ext
END IF


//检查该月份,该工资项目是否已开工资变更单
cnt = 0

SELECT count(*)
	INTO :cnt
	FROM u_wage_change
	WHERE wageid = :wageid
	AND wagemth = :wagemth;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询该月份该工资项目是否已开工资变更单失败'+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt > 0 THEN
	rslt = 0
	arg_msg = '该月份该工资项目已开工资变更单,不能撤审'
	GOTO ext
END IF

cnt = 0
SELECT  count(*) INTO :cnt
	FROM u_gz_wageitem Where useflag = 1 AND wageid = :wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目!原因>>'+sqlca.SQLErrText
	GOTO ext
END IF

IF u_wage.f_setwagemxdata(wagemth,empid,wageid,0 - award_punish_amt * billtype,arg_msg,FALSE) = 0 THEN
	rslt = 0
	GOTO ext
END IF

UPDATE u_gz_award_punish
	SET flag = 0,
	auditdate = :ls_null,
	auditrep = ''
	WHERE billid = :arg_billid
	AND flag = 1 ;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新奖罚单状态失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
RETURN rslt


end function

public function integer del (long arg_billid, ref string arg_msg, boolean arg_ifcommit);//====================================================================
// Function: del(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================

int rslt = 1
if arg_billid <= 0 then
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	goto ext
end if

if it_newbegin or it_updatebegin then
	rslt=0
   arg_msg="编辑状态下不可以执行,操作取消"
	goto ext
end if

select u_gz_award_punish.flag
	into :flag
	from u_gz_award_punish
	where u_gz_award_punish.billid = :arg_billid;
if sqlca.sqlcode <> 0  then
	rslt = 0
	arg_msg = '查询奖罚单操作失败'
	goto ext
end if

if flag = 1 then
	rslt = 0
	arg_msg = "单据已经审核,不可以删除"
	goto ext
end if

delete from u_gz_award_punish where u_gz_award_punish.billid = :arg_billid;
if sqlca.sqlcode <> 0 then
	rslt = 0
	arg_msg = "删除奖罚单操作失败"+"~n"+sqlca.sqlerrtext
	goto ext
end if

ext:

IF rslt = 0 THEN
	ROLLBACK ;
	p_reset()
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT ;
END IF

Return (rslt)


end function

on uo_award_punish.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_award_punish.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

event constructor; u_wage=create uo_wage
end event

event destructor;DESTROY u_wage
end event