Q5/ws_objects/Ew_mrp.pbl.src/w_sc_workgroup.srw

$PBExportHeader$w_sc_workgroup.srw
forward
global type w_sc_workgroup from w_publ_edit_choice
end type
end forward

global type w_sc_workgroup from w_publ_edit_choice
integer width = 3611
integer height = 2380
string title = "工组"
boolean minbox = true
windowtype windowtype = popup!
end type
global w_sc_workgroup w_sc_workgroup

on w_sc_workgroup.create
call super::create
end on

on w_sc_workgroup.destroy
call super::destroy
end on

event retrieve_uc;call super::retrieve_uc;datawindowchild childdw
dw_uc.SetTransObject(sqlca)
dw_uc.GetChild("storageid",childdw)
childdw.SetTransObject(sqlca)
childdw.InsertRow(0)



end event

type cb_func from w_publ_edit_choice`cb_func within w_sc_workgroup
end type

type cb_exit from w_publ_edit_choice`cb_exit within w_sc_workgroup
end type

type cb_add from w_publ_edit_choice`cb_add within w_sc_workgroup
end type

event cb_add::clicked;call super::clicked;IF NOT f_power_ind(1350) THEN
	MessageBox(publ_operator,'你没有使用权限！')
	RETURN
END IF


Long ll_newid,i
String errmsg
IF dw_edit_mode THEN
	dw_uc.AcceptText()
	IF dw_uc.GetNextModified(0, Primary!) = 0 THEN
		MessageBox(publ_operator,'没有任何修改，不可以保存!')
		RETURN
	END IF
	dw_uc.Object.wrkgrpcode[dw_uc.GetRow()] = Trim(dw_uc.Object.wrkgrpcode[dw_uc.GetRow()])
	dw_uc.Object.wrkGrpName[dw_uc.GetRow()] = Trim(dw_uc.Object.wrkGrpName[dw_uc.GetRow()])
	
	IF dw_uc.Object.wrkgrpcode[dw_uc.GetRow()] = '' THEN
		MessageBox(publ_operator,'请输入工组号!')
		RETURN
	END IF
	
	IF dw_uc.Object.wrkGrpName[dw_uc.GetRow()] = '' THEN
		MessageBox(publ_operator,'请输入工组名称!')
		RETURN
	END IF
	
	
	IF dw_uc.Object.storageid[dw_uc.GetRow()] = 0 THEN
		MessageBox(publ_operator,'请选择对应车间!')
		RETURN
	END IF
	
	
	IF dw_uc.Object.ifprint[dw_uc.GetRow()] = 0 AND dw_uc.Object.ifjj[dw_uc.GetRow()] = 1 THEN
		MessageBox(publ_operator,'参加计划打印确认请选择为参加生产计划进度!')
		RETURN
	END IF
	
	IF dw_uc.Object.wrkGrpid[dw_uc.GetRow()] = 0 THEN
		ll_newid = f_sys_scidentity(0,"u_sc_workgroup","wrkGrpid",errmsg,FALSE,sqlca)
		IF ll_newid <= 0 THEN
			MessageBox(publ_operator,errmsg)
			RETURN
		ELSE
			dw_uc.Object.wrkGrpid[dw_uc.GetRow()] = ll_newid
		END IF
		dw_uc.Object.opemp[dw_uc.GetRow()] = publ_operator
	ELSE
		dw_uc.Object.modemp[dw_uc.GetRow()] = publ_operator
		dw_uc.Object.moddate[dw_uc.GetRow()] = DateTime(Today(),Now())
	END IF
END IF

IF dw_edit_mode THEN
	String ls_errmsg
	
	dw_uc.AcceptText()
	
	IF dw_uc.Update() = -1 THEN
		IF Pos(ins_sqlerrtext,"Cannot insert duplicate key row") > 0 THEN
			ls_errmsg = "关键内容重复"
		ELSE
			ls_errmsg = "因为网络或其他原因>"+ins_sqlerrtext
		END IF
		ROLLBACK;
		MessageBox (publ_operator,ls_errmsg+",保存操作失败!",Exclamation!,OK!)
		LS_UPDATE_FLAG = FALSE
		RETURN
	ELSE
		COMMIT;
		FOR i = 1 TO 7
			dw_uc.SetTabOrder ( i, 0 )
		NEXT
		LS_UPDATE_FLAG = TRUE
	END IF
	ins_sqlerrtext = ""
ELSE
	Long	li_row, li_cur_row
	li_cur_row = dw_uc.GetRow()
	li_row = dw_uc.InsertRow (0)
	FOR i = 1 TO 7
		dw_uc.SetTabOrder ( i, i*10 )
	NEXT
	dw_uc.SelectRow(0,FALSE)
	dw_uc.ScrollToRow (li_row)
	dw_uc.SelectRow(li_row,TRUE)
	dw_uc.SetFocus()
	modifyrow_no = li_row
END IF

dw_edit_mode = NOT dw_edit_mode
WF_FACE_CHANGE()





end event

type cb_edit from w_publ_edit_choice`cb_edit within w_sc_workgroup
end type

event cb_edit::clicked;call super::clicked;IF NOT f_power_ind(1350) THEN
	MessageBox(publ_operator,'你没有使用权限！')
	RETURN
END IF

Long i
IF dw_edit_mode THEN
	IF dw_uc.GetItemStatus(dw_uc.GetRow(), 0, Primary!) = NewModified! OR dw_uc.GetItemStatus(dw_uc.GetRow(), 0, Primary!) = New! THEN
		dw_uc.DeleteRow(dw_uc.GetRow())
	ELSE
		dw_uc.ReselectRow(dw_uc.GetRow())
	END IF
	FOR i = 1 TO 7
		dw_uc.SetTabOrder ( i, 0 )
	NEXT
	modifyrow_no = 0
ELSE
	modifyrow_no = dw_uc.GetRow()
	FOR i = 1 TO 7
		dw_uc.SetTabOrder ( i, i*10 )
	NEXT
	dw_uc.SetFocus()
	
	dw_uc.SelectRow(0,FALSE)
	dw_uc.ScrollToRow (modifyrow_no)
	dw_uc.SelectRow(modifyrow_no,TRUE)
	
END IF

dw_edit_mode = NOT dw_edit_mode
WF_FACE_CHANGE()

end event

type cb_delet from w_publ_edit_choice`cb_delet within w_sc_workgroup
end type

event cb_delet::clicked;call super::clicked;IF NOT f_power_ind(1350) THEN
	MessageBox(publ_operator,'你没有使用权限！')
	RETURN
END IF

IF MessageBox (publ_operator,"是否确定要删除当前记录?(选择确定后记录将不可恢复)",question!,yesno! ) = 2 THEN
	RETURN
END IF

Long ls_id
Long ls_long = 0
String ls_code,arg_msg
IF dw_uc.GetRow() <= 0 THEN
	MessageBox('','没有操作目标记录!')
	RETURN
END IF

ls_id = dw_uc.Object.wrkgrpid[dw_uc.GetRow()]

SELECT count(*) INTO :ls_long FROM u_sc_workprice
	Where u_sc_workprice.wrkgrpid = :ls_id ;
IF sqlca.SQLCode <> 0 THEN
	MessageBox (publ_operator,"数据查询操作失败!(请重试!)",exclamation!,ok!)
	RETURN
END IF
IF ls_long > 0 THEN
	MessageBox (publ_operator,"该资料已经使用于工价表,不可以删除!",exclamation!,ok!)
	RETURN
END IF

ls_long = 0
SELECT count(*) INTO :ls_long FROM u_prdpf
	Where u_prdpf.wrkgrpid = :ls_id ;
IF sqlca.SQLCode <> 0 THEN
	MessageBox (publ_operator,"数据查询操作失败!(请重试!)",exclamation!,ok!)
	RETURN
END IF
IF ls_long > 0 THEN
	MessageBox (publ_operator,"该资料已经使用于物料清单,不可以删除!",exclamation!,ok!)
	RETURN
END IF

//ls_long = 0
//SELECT count(*) INTO :ls_long FROM u_mtrl_wkp
//	Where u_mtrl_wkp.swkpid = :ls_id OR u_mtrl_wkp.owkpid = :ls_id  ;
//IF sqlca.SQLCode <> 0 THEN
//	MessageBox (publ_operator,"数据查询操作失败!(请重试!)",exclamation!,ok!)
//	RETURN
//END IF
//IF ls_long > 0 THEN
//	MessageBox (publ_operator,"该资料已经使用于物料工组进度,不可以删除!",exclamation!,ok!)
//	RETURN
//END IF

//ls_long = 0
//SELECT count(*) INTO :ls_long FROM u_ordermtrl_workgroup
//	Where u_ordermtrl_workgroup.wrkgrpid = :ls_id ;
//IF sqlca.SQLCode <> 0 THEN
//	MessageBox (publ_operator,"数据查询操作失败!(请重试!)",exclamation!,ok!)
//	RETURN
//END IF
//IF ls_long > 0 THEN
//	MessageBox (publ_operator,"该资料已经使用于生产计划工组进度,不可以删除!",exclamation!,ok!)
//	RETURN
//END IF

dw_uc.SetRedraw (FALSE)
dw_uc.DeleteRow (0)
dw_uc.TriggerEvent (RowFocusChanged!)

IF dw_uc.Update() = -1 THEN
	ROLLBACK;
	MessageBox (publ_operator,"删除记录操作失败!",exclamation!,ok!)
ELSE
	COMMIT;
END IF
dw_uc.SetRedraw (TRUE)



end event

type cb_choice from w_publ_edit_choice`cb_choice within w_sc_workgroup
boolean enabled = false
end type

type dw_uc from w_publ_edit_choice`dw_uc within w_sc_workgroup
integer width = 3543
integer height = 2060
string dataobject = "dw_sc_workgroup_index"
boolean hscrollbar = true
end type

type cb_rtr from w_publ_edit_choice`cb_rtr within w_sc_workgroup
end type

type cb_help from w_publ_edit_choice`cb_help within w_sc_workgroup
end type

type ln_bar from w_publ_edit_choice`ln_bar within w_sc_workgroup
end type

type ln_bar2 from w_publ_edit_choice`ln_bar2 within w_sc_workgroup
end type

type r_bar from w_publ_edit_choice`r_bar within w_sc_workgroup
end type