Q5/ws_objects/Ew_sale.pbl.src/w_reissue.srw

$PBExportHeader$w_reissue.srw
forward
global type w_reissue from w_publ_1ton_share_detail
end type
type ddlb_scid from uo_ddlb_scid within w_reissue
end type
type ddlb_status from dropdownlistbox within w_reissue
end type
type st_3 from statictext within w_reissue
end type
type st_2 from statictext within w_reissue
end type
end forward

global type w_reissue from w_publ_1ton_share_detail
string title = "客户费用单"
boolean maxbox = true
windowstate windowstate = maximized!
event insert_childrow ( )
ddlb_scid ddlb_scid
ddlb_status ddlb_status
st_3 st_3
st_2 st_2
end type
global w_reissue w_reissue

type variables
uo_reissue uo_ware

Long cur_scid
Long cur_scid_arr[]

Long cur_flag = -1


uo_ljfieb uo_fieb
end variables

forward prototypes
public function integer wf_flagstatus_rf ()
public function integer wf_refresh_curuc (long arg_scid, long arg_reissueid)
public function integer wf_addmx (long arg_scid, long arg_outwareid, ref string arg_msg)
public function integer wf_adduc (long arg_scid, long arg_outwareid, ref string arg_msg)
public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg)
public function integer wf_adduc_saletask (long arg_scid, long arg_taskid, ref string arg_msg)
public function integer wf_addmx_saletask (long arg_scid, long arg_taskid, ref string arg_msg)
end prototypes

event insert_childrow();Long li_row
li_row = dw_child.InsertRow(0)
dw_child.ScrollToRow(li_row)
dw_child.SetColumn ('u_expenses_expensescode')

end event

public function integer wf_flagstatus_rf ();Long pagerert_row

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	cb_auditing.Enabled = FALSE
	cb_auditing_cancel.Enabled = FALSE
	GOTO ext
END IF

IF dw_edit_mode THEN
	cb_auditing.Enabled = FALSE
	cb_auditing_cancel.Enabled = FALSE
ELSE
	IF dw_pageretr.Object.flag[pagerert_row] = 0 THEN
		cb_auditing.Enabled = TRUE
		cb_auditing_cancel.Enabled = FALSE
	ELSEIF dw_pageretr.Object.flag[pagerert_row] = 1 THEN
		cb_auditing.Enabled = FALSE
		cb_auditing_cancel.Enabled = TRUE
	END IF
END IF

ext:
RETURN 0

end function

public function integer wf_refresh_curuc (long arg_scid, long arg_reissueid);IF arg_reissueid <= 0 OR IsNull(arg_reissueid) THEN RETURN 0
Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN RETURN 0

Long     cusid
DateTime reissuedate
String   dscrp
String   reissuecode
DateTime opdate
String   operator
Int     flag
DateTime auditingdate  ,moddate
String   Auditingrep  ,modemp
String relcode
Long relid,moneyid
Long r_type
string reissueemp,cusname,cuscode
long ll_printnum
long itemid
string ls_itemcode,ls_itemname
Decimal mrate

SELECT u_reissue.reissuecode,
	u_reissue.cusid,
	u_reissue.reissuedate,
	u_reissue.relid,
	u_reissue.relcode,
	u_reissue.dscrp,
	u_reissue.opemp,
	u_reissue.opdate,
	u_reissue.modemp,
	u_reissue.moddate,
	u_reissue.auditingrep,
	u_reissue.auditingdate,
	u_reissue.flag ,
	u_reissue.type,
	u_reissue.moneyid,
	u_reissue.mrate,
	u_reissue.reissueemp,
	u_reissue.printnum  ,
	u_cust.name,
	u_cust.cuscode,
u_reissue.itemid,
	u_itemdef.itemcode,
	u_itemdef.itemname
	INTO	:reissuecode,
	:cusid,
	:reissuedate,
	:relid,
	:relcode,
	:dscrp,
	:operator,
	:opdate,
	:modemp,
	:moddate,
	:Auditingrep,
	:Auditingdate,
	:flag,
	:r_type,
	:moneyid,
	:mrate,
	:reissueemp,
	:ll_printnum,
	:cusname,
	:cuscode,
	:itemid,
	:ls_itemcode,
	:ls_itemname
 FROM u_reissue LEFT OUTER JOIN
	u_itemdef ON u_reissue.itemid = u_itemdef.itemid LEFT OUTER JOIN
	u_cust ON u_reissue.cusid = u_cust.cusid 
	WHERE ( u_reissue.reissueid = :arg_reissueid )  AND
	( u_reissue.scid = :arg_scid);
IF sqlca.SQLCode <> 0 THEN
	MessageBox('错误',"查询操作失败(错误单据唯一码)",stopsign!,OK!)
	RETURN 0
END IF
dw_pageretr.Object.scid[uc_row] = arg_scid
dw_pageretr.Object.reissueid[uc_row] = arg_reissueid
dw_pageretr.Object.reissuedate[uc_row] = reissuedate
dw_pageretr.Object.dscrp[uc_row] =  dscrp
dw_pageretr.Object.reissuecode[uc_row] = reissuecode
dw_pageretr.Object.opdate[uc_row] =  opdate
dw_pageretr.Object.opemp[uc_row] = operator
dw_pageretr.Object.flag[uc_row] = flag
dw_pageretr.Object.relid[uc_row] = relid
dw_pageretr.Object.relcode[uc_row] = relcode
dw_pageretr.Object.auditingdate[uc_row] = auditingdate
dw_pageretr.Object.Auditingrep[uc_row] = Auditingrep
dw_pageretr.Object.cusid[uc_row] = cusid
dw_pageretr.Object.moddate[uc_row] = moddate
dw_pageretr.Object.modemp[uc_row] = modemp
dw_pageretr.Object.TYPE[uc_row] = r_type
dw_pageretr.Object.moneyid[uc_row] = moneyid

dw_pageretr.Object.reissueemp[uc_row] = reissueemp
dw_pageretr.Object.printnum[uc_row] = printnum
dw_pageretr.Object.u_cust_cuscode[uc_row] = cuscode
dw_pageretr.Object.u_cust_name[uc_row] = cusname

dw_pageretr.Object.u_itemdef_itemcode[uc_row] = ls_itemcode
dw_pageretr.Object.u_itemdef_itemname[uc_row] = ls_itemname
dw_pageretr.Object.u_reissue_itemid[uc_row] = itemid
dw_pageretr.Object.u_reissue_mrate[uc_row] = mrate

dw_uc.Reset()
dw_pageretr.RowsCopy(dw_pageretr.GetRow(), dw_pageretr.GetRow(), Primary!, dw_uc, 1, Primary!)


dw_uc.ResetUpdate()
dw_uc.SetRedraw(TRUE)


wf_flagstatus_rf()
RETURN 1

end function

public function integer wf_addmx (long arg_scid, long arg_outwareid, ref string arg_msg);//wf_saletaskmtrltoarr(long arg_taskid,ref s_saletask_mtrl arg_s_rqmtrl[],ref long arg_p_rqmtrl,ref string arg_msg)
//查询合同物料资料
//把物料资料写入数组

long rslt=1
long ls_mtrlid
string ls_mtrlcode,ls_mtrlname

dec ls_qty
Long child_row

child_row = dw_child.GetRow()
//查询合同物料
DECLARE pf_cur CURSOR FOR 
SELECT u_mtrldef.mtrlid AS mtrlid, u_mtrldef.mtrlcode AS mtrlcode, 
      u_mtrldef.mtrlname AS mtrlname,u_outwaremx.qty
FROM u_outwaremx INNER JOIN
      u_mtrldef ON u_outwaremx.mtrlid = u_mtrldef.mtrlid
  WHERE ( u_outwaremx.outwareid = :arg_outwareid )
   and ( u_outwaremx.scid = :arg_scid ); 
open pf_cur;

fetch pf_cur into :ls_mtrlid,:ls_mtrlcode,:ls_mtrlname,:ls_qty;
do while sqlca.sqlcode=0	
	IF dw_child.GetRow() > 0 THEN
		IF dw_child.Object.mtrlid[child_row] <> 0 THEN
			child_row = dw_child.InsertRow (0)
		ELSE
			child_row = dw_child.GetRow()
		END IF
	ELSE
		child_row = dw_child.InsertRow (0)
	END IF
	
	dw_child.object.mtrlid[child_row]=ls_mtrlid
	dw_child.object.mtrlcode[child_row]=ls_mtrlcode
	dw_child.object.mtrlname[child_row]=ls_mtrlname
	dw_child.object.qty[child_row]=ls_qty
	fetch pf_cur into :ls_mtrlid,:ls_mtrlcode,:ls_mtrlname,:ls_qty;
loop

close pf_cur;
dw_child.accepttext()
return rslt
end function

public function integer wf_adduc (long arg_scid, long arg_outwareid, ref string arg_msg);//wf_saletaskmtrltoarr(long arg_taskid,ref s_saletask_mtrl arg_s_rqmtrl[],ref long arg_p_rqmtrl,ref string arg_msg)
//查询合同物料资料
//把物料资料写入数组

long rslt=1
long ls_cusid
string ls_cuscode,ls_cusname,ls_relcode
long li_row
SELECT u_cust.cusid, u_cust.cuscode, u_cust.name,u_outware.outwarecode
into :ls_cusid,:ls_cuscode,:ls_cusname,:ls_relcode
FROM u_outware INNER JOIN
      u_cust ON u_outware.cusid = u_cust.cusid
where u_outware.outwareid=:arg_outwareid and
		u_outware.scid=:arg_scid using sqlca;

if sqlca.sqlcode<>0 then
	rslt=0
	arg_msg="查询操作失败，销售单客户"
	goto ext
end if
dw_uc.object.cusid[dw_uc.getrow()]=ls_cusid
dw_uc.object.cuscode[dw_uc.getrow()]=ls_cuscode
dw_uc.object.cusname[dw_uc.getrow()]=ls_cusname
dw_uc.object.relid[dw_uc.getrow()]=arg_outwareid
dw_uc.object.relcode[dw_uc.getrow()]=ls_relcode

dw_uc.accepttext()

wf_addmx(arg_scid,arg_outwareid,arg_msg)
ext:
return rslt
end function

public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg);//==============================================================================
// 函数: w_publ_1ton_share_detail::wf_xls_retrievedata()
//------------------------------------------------------------------------------
// 描述:  此函数需要 重载,复制祖先范例代码,然后修改retrieve参数部分两处即可
//------------------------------------------------------------------------------

Long LS_ROW,ll_id,i,ll_scid
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	arg_msg = '没有目标单据!'
	RETURN 0
END IF

//修改点:获取 指定retriev参数
ll_id = dw_pageretr.Object.#1[LS_ROW]
ll_scid = dw_pageretr.Object.scid[LS_ROW]


////可选设置///
arg_obj_st.uo_const.create_new_pwd( )  //创建随机密码 
if sys_option_xls_ifuse_passwd = 1 then arg_obj_st.uo_const.pwd = trim(sys_option_xls_user_passwd)   //默认加密密码    默认为随即密码


boolean xls_locked
xls_locked = not (sys_option_xls_lock = 1)

/// Excel 的可选设置
if arg_obj_st.of_setoption(arg_ationid,  xls_locked,true,arg_msg) <> 1 then
		return 0
end if


for i = 1 to arg_str_billlist.count
	////可选操作///
	arg_str_billlist.bill[i].ds_data = create datastore                                  //
	arg_str_billlist.bill[i].ds_data.dataobject = arg_str_billlist.bill[i].datawindow       //
	arg_str_billlist.bill[i].ds_data.settransobject(sqlca)
	
	//修改点:注意retrieve 参数与上文对应
	arg_str_billlist.bill[i].ds_data.retrieve(ll_scid,ll_id)

next 

return 1
end function

public function integer wf_adduc_saletask (long arg_scid, long arg_taskid, ref string arg_msg);//wf_saletaskmtrltoarr(long arg_taskid,ref s_saletask_mtrl arg_s_rqmtrl[],ref long arg_p_rqmtrl,ref string arg_msg)
//查询合同物料资料
//把物料资料写入数组

Long rslt = 1
Long ls_cusid
String ls_cuscode,ls_cusname,ls_relcode
Long li_row
long ll_moneyid, ll_banktypeid

SELECT u_cust.cusid, u_cust.cuscode, u_cust.name,u_saletask.taskcode,u_saletask.moneyid,u_saletask.banktypeid
	INTO :ls_cusid,:ls_cuscode,:ls_cusname,:ls_relcode,:ll_moneyid, :ll_banktypeid
	FROM u_saletask INNER JOIN
	u_cust ON u_saletask.cusid = u_cust.cusid
	WHERE u_saletask.taskid = :arg_taskid AND
	u_saletask.scid = :arg_scid Using sqlca;
	
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败，销售单客户"
	GOTO ext
END IF
dw_uc.Object.cusid[dw_uc.GetRow()] = ls_cusid
dw_uc.Object.u_cust_cuscode[dw_uc.GetRow()] = ls_cuscode
dw_uc.Object.u_cust_name[dw_uc.GetRow()] = ls_cusname
//dw_uc.Object.relid[dw_uc.GetRow()] = arg_taskid
dw_uc.Object.relcode[dw_uc.GetRow()] = ls_relcode
dw_uc.Object.moneyid[dw_uc.GetRow()] = ll_moneyid
dw_uc.Object.relid[dw_uc.GetRow()] = ll_banktypeid

dw_uc.AcceptText()

//wf_addmx_saletask(arg_scid,arg_taskid,arg_msg)
ext:
RETURN rslt

end function

public function integer wf_addmx_saletask (long arg_scid, long arg_taskid, ref string arg_msg);//wf_saletaskmtrltoarr(long arg_taskid,ref s_saletask_mtrl arg_s_rqmtrl[],ref long arg_p_rqmtrl,ref string arg_msg)
//查询合同物料资料
//把物料资料写入数组

Long rslt = 1
Long ls_mtrlid
String ls_mtrlcode,ls_mtrlname

Dec ls_qty
Long child_row

child_row = dw_child.GetRow()
//查询合同物料
DECLARE pf_cur CURSOR FOR
	SELECT u_mtrldef.mtrlid AS mtrlid, u_mtrldef.mtrlcode AS mtrlcode,
	u_mtrldef.mtrlname AS mtrlname,u_saletaskmx.qty
	FROM u_saletaskmx INNER JOIN
	u_mtrldef ON u_saletaskmx.mtrlid = u_mtrldef.mtrlid
	WHERE ( u_saletaskmx.taskid = :arg_taskid )
	And ( u_saletaskmx.scid = :arg_scid );
OPEN pf_cur;

FETCH pf_cur Into :ls_mtrlid,:ls_mtrlcode,:ls_mtrlname,:ls_qty;
DO WHILE sqlca.SQLCode = 0
	IF dw_child.GetRow() > 0 THEN
		IF dw_child.Object.mtrlid[child_row] <> 0 THEN
			child_row = dw_child.InsertRow (0)
		ELSE
			child_row = dw_child.GetRow()
		END IF
	ELSE
		child_row = dw_child.InsertRow (0)
	END IF
	
	dw_child.Object.mtrlid[child_row] = ls_mtrlid
	dw_child.Object.u_expenses_expensescode[child_row] = ls_mtrlcode
	dw_child.Object.u_expenses_expensesname[child_row] = ls_mtrlname
	dw_child.Object.qty[child_row] = ls_qty
	FETCH pf_cur Into :ls_mtrlid,:ls_mtrlcode,:ls_mtrlname,:ls_qty;
LOOP

CLOSE pf_cur;
dw_child.AcceptText()
RETURN rslt

end function

on w_reissue.create
int iCurrent
call super::create
this.ddlb_scid=create ddlb_scid
this.ddlb_status=create ddlb_status
this.st_3=create st_3
this.st_2=create st_2
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.ddlb_scid
this.Control[iCurrent+2]=this.ddlb_status
this.Control[iCurrent+3]=this.st_3
this.Control[iCurrent+4]=this.st_2
end on

on w_reissue.destroy
call super::destroy
destroy(this.ddlb_scid)
destroy(this.ddlb_status)
destroy(this.st_3)
destroy(this.st_2)
end on

event retrieve_pageretr;Boolean cb_nextpage_enabled,cb_retrieveall_enabled
Boolean cb_func_enabled,cb_retrieve_enabled

cb_nextpage_enabled = cb_nextpage.Enabled
cb_retrieveall_enabled = cb_retrieveall.Enabled
cb_func_enabled = cb_func.Enabled

cb_nextpage.Enabled = FALSE
cb_retrieveall.Enabled = FALSE
cb_func.Enabled = FALSE

Int li_option_outrep, li_option_area
IF sys_power_issuper THEN
	li_option_outrep = 0
ELSE
	li_option_outrep = sys_option_outrep
END IF
IF sys_power_issuper THEN
	li_option_area = 0
ELSE
	li_option_area = sys_option_cusarea
END IF

dw_uc.Retrieve()
dw_pageretr.Retrieve(cur_scid_arr,cur_flag,sys_areaid,li_option_area)
IF dw_pageretr.RowCount() > 0 THEN 
	dw_pageretr.SetRow(1)
	dw_pageretr.triggerevent(rowfocuschanged!)
end if

wf_flagstatus_rf()
THIS.TriggerEvent('retrieve_childdw')


cb_nextpage.Enabled = cb_nextpage_enabled
cb_retrieveall.Enabled = cb_retrieveall_enabled
cb_func.Enabled = cb_func_enabled


end event

event ue_usual_query_filt;call super::ue_usual_query_filt;String obj_expr = ''
IF Trim(sle_usual_query.Text) <> '' THEN
	IF Pos(Trim(sle_usual_query.Text),'%') = 0 THEN
		obj_expr = obj_expr+'( reissuecode LIKE "%'+Trim(sle_usual_query.Text)+'%" )'
		obj_expr = obj_expr+' or ( relcode LIKE "%'+Trim(sle_usual_query.Text)+'%" )'
	ELSE
		obj_expr = obj_expr+'( reissuecode LIKE "'+Trim(sle_usual_query.Text)+'" )'
		obj_expr = obj_expr+' or ( relcode LIKE "'+Trim(sle_usual_query.Text)+'" )'
	END IF
END IF

dw_pageretr.SetFilter(obj_expr)

dw_pageretr.SetRedraw(False)
dw_pageretr.Filter()
IF dw_pageretr.RowCount() >= 1 THEN
	dw_pageretr.SelectRow(0,False)
	dw_pageretr.SetRow(1)
	dw_pageretr.SelectRow(1,True)
END IF
dw_pageretr.TriggerEvent(RowFocusChanged!)
dw_pageretr.SetRedraw(True)

end event

event ue_usual_query_retr;call super::ue_usual_query_retr;String ls_querystrpart = ''
ls_newselect = Lower(ori_oldselect)
IF Trim(sle_usual_query.Text) <> '' THEN
	IF Pos(Trim(sle_usual_query.Text),'%') = 0 THEN
		ls_querystrpart = "(u_reissue.reissuecode like '%"+Trim(sle_usual_query.Text)+"%')"
		ls_querystrpart += " or (u_reissue.relcode like '%"+Trim(sle_usual_query.Text)+"%')"
	ELSE
		ls_querystrpart = "(u_reissue.reissuecode like '"+Trim(sle_usual_query.Text)+"')"
		ls_querystrpart += " or (u_reissue.relcode like '"+Trim(sle_usual_query.Text)+"')"
	END IF
	
	IF Pos(ls_newselect," where ") <> 0 THEN
		ls_newselect = ls_newselect+" AND ("+ls_querystrpart+')'
	ELSE
		ls_newselect = ls_newselect+" where ("+ls_querystrpart+')'
	END IF
END IF
wf_retrieveuc(dw_pageretr,ls_newselect,1)
This.TriggerEvent('retrieve_pageretr')


end event

event open;call super::open;uc_column_int = 10 //uc dw前7列可以编辑
child_column_int = 4 //子dw前8列可以编辑

uo_ware = CREATE uo_reissue
uo_ware.commit_transaction = sqlca

uo_fieb = create uo_ljfieb
uo_fieb.commit_transaction = sys_email_sqlca


IF s_tran.d_long = 1 THEN
	cur_scid =  s_tran.c_long
	Int li_item
	li_item = ddlb_scid.FindItem(s_tran.d_string,0)
	IF li_item > 0 THEN
		ddlb_scid.SelectItem(li_item)
	END IF
	String arg_msg
	cb_add.TriggerEvent(Clicked!)
	IF dw_uc.GetRow() > 0 THEN
		IF s_tran.e_long > 0 THEN
			String ls_cuscode,ls_cusname
			SELECT cuscode,name
				INTO :ls_cuscode,:ls_cusname
				FROM u_cust
				Where cusid = :s_tran.e_long;
			IF sqlca.SQLCode = 0 THEN
				dw_uc.Object.cusid[dw_uc.GetRow()] = s_tran.e_long
				dw_uc.Object.u_cust_name[dw_uc.GetRow()] = ls_cusname
				dw_uc.Object.u_cust_cuscode[dw_uc.GetRow()] = ls_cuscode
			END IF
		END IF
	END IF
END IF


end event

event refresh_interface;call super::refresh_interface;ddlb_status.Enabled = NOT dw_edit_mode
ddlb_scid.Enabled = NOT dw_edit_mode


end event

event close;call super::close;destroy uo_ware

end event

event ue_f8;call super::ue_f8;//用于选择明细内容,被F8[默认]\dw_child.doubleclicked调用
IF NOT dw_edit_mode THEN RETURN

Long child_row

child_row = dw_child.GetRow()

IF NOT IsValid(w_expensesdef) THEN
	s_edit_index_tran s_ch_tran //传递参数使用
	s_ch_tran.if_retrieve_all = FALSE //是否一次RETRIEVE所有行
	s_ch_tran.work_mode = 1 //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid = 0 //目标定位PKID (备用)
	s_ch_tran.arg_string_code = '' //查询列(物料编码)部分内容,用于初步筛选
	s_ch_tran.if_select_all = TRUE
	s_ch_tran.b_long = -1
	
	Long chc = 1,ls_j
	dw_child.AcceptText()
	IF dw_child.GetRow() > 0 THEN s_ch_tran.arg_string_code = Trim(dw_child.Object.u_expenses_expensescode[dw_child.GetRow()])
	
	OpenWithParm(w_expensesdef,s_ch_tran)
	
	
	s_mtrldef_array S_INSCUST
	S_INSCUST = Message.PowerObjectParm
	FOR ls_j = 1 TO  UpperBound(S_INSCUST.mtrlid)
		IF S_INSCUST.mtrlid[ls_j] > 0 THEN
			IF dw_child.GetRow() > 0 THEN
				IF dw_child.Object.mtrlid[child_row] <> 0 THEN
					child_row = dw_child.InsertRow (0)
				ELSE     
					child_row = dw_child.GetRow()
				END IF
			ELSE
				child_row = dw_child.InsertRow (0)
			END IF
			dw_child.Object.mtrlid[child_row] = S_INSCUST.mtrlid[ls_j]
			dw_child.Object.u_expenses_expensescode[child_row] = S_INSCUST.mtrlcode[ls_j]
			dw_child.Object.u_expenses_expensesname[child_row] = S_INSCUST.mtrlname[ls_j]
			dw_child.Object.qty[child_row]   = 1
		END IF
	NEXT
	dw_child.SetFocus()
END IF



end event

event retrieve_childdw;call super::retrieve_childdw;Long row,uc_relid,uc_scid
row = dw_pageretr.GetRow()

IF row > 0 THEN
	uc_relid = dw_pageretr.Object.reissueid[row]
	uc_scid = dw_pageretr.Object.scid[row]
	dw_child.SetRedraw (FALSE)
	dw_child.Retrieve(uc_scid,uc_relid)
	dw_child.SetRedraw (TRUE)
	IF dw_child.RowCount() > 0 THEN
		dw_child.SelectRow(0,FALSE)
		dw_child.SelectRow(1,TRUE)
		dw_child.SetRow(1)
	END IF	
ELSE
	dw_child.Reset()
END IF


end event

event ue_f9;call super::ue_f9;IF NOT dw_edit_mode THEN RETURN
Long child_row

child_row = dw_uc.GetRow()
IF child_row = 0 THEN
	MessageBox('提示','请选定补件单!',information!,OK!)
	RETURN
END IF

IF NOT IsValid(W_cust_edit) THEN
	s_edit_index_tran s_ch_tran //传递参数使用
	s_ch_tran.if_retrieve_all = FALSE //是否一次RETRIEVE所有行
	s_ch_tran.work_mode = 1 //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid = 0 //目标定位PKID (备用)
	//查询列(物料编码)部分内容,用于初步筛选
	
	dw_uc.AcceptText()
	s_ch_tran.arg_string_code = Upper(Trim(dw_uc.Object.u_cust_cuscode[dw_uc.GetRow()]))
	
	OpenWithParm(W_cust_edit,s_ch_tran) //调用
	
	s_custom S_INSCUST
	S_INSCUST = Message.PowerObjectParm //接受返回结构
	
	IF S_INSCUST.cusid > 0 THEN //正常返回值则可以取以下值
		dw_uc.SetRedraw(FALSE)
		dw_uc.Object.cusid[child_row] = S_INSCUST.cusid
		dw_uc.Object.u_cust_name[child_row] = S_INSCUST.Name
		dw_uc.Object.u_cust_cuscode[child_row] = S_INSCUST.cuscode
		dw_uc.SetRedraw(TRUE)
		dw_uc.SetFocus()
		dw_uc.SetColumn("moneyid")
	END IF
END IF


end event

event ue_viewprint;call super::ue_viewprint;
IF NOT f_power_ind(1026)  THEN
	MessageBox('提示','你没有使用权限！',information!,OK!)
	RETURN
END IF

Long LS_ROW
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('提示','没有打印目标单据!',information!,OK!)
	RETURN
END IF

S_print_MSG LS_PRMSG

IF ls_newname <> '' THEN
	
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('提示','目标单据还未审核,不能打印!',information!,OK!)
			RETURN
		END IF
	END IF
	
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
//	IF NOT f_power_ind(1026)  THEN
//		MessageBox('提示','你没有使用权限！',information!,OK!)
//		RETURN
//	END IF
	
	LS_PRMSG.obj_dwNAME = 'dw_rp_reissue_print'
END IF

IF LS_PRMSG.obj_dwNAME = '' THEN RETURN

LS_PRMSG.printrow = ll_prownum
LS_PRMSG.TAG_TEXT = '客户费用单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.retr_pram_falg = 15
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_scid = dw_pageretr.Object.scid[LS_ROW]
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.reissueid[LS_ROW]
LS_PRMSG.rowcnt = dw_child.RowCount()
OpenWithParm(w_publ_preview,LS_PRMSG)

//更新打印次数
String arg_msg
printnum = Message.DoubleParm
f_update_printnum('u_reissue',printnum,dw_pageretr.Object.scid[dw_pageretr.GetRow()],dw_pageretr.Object.reissueid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)

end event

event ue_print;call super::ue_print;//--直接打印
IF NOT f_power_ind(1026)  THEN
	MessageBox('提示','你没有使用权限！',information!,OK!)
	RETURN
END IF

uo_print_preview uo_print
IF MessageBox ("询问","是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN


S_print_MSG LS_PRMSG

Long LS_ROW
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('提示','没有打印目标单据!',information!,OK!)
	RETURN
END IF

IF ls_newname <> '' THEN
	
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('提示','目标单据还未审核,不能打印!',information!,OK!)
			RETURN
		END IF
	END IF
	
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	
	IF NOT f_power_ind(1026)  THEN
		MessageBox('提示','你没有使用权限！',information!,OK!)
		RETURN
	END IF
	
	LS_PRMSG.obj_dwNAME = 'dw_rp_reissue_print'
END IF

if LS_PRMSG.obj_dwNAME = '' then return

LS_PRMSG.retr_pram_falg = 15
LS_PRMSG.printrow = ll_prownum
LS_PRMSG.TAG_TEXT = '客户费用单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_scid = dw_pageretr.Object.scid[LS_ROW]
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.reissueid[LS_ROW]
LS_PRMSG.rowcnt = dw_child.RowCount()
uo_print.FACT_PRINT_MSG = LS_PRMSG


String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("错误",arg_msg,stopsign!,OK!)
	RETURN
END IF
uo_print.ds_print()

//更新打印次数
printnum = 1

Long ll_scid
String ls_code

ll_scid = dw_pageretr.Object.scid[dw_pageretr.GetRow()]
ls_code = dw_pageretr.Object.reissuecode[dw_pageretr.GetRow()]

 
//**更新打印次料
printnum = Message.DoubleParm
f_update_printnum('u_reissue',printnum,dw_pageretr.Object.scid[dw_pageretr.GetRow()],dw_pageretr.Object.reissueid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)

end event

event ue_addzy;call super::ue_addzy;if not f_power_ind(1027) then
	messagebox('提示','你没有使用权限！',information!,OK!)
	return
end if

IF dw_edit_mode THEN RETURN
String arg_msg = ''
String ls_str
Long uc_row
s_inputbox s_sreu

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,OK!)
	RETURN
END IF
s_sreu.Title = '请输入要补充到备注的内容'
s_sreu.old_text = ''
OpenWithParm(w_inputbox,s_sreu)
ls_str = Message.StringParm
IF Trim(ls_str) = '' OR IsNull(ls_str) THEN RETURN

IF uo_ware.add_dscrp(dw_pageretr.object.scid[uc_row],dw_pageretr.Object.reissueid[uc_row],ls_str,arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,OK!)
	RETURN
ELSE
	MessageBox('提示','添加备注操作成功!',information!,OK!)
	wf_refresh_curuc(dw_pageretr.object.scid[uc_row],dw_pageretr.Object.reissueid[uc_row])
END IF


end event

event ue_rpt_print;call super::ue_rpt_print;Long row,uc_relid,ll_scid
row = dw_pageretr.GetRow()
IF row = 0 THEN RETURN


uo_rpt_print_preview uo_print
S_rpt_print_MSG LS_PRMSG

IF dw_pageretr.RowCount() = 0 THEN
	MessageBox('提示','没有可打印的单据！',information!,OK!)
	RETURN
END IF

IF ls_rpname = '' THEN RETURN

IF li_auditprint = 1 THEN
	IF dw_pageretr.Object.flag[row] = 0 THEN
		MessageBox('提示','目标单据还未审核,不能打印!',information!,OK!)
		RETURN
	END IF
END IF

IF MessageBox ("询问","是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN

LS_PRMSG.retr_pram_falg = 15
LS_PRMSG.TAG_TEXT = THIS.Title
LS_PRMSG.rpname = ls_rpname
LS_PRMSG.FILTER_STRING = ''

LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.rpid = ls_msgprintid_rpt
LS_PRMSG.retr_scid = dw_pageretr.Object.scid[row]
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.reissueid[row]
LS_PRMSG.rowcnt = dw_child.RowCount()


uo_print.FACT_PRINT_MSG = LS_PRMSG

String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("错误",arg_msg,stopsign!,OK!)
	RETURN
END IF
uo_print.ds_print()


//**更新打印次料
printnum = Message.DoubleParm

String ls_code

ll_scid = dw_pageretr.Object.scid[row]
ls_code = dw_pageretr.Object.reissuecode[row]

//**更新打印次料
printnum = Message.DoubleParm
f_update_printnum('u_reissue',printnum,dw_pageretr.Object.scid[dw_pageretr.GetRow()],dw_pageretr.Object.reissueid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)

end event

event ue_rpt_viewprint;call super::ue_rpt_viewprint;

Long row,uc_relid,ll_scid
row = dw_pageretr.GetRow()
IF row = 0 THEN RETURN


IF ls_rpname = '' THEN RETURN

IF li_auditprint = 1 THEN
	IF dw_pageretr.Object.flag[row] = 0 THEN
		MessageBox('提示','目标单据还未审核,不能打印!',information!,OK!)
		RETURN
	END IF
END IF

s_rpt_print_msg s_print
s_print.retr_pram_falg = 15
s_print.rpid = ls_msgprintid_rpt
s_print.retr_flag = TRUE
s_print.tag_text = THIS.Title

s_print.rpname  = ls_rpname
s_print.retr_scid = dw_pageretr.Object.scid[row]
s_print.retr_pramnmb = dw_pageretr.Object.reissueid[row]
s_print.rowcnt = dw_child.RowCount()
OpenWithParm(w_rpt_preview,s_print)

//**更新打印次料
String arg_msg
printnum = Message.DoubleParm

String ls_code

ll_scid = dw_pageretr.Object.scid[row]
ls_code = dw_pageretr.Object.reissuecode[row]
//**更新打印次料
printnum = Message.DoubleParm
f_update_printnum('u_reissue',printnum,dw_pageretr.Object.scid[dw_pageretr.GetRow()],dw_pageretr.Object.reissueid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)

end event

event ue_f7;call super::ue_f7;//用于选择明细内容,被F9[默认]
IF NOT dw_edit_mode THEN RETURN

Long uc_row
String ls_itemcode
uc_row = dw_uc.GetRow()
ls_itemcode = Trim(dw_uc.Object.u_itemdef_itemcode[uc_row])

IF uc_row = 0 THEN
	MessageBox('提示','请选定单据!',information!,OK!)
	RETURN
END IF

dw_uc.AcceptText()
IF NOT IsValid(w_itemdef_ch) THEN
	s_edit_index_tran s_ch_tran //传递参数使用
	s_ch_tran.if_retrieve_all = local_retrieve_all  //是否一次retrieve所有行
	s_ch_tran.work_mode = 1                         //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid = 0                          //目标定位pkid (备用)	
	s_ch_tran.arg_string_code = ls_itemcode         //查询列(物料编码)部分内容,用于初步筛选
	
	OpenWithParm(w_itemdef_ch,s_ch_tran) //调用
	
	s_itemdef s_inscust
	s_inscust = Message.PowerObjectParm //接受返回结构
	
	IF s_inscust.itemid > 0 THEN //正常返回值则可以取以下值
		dw_uc.SetRedraw(FALSE)
		dw_uc.Object.u_reissue_itemid[uc_row] = s_inscust.itemid
		dw_uc.Object.u_itemdef_itemcode[uc_row] = s_inscust.itemcode
		dw_uc.Object.u_itemdef_itemname[uc_row] = s_inscust.itemname
		
		dw_uc.SetColumn("dscrp")
		dw_uc.SetRedraw(TRUE)
	END IF
END IF

end event

event ue_send_ljfieb;IF dw_edit_mode THEN RETURN

IF  sys_email_sqlca.DBHandle() = 0  THEN
	MessageBox('Error','电子商务数据库连接失败,请检查')
	RETURN
END IF

IF MessageBox('询问','是否确认要发送单据给客户?',question!,yesno!) = 2 THEN RETURN

Long ll_scid,ll_reissueid
String ls_taskcode
Long ll_row
Int li_ifecomm
String arg_summary,arg_postscript,arg_remark
String arg_msg

ll_row  = dw_pageretr.GetRow()

IF ll_row <= 0 THEN
	MessageBox('系统提示','请选择要发送的单据')
	RETURN
END IF

ll_scid = dw_pageretr.Object.scid[ll_row]
ll_reissueid  = dw_pageretr.Object.reissueid[ll_row]
ls_taskcode = dw_pageretr.Object.reissuecode[ll_row]

SELECT u_cust.ifecomm
	INTO :li_ifecomm
 FROM u_reissue  LEFT OUTER JOIN
	u_cust ON u_reissue.cusid = u_cust.cusid
	WHERE u_reissue.scid = :ll_scid
	And u_reissue.reissueid = :ll_reissueid Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	MessageBox('Error','查询费用单相关客户通信信息失败,请检查设置,'+sqlca.SQLErrText)
	RETURN
END IF

IF li_ifecomm = 0 THEN
	MessageBox('系统提示','客户没有使用电子商务,不能发送单据')
	RETURN
END IF

s_packet_ljfieb s_pack,s_return


s_pack.summary = '发送客户费用单:'+ls_taskcode

OpenWithParm(w_dscrp_edit_ljfieb,s_pack)

s_return = Message.PowerObjectParm

IF s_return.returnflag <> 1 THEN RETURN

arg_summary = s_return.summary
arg_postscript = s_return.postscript
arg_remark = s_return.remark

IF uo_fieb.send_reissue(ll_scid,ll_reissueid,arg_summary,arg_postscript,arg_remark,arg_msg,True) = 0 THEN
	MessageBox('Erorr',arg_msg)
	RETURN
END IF

UPDATE u_reissue
	SET senduser = :publ_operator,
	sendtime = getdate(),
	sendcnt = sendcnt + 1
	WHERE reissueid = :ll_reissueid
	And scid = :ll_scid Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	ROLLBACK Using sqlca;
	MessageBox('Error','更新发送次数失败,'+sqlca.SQLErrText)
	RETURN
ELSE
	COMMIT Using sqlca;
END IF

wf_refresh_curuc(ll_scid,ll_reissueid)
MessageBox('系统提示','提交成功!')




end event

event ue_jdview_ljfieb;long ll_row

ll_row = dw_pageretr.getrow()

if ll_row <= 0 then return

string ls_taskcode

ls_taskcode = dw_pageretr.object.reissuecode[ll_row]

openwithparm(w_ljfieb_buytask_hisview,ls_taskcode)
end event

type cb_func from w_publ_1ton_share_detail`cb_func within w_reissue
end type

type cb_exit from w_publ_1ton_share_detail`cb_exit within w_reissue
integer x = 2514
integer width = 146
end type

type sle_usual_query from w_publ_1ton_share_detail`sle_usual_query within w_reissue
integer x = 192
integer width = 549
end type

type cb_retrieveall from w_publ_1ton_share_detail`cb_retrieveall within w_reissue
integer x = 2962
end type

type em_pagerowno from w_publ_1ton_share_detail`em_pagerowno within w_reissue
integer x = 2661
end type

type dw_pageretr from w_publ_1ton_share_detail`dw_pageretr within w_reissue
integer x = 1710
integer width = 1829
integer height = 1116
string dataobject = "dw_reissue_index"
end type

event dw_pageretr::rowfocuschanged;call super::rowfocuschanged;wf_flagstatus_rf()

end event

type st_1 from w_publ_1ton_share_detail`st_1 within w_reissue
integer x = 18
end type

type cb_nextpage from w_publ_1ton_share_detail`cb_nextpage within w_reissue
integer x = 3113
end type

type dw_uc from w_publ_1ton_share_detail`dw_uc within w_reissue
integer width = 1710
integer height = 1116
string dataobject = "dw_reissue_edit"
end type

event dw_uc::dwnkey;PARENT.TriggerEvent('user_key')

IF Key = KeyDownArrow! THEN RETURN 1

IF dw_edit_mode THEN
	IF dw_uc.GetColumnName ( ) = 'dscrp'  AND Key = KeyEnter! THEN
		dw_child.SetFocus()
		dw_child.ScrollToRow(1)
		dw_child.SetColumn ('u_expenses_expensescode')
		RETURN 1
	ELSEIF dw_uc.GetColumnName ( ) = 'u_cust_cuscode' AND Key = KeyEnter! THEN
		String ls_code
		
		dw_uc.AcceptText()
		ls_code = Trim(dw_uc.Object.u_cust_cuscode[dw_uc.GetRow()])

		s_custom arg_s_cust
		
		IF f_find_cust(ls_code,arg_s_cust) = 0 THEN
			PARENT.TriggerEvent('ue_f9')
			RETURN 1
		ELSE
			dw_uc.SetRedraw(FALSE)
			dw_uc.Object.cusid[dw_uc.GetRow()] = arg_s_cust.cusid
			dw_uc.Object.u_cust_cuscode[dw_uc.GetRow()] = arg_s_cust.cuscode
			dw_uc.Object.u_cust_name[dw_uc.GetRow()] = arg_s_cust.Name
			dw_uc.setfocus()
			dw_uc.SetRedraw(TRUE)
			dw_uc.SetColumn("moneyid")
			RETURN 1
		END IF
	ELSEIF dw_uc.GetColumnName ( ) = 'u_itemdef_itemcode' AND Key = KeyEnter! THEN
		String ls_itemcode,ls_itemname
		Long ls_itemid
		
		dw_uc.AcceptText()
		ls_itemcode = Upper(Trim(dw_uc.Object.u_itemdef_itemcode[dw_uc.GetRow()]))
		SELECT
		u_itemdef.itemid,
		u_itemdef.itemname
		INTO
		:ls_itemid,
		:ls_itemname
		FROM u_itemdef
		Where ( u_itemdef.itemcode = :ls_itemcode );
		IF sqlca.SQLCode <> 0 THEN
			PARENT.TriggerEvent('ue_f7')
			RETURN 1
		ELSE
			dw_uc.SetRedraw(FALSE)
			dw_uc.Object.u_reissue_itemid[dw_uc.GetRow()] = ls_itemid
			dw_uc.Object.u_itemdef_itemname[dw_uc.GetRow()] = ls_itemname
			dw_uc.SetRedraw(TRUE)
			dw_uc.SetColumn("dscrp")
			RETURN 1
		END IF
	ELSE
		IF  Key = KeyEnter! THEN //
			keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
			keybd_event ( 9, 0, 2, 0 ) // 释放tab 
			RETURN 1
		END IF
	END IF
END IF


end event

event dw_uc::buttonclicked;call super::buttonclicked;IF NOT dw_edit_mode THEN RETURN

IF row <= 0 THEN RETURN

IF dwo.Name = 'b_cust' THEN
	PARENT.TriggerEvent('ue_f9')
END IF

end event

event dw_uc::doubleclicked;IF dw_edit_mode AND row > 0  THEN
	IF dwo.Name = 'u_itemdef_itemcode' OR dwo.Name = 'u_itemdef_itemname' THEN
		PARENT.TriggerEvent('ue_f7')
	ELSE
		PARENT.TriggerEvent('ue_f9')
	END IF
END IF

end event

event dw_uc::itemchanged;call super::itemchanged;IF Not dw_edit_mode THEN RETURN

This.AcceptText()
IF This.GetRow() <= 0 THEN RETURN

IF dwo.Name =  'moneyid' THEN
	
	Long ll_moneyid
	ll_moneyid = This.Object.moneyid[This.GetRow()]
	This.SetRedraw(False)
	This.Object.u_reissue_mrate[This.GetRow()] = f_get_mrate(ll_moneyid)
	This.SetRedraw(True)
	
END IF

end event

type gb_2 from w_publ_1ton_share_detail`gb_2 within w_reissue
integer x = 585
integer y = 456
integer width = 293
integer height = 156
end type

type dw_child from w_publ_1ton_share_detail`dw_child within w_reissue
integer y = 1416
integer width = 3543
integer height = 860
string dataobject = "dw_reissuemx_index"
end type

event dw_child::dwnkey;call super::dwnkey;PARENT.TriggerEvent('user_key')

String ls_mtrlcode,ls_mtrlname
Long ls_mtrlid

Long child_row

IF dw_edit_mode THEN
	IF KeyDown(Keydownarrow!) THEN
		Long li_row
		IF dw_child.GetRow() = dw_child.RowCount() THEN
			PARENT.TriggerEvent("insert_childrow")
		END IF
	ELSE
		If (KeyDown(KeyEnter!) OR KeyDown(KeyTab!)) AND NOT KeyDown(KeyControl!) AND NOT KeyDown(KeyShift!)  THEN
			IF dw_child.GetColumnName() = 'u_expenses_expensescode' THEN
				dw_child.AcceptText()
				child_row = dw_child.GetRow()
				
				ls_mtrlcode = dw_child.Object.u_expenses_expensescode[child_row]
				
				
				SELECT U_Expenses.Expensesid,
					U_Expenses.Expensesname
					INTO	:ls_mtrlid,:ls_mtrlname
					FROM 	U_Expenses
					Where	( U_Expenses.Expensescode = :ls_mtrlcode);
					
				IF sqlca.SQLCode = 100 THEN
					PARENT.TriggerEvent('ue_f8')
					RETURN
				END IF
				 
				dw_child.Object.mtrlid[child_row]    = ls_mtrlid
				dw_child.Object.u_expenses_expensesname[child_row]   = ls_mtrlname
				dw_child.Object.qty[child_row]   = 1
				IF Key = KeyEnter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF			
			ELSEIF dw_child.GetColumnName( ) = 'dscrp' AND dw_child.GetRow() = dw_child.RowCount() THEN
				PARENT.TriggerEvent("insert_childrow")
				RETURN 1	
			ELSE
				IF Key = KeyEnter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF
			END IF
		END IF
	END IF
END IF


end event

type cb_viewprint from w_publ_1ton_share_detail`cb_viewprint within w_reissue
integer x = 1870
end type

type cb_print from w_publ_1ton_share_detail`cb_print within w_reissue
integer x = 1678
end type

type cb_add from w_publ_1ton_share_detail`cb_add within w_reissue
end type

event cb_add::clicked;IF NOT f_power_ind(1022)  THEN
	MessageBox('提示','你没有使用权限！',information!,OK!)
	RETURN
END IF

String arg_msg = ''
Long uc_row
Long i

IF dw_edit_mode THEN
	dw_uc.AcceptText()
	dw_child.AcceptText()
	uc_row = dw_uc.GetRow()
	IF uc_row <= 0 THEN
		MessageBox('提示','请选定当前目标单据!',information!,OK!)
		RETURN
	END IF
	
	IF NOT dw_uc.Object.reissuedate[uc_row] > DateTime(2000-01-01,Now()) THEN
		MessageBox('提示','不合理发生时间',information!,OK!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("reissuedate")
		RETURN
	END IF
	
	IF trim(dw_uc.Object.reissueemp[uc_row]) = '' THEN
		MessageBox('提示','请输入经手人',information!,OK!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("reissueemp")
		RETURN
	END IF
	
	IF dw_uc.Object.relid[uc_row] = 0 THEN
		MessageBox('提示','请选择结算方式',information!,OK!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("relid")
		RETURN
	END IF
	
	IF dw_uc.Object.moneyid[uc_row] = 0 THEN
		MessageBox('提示','请选择币种',information!,OK!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("moneyid")
		RETURN
	END IF

	IF dw_uc.Object.u_reissue_itemid[uc_row] = 0 THEN
		MessageBox('提示','请选择项目',information!,OK!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("u_reissue_itemid")
		RETURN
	END IF	

	uo_ware.reissuedate = dw_uc.Object.reissuedate[uc_row]
	uo_ware.dscrp  = dw_uc.Object.dscrp[uc_row]
	uo_ware.cusid  = dw_uc.Object.cusid[uc_row]
	uo_ware.relcode  = dw_uc.Object.relcode[uc_row]
	uo_ware.r_type  = 1
	uo_ware.relid  = dw_uc.Object.relid[uc_row]
	uo_ware.moneyid  = dw_uc.Object.moneyid[uc_row]	
	uo_ware.reissueemp = dw_uc.Object.reissueemp[uc_row]
	uo_ware.itemid = dw_uc.Object.u_reissue_itemid[uc_row]
	uo_ware.mrate = dw_uc.Object.u_reissue_mrate[uc_row]
		
	FOR i = 1 TO dw_child.RowCount()
		IF uo_ware.acceptmx(	dw_child.Object.qty[i],&
			dw_child.Object.price[i],&
			dw_child.Object.amt1[i],&
			dw_child.Object.dscrp[i],&
			i,&
			arg_msg,&
			dw_child.Object.mtrlid[i],'') = 0 THEN
			MessageBox('错误',arg_msg,stopsign!,OK!)
			RETURN
		END IF
	NEXT
	
	IF uo_ware.Save(TRUE,arg_msg) = 0 THEN
		MessageBox('错误',arg_msg,stopsign!,OK!)
		RETURN
	END IF
	MessageBox('提示','保存操作成功!',information!,OK!)
	
	//write ini
	f_SetProfileString (sys_empid,publ_userid+'_'+dw_uc.DataObject, "moneyid",String(dw_uc.Object.moneyid[dw_uc.GetRow()]))
	//
	long ll_row
	ll_row = dw_pageretr.getrow()
	dw_pageretr.SelectRow(0,FALSE)
	dw_pageretr.SelectRow(ll_row,TRUE)
	wf_refresh_curuc(cur_scid,uo_ware.reissueid) //刷新uc	
	
ELSE
	IF uo_ware.newbegin(cur_scid,arg_msg) = 0 THEN
		MessageBox('错误',arg_msg,stopsign!,OK!)
		RETURN
	END IF
END IF

CALL SUPER::Clicked
//read ini
IF dw_edit_mode THEN
	PARENT.TriggerEvent("insert_childrow")
	
	String ls_moneyid
	ls_moneyid = f_ProfileString (sys_empid,publ_userid+'_'+dw_uc.DataObject, "moneyid",'0')
	dw_uc.SetRedraw(FALSE)
	dw_uc.Object.moneyid[dw_uc.GetRow()] = Long(ls_moneyid)
	dw_uc.Object.u_reissue_mrate[dw_uc.GetRow()] = f_get_mrate(Long(ls_moneyid))
	dw_uc.SetColumn("u_cust_cuscode")
	dw_uc.SetRedraw(TRUE)
ELSE
	PARENT.TriggerEvent("retrieve_childdw")
END IF
//




end event

type cb_edit from w_publ_1ton_share_detail`cb_edit within w_reissue
end type

event cb_edit::clicked;IF NOT f_power_ind(1022)  THEN
	MessageBox('提示','你没有使用权限！',information!,OK!)
	RETURN
END IF

String arg_msg = ''
Long uc_row

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,OK!)
	RETURN
END IF

IF NOT dw_edit_mode THEN
	IF uo_ware.updatebegin(dw_pageretr.Object.scid[uc_row],dw_pageretr.Object.reissueid[uc_row],arg_msg) = 0 THEN
		MessageBox('错误',arg_msg,stopsign!,OK!)
		RETURN
	END IF
	
		wf_refresh_curuc(dw_pageretr.Object.scid[uc_row],dw_pageretr.Object.reissueid[uc_row]) //刷新uc	
PARENT.TriggerEvent("retrieve_childdw")
	
END IF

CALL SUPER::Clicked


end event

type cb_delet from w_publ_1ton_share_detail`cb_delet within w_reissue
integer width = 146
end type

event cb_delet::clicked;call super::clicked;IF NOT f_power_ind(1023)  THEN
	MessageBox('提示','你没有使用权限！',information!,OK!)
	RETURN
END IF
String arg_msg = ''

IF dw_edit_mode THEN RETURN

Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,OK!)
	RETURN
END IF
IF MessageBox ("询问","是否确定要删除当前单据?",question!,yesno! ) = 2 THEN RETURN
IF uo_ware.del(dw_pageretr.Object.scid[uc_row],dw_pageretr.Object.reissueid[uc_row],arg_msg,TRUE) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,OK!)
ELSE
	//日志
	Long ls_id
	String ls_code
	ls_id = dw_pageretr.Object.reissueid[uc_row]
	ls_code = dw_pageretr.Object.reissuecode[uc_row]
	f_setsysoplog('客户费用单','客户费用单删除,id:'+String(ls_id)+',code:'+ls_code,arg_msg,TRUE)
	//--
	MessageBox('提示','删除单据'+String(dw_pageretr.Object.reissuecode[uc_row])+'成功!',information!,OK!)
	
	dw_pageretr.DeleteRow(uc_row)
	dw_pageretr.Triggerevent(rowfocuschanged!)
END IF

end event

type cb_addzy from w_publ_1ton_share_detail`cb_addzy within w_reissue
integer x = 1175
end type

event cb_addzy::clicked;call super::clicked;m_Dfc_Control_PopupMenu dmPopupMenu
string menustr


menustr="Text=增加备注~tEvent=ue_addzy"

if len(trim(menustr))<>0 then
	dmPopupMenu = Create m_Dfc_Control_PopupMenu
	dmPopupMenu.mf_BuildMenu(This, menustr)
	dmPopupMenu.mf_PopMenu()
	Destroy dmPopupMenu
end if


end event

type cb_auditing from w_publ_1ton_share_detail`cb_auditing within w_reissue
integer x = 832
end type

event cb_auditing::clicked;call super::clicked;IF NOT f_power_ind(1024)  THEN
	MessageBox('提示','你没有使用权限！',information!,OK!)
	RETURN
END IF

IF dw_edit_mode THEN RETURN

String arg_msg = '',ls_code
Long pagerert_row,ls_id

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,OK!)
	RETURN
END IF
IF MessageBox ("询问","是否确定要"+THIS.Text+"当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN

IF uo_ware.getinfo(dw_pageretr.Object.scid[pagerert_row],dw_pageretr.Object.reissueid[pagerert_row],arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,OK!)
	RETURN
END IF



IF uo_ware.auditing(TRUE,arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,OK!)
ELSE
	MessageBox('提示','审核成功!',information!,OK!)
	wf_refresh_curuc(dw_pageretr.Object.scid[pagerert_row],dw_pageretr.Object.reissueid[pagerert_row])
END IF



end event

type cb_xm from w_publ_1ton_share_detail`cb_xm within w_reissue
integer x = 1426
end type

type cb_retrieve from w_publ_1ton_share_detail`cb_retrieve within w_reissue
end type

type cb_xls from w_publ_1ton_share_detail`cb_xls within w_reissue
integer x = 2062
end type

type cb_help from w_publ_1ton_share_detail`cb_help within w_reissue
integer x = 2363
end type

type cb_auditing_cancel from w_publ_1ton_share_detail`cb_auditing_cancel within w_reissue
integer x = 1024
end type

event cb_auditing_cancel::clicked;call super::clicked;IF NOT f_power_ind(1025)  THEN
	MessageBox('提示','你没有使用权限！',information!,OK!)
	RETURN
END IF

IF dw_edit_mode THEN RETURN


String arg_msg = '',ls_code,ls_opemp,ls_outpart
Long pagerert_row,ls_id

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,OK!)
	RETURN
END IF
IF MessageBox ("询问","是否确定要"+THIS.Text+"当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN
IF uo_ware.getinfo(dw_pageretr.Object.scid[pagerert_row],dw_pageretr.Object.reissueid[pagerert_row],arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,OK!)
	RETURN
END IF


IF uo_ware.c_auditing(TRUE,arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,OK!)
ELSE
	MessageBox('提示','撤审成功!',information!,OK!)
	//日志	
	ls_code = dw_pageretr.Object.reissuecode[pagerert_row]
	ls_opemp = dw_pageretr.Object.opemp[pagerert_row]
	ls_outpart = dw_pageretr.Object.relcode[pagerert_row]
	f_setsysoplog('客户费用单','客户费用单撤审'+',code:'+ls_code+',相关号码:'+ls_outpart+',建立人:'+ls_opemp,arg_msg,TRUE)
	//--
	wf_refresh_curuc(dw_pageretr.Object.scid[pagerert_row],dw_pageretr.Object.reissueid[pagerert_row])
END IF






end event

type p_msg from w_publ_1ton_share_detail`p_msg within w_reissue
end type

type p_help from w_publ_1ton_share_detail`p_help within w_reissue
end type

type p_encl from w_publ_1ton_share_detail`p_encl within w_reissue
end type

type p_other from w_publ_1ton_share_detail`p_other within w_reissue
end type

type gb_3 from w_publ_1ton_share_detail`gb_3 within w_reissue
end type

type ln_bar from w_publ_1ton_share_detail`ln_bar within w_reissue
end type

type ln_bar2 from w_publ_1ton_share_detail`ln_bar2 within w_reissue
end type

type r_bar from w_publ_1ton_share_detail`r_bar within w_reissue
end type

type ln_1 from w_publ_1ton_share_detail`ln_1 within w_reissue
end type

type ln_2 from w_publ_1ton_share_detail`ln_2 within w_reissue
end type

type ddlb_scid from uo_ddlb_scid within w_reissue
integer x = 896
integer y = 188
integer width = 549
integer height = 468
integer taborder = 20
boolean bringtotop = true
end type

event constructor;call super::constructor;cur_scid=this.uo_scid
cur_scid_arr = THIS.uo_scid_arr
end event

event selectionchanged;call super::selectionchanged;cur_scid=this.uo_scid
cur_scid_arr = THIS.uo_scid_arr
parent.triggerevent("retrieve_pageretr")
end event

type ddlb_status from dropdownlistbox within w_reissue
integer x = 1586
integer y = 188
integer width = 384
integer height = 552
integer taborder = 30
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
string text = "[全部]"
boolean sorted = false
string item[] = {"[全部]","待审核","审核完毕"}
borderstyle borderstyle = stylelowered!
end type

event selectionchanged;if index=1 then
	cur_flag= -1	
elseif index=2 then
	cur_flag= 0 
elseif index=3 then
	cur_flag= 1	
end if
parent.triggerevent('retrieve_pageretr')
end event

type st_3 from statictext within w_reissue
integer x = 1413
integer y = 204
integer width = 160
integer height = 48
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "状态"
alignment alignment = right!
boolean focusrectangle = false
end type

type st_2 from statictext within w_reissue
integer x = 722
integer y = 204
integer width = 160
integer height = 48
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "分部"
alignment alignment = right!
boolean focusrectangle = false
end type