Q5/ws_objects/Ew_ljfieb.pbl.src/w_buytask_receive_ljfieb.srw

$PBExportHeader$w_buytask_receive_ljfieb.srw
forward
global type w_buytask_receive_ljfieb from w_publ_base
end type
type dw_uc from datawindow within w_buytask_receive_ljfieb
end type
type dw_child from u_dw_rbtnfilter within w_buytask_receive_ljfieb
end type
type mle_1 from multilineedit within w_buytask_receive_ljfieb
end type
type st_1 from statictext within w_buytask_receive_ljfieb
end type
type st_2 from statictext within w_buytask_receive_ljfieb
end type
type sle_scname from singlelineedit within w_buytask_receive_ljfieb
end type
type cb_accept from uo_imflatbutton within w_buytask_receive_ljfieb
end type
type cb_feedback from uo_imflatbutton within w_buytask_receive_ljfieb
end type
type cb_reject from uo_imflatbutton within w_buytask_receive_ljfieb
end type
type mle_2 from multilineedit within w_buytask_receive_ljfieb
end type
type st_3 from statictext within w_buytask_receive_ljfieb
end type
type cb_1 from uo_imflatbutton within w_buytask_receive_ljfieb
end type
type ln_bar from line within w_buytask_receive_ljfieb
end type
type ln_bar2 from line within w_buytask_receive_ljfieb
end type
type ln_1 from line within w_buytask_receive_ljfieb
end type
type ln_2 from line within w_buytask_receive_ljfieb
end type
type r_bar from rectangle within w_buytask_receive_ljfieb
end type
end forward

global type w_buytask_receive_ljfieb from w_publ_base
integer width = 3611
integer height = 2380
string title = "客户采购订单"
boolean minbox = false
windowtype windowtype = response!
windowstate windowstate = maximized!
dw_uc dw_uc
dw_child dw_child
mle_1 mle_1
st_1 st_1
st_2 st_2
sle_scname sle_scname
cb_accept cb_accept
cb_feedback cb_feedback
cb_reject cb_reject
mle_2 mle_2
st_3 st_3
cb_1 cb_1
ln_bar ln_bar
ln_bar2 ln_bar2
ln_1 ln_1
ln_2 ln_2
r_bar r_bar
end type
global w_buytask_receive_ljfieb w_buytask_receive_ljfieb

type variables
Transaction tr_eb_sqlca

s_packet_ljfieb s_inscust


long ins_scid
string ins_sn
long ins_cusid

uo_saletask obj_saletask
uo_cusprice uo_price
uo_ljfieb uo_fieb


long ins_sendid,ins_receid
string ins_sendsccode,ins_reccesccode
string ins_RelatedCode

datetime ins_addtime
string ins_adduser

string ins_returncode
end variables

forward prototypes
public function integer wf_retrieve (string arg_sn, long arg_sendcuscommid, string arg_sendsccode, ref string arg_msg)
public function integer wf_importnewbj (long arg_cusid, long arg_moneyid, long arg_mtrlid, string arg_status, string arg_woodcode, string arg_pcode, ref decimal arg_price, ref decimal arg_rebate, ref string arg_msg)
public function integer wf_importnewprice (long arg_cusid, long arg_moneyid, long arg_mtrlid, string arg_status, string arg_woodcode, string arg_pcode, ref decimal arg_price, ref decimal arg_rebate, ref string arg_msg)
end prototypes

public function integer wf_retrieve (string arg_sn, long arg_sendcuscommid, string arg_sendsccode, ref string arg_msg);Int rslt = 1
String ls_cuscode
Long uc_row
Long ll_i, ll_rowcnt,ll_row
Long ll_moneyid,ll_banktypeid
Int li_CusType

Decimal ls_1stnewprice,ls_1stzqrate

s_mtrldef_array  arg_s_mtrl

datastore ds_mx
ds_mx = Create datastore
ds_mx.DataObject = 'ds_buytaskmx_receive_ljfieb'
ds_mx.SetTransObject(tr_eb_sqlca)



SELECT CusCode,CusType
	INTO :ls_cuscode,:li_CusType
	FROM LJFIEB_CusComm
	Where CusCommID = :arg_sendcuscommid Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	ls_cuscode = ''
END IF

IF li_CusType = 5 THEN
	SELECT cuscode INTO :ls_cuscode
		FROM u_cust
		Where cusid = :ins_cusid Using sqlca;
	IF sqlca.SQLCode <> 0 THEN
		ls_cuscode = ''
	END IF
END IF

IF Trim(ls_cuscode) = '' THEN
	rslt = 0
	arg_msg = '客户信息不明确,请检查'
	GOTO ext
END IF

Long cusid
String CusCode, Name, tele, tele1, rep, upname, freight, freight_tele, Address, CusType, faxno, simplename
SELECT cusid,
	cuscode,
	name,
	tele,
	tele1,
	rep,
	upname,
	freight,
	freight_tele,
	address,
	custype,
	faxno,
	simplename
	INTO
	:cusid,
	:cuscode,
	:Name,
	:tele,
	:tele1,
	:rep,
	:upname,
	:freight,
	:freight_tele,
	:Address,
	:custype,
	:faxno,
	:simplename
	FROM u_cust
	WHERE (commcode = :ls_cuscode AND commsccode = :arg_SendSCcode AND :li_CusType <> 5
	Or CusCode = :ls_cuscode And :li_CusType = 5 )  Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询客户信息失败,请检查通信设置是否正确,'+sqlca.SQLErrText
	GOTO ext
END IF

String TaskCode, moneyname
Decimal mrate
DateTime requiredate
Decimal billamt
String train, banktypename, Dscrp
String Opemp,Modemp,Permit_Emp
DateTime opdate,moddate,Permit_date
DateTime ldt_requiredate_mx
String dscrp2, station_name, station_tel, shouhuoren,shouhuoren_tel, shouhuoren_address
Int li_status_task
SELECT TaskCode,
	moneyname,
	mrate,
	requiredate,
	billamt,
	train,
	banktypename,
	Dscrp,
	Opemp,
	opdate,
	Modemp,
	moddate,
	Permit_Emp,
	Permit_date,
	dscrp2,
	station_name,
	station_tel,
	shouhuoren,
	shouhuoren_tel,
	shouhuoren_address,
	status
	INTO :TaskCode,
	:moneyname,
	:mrate,
	:requiredate,
	:billamt,
	:train,
	:banktypename,
	:Dscrp,
	:Opemp,
	:opdate,
	:Modemp,
	:moddate,
	:Permit_Emp,
	:Permit_date,
	:dscrp2,
	:station_name,
	:station_tel,
	:shouhuoren,
	:shouhuoren_tel,
	:shouhuoren_address,
	:li_status_task
	FROM LJFIEB_tempbuyTask
	Where serialnum = :arg_sn Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询临时采购订单内容失败,'+tr_eb_sqlca.SQLErrText
	GOTO ext
END IF

dw_uc.Reset()
uc_row = dw_uc.InsertRow(0)


datawindowchild childdwmx
dw_uc.SetTransObject (sqlca)
dw_uc.GetChild("u_saletask_banktypeid",childdwmx)
childdwmx.SetTransObject (sqlca)

IF childdwmx.Retrieve() = 0 THEN
	childdwmx.InsertRow(0)
END IF

datawindowchild childdwmx_s
dw_uc.SetTransObject (sqlca)
dw_uc.GetChild("u_saletask_typeid",childdwmx_s)
childdwmx_s.SetTransObject (sqlca)

IF childdwmx_s.Retrieve() = 0 THEN
	childdwmx_s.InsertRow(0)
END IF

dw_uc.Object.cusid[uc_row] = cusid
dw_uc.Object.u_cust_name[uc_row] = Name
dw_uc.Object.u_cust_tele1[uc_row] = tele1
dw_uc.Object.u_cust_cuscode[uc_row] = CusCode
dw_uc.Object.assign_emp[uc_row] = CusType
dw_uc.Object.u_saletask_upname[uc_row] = upname

dw_uc.Object.u_saletask_cus_fax[uc_row] = faxno
dw_uc.Object.u_cust_simplename[uc_row] = simplename

dw_uc.Object.TaskCode[uc_row] = TaskCode
dw_uc.Object.cw_currency_name[uc_row] = moneyname
dw_uc.Object.u_saletask_mrate[uc_row] = mrate
dw_uc.Object.u_saletask_taskdate[uc_row] = opdate
dw_uc.Object.u_saletask_msttakeamt[uc_row] = billamt
dw_uc.Object.u_saletask_paytype[uc_row] = train
dw_uc.Object.cw_banktype_banktypename[uc_row] = banktypename
dw_uc.Object.Dscrp[uc_row] = Dscrp

dw_uc.Object.Opemp[uc_row] = Opemp
dw_uc.Object.opdate[uc_row] = opdate
dw_uc.Object.u_saletask_modemp[uc_row] = Modemp
dw_uc.Object.u_saletask_moddate[uc_row] = moddate
dw_uc.Object.Permit_Emp[uc_row] = Permit_Emp
dw_uc.Object.u_saletask_permit_date[uc_row] = Permit_date

dw_uc.Object.status_task[uc_row] = li_status_task

IF station_name <> '' THEN
	dw_uc.Object.u_saletask_freight[uc_row] = station_name
ELSE
	dw_uc.Object.u_saletask_freight[uc_row] = freight
END IF

IF station_tel <> '' THEN
	dw_uc.Object.u_saletask_freight_tele[uc_row] = station_tel
ELSE
	dw_uc.Object.u_saletask_freight_tele[uc_row] = freight_tele
END IF

IF shouhuoren_address <> '' THEN
	dw_uc.Object.u_saletask_cus_address[uc_row] = shouhuoren_address
ELSE
	dw_uc.Object.u_saletask_cus_address[uc_row] = Address
END IF

IF shouhuoren_tel <> '' THEN
	dw_uc.Object.u_saletask_cus_tele[uc_row] = shouhuoren_tel
ELSE
	dw_uc.Object.u_saletask_cus_tele[uc_row] = tele
END IF

IF shouhuoren <> '' THEN
	dw_uc.Object.u_saletask_rel_rep[uc_row] = shouhuoren
ELSE
	dw_uc.Object.u_saletask_rel_rep[uc_row] = rep
END IF

dw_uc.Object.u_saletask_dscrp2[uc_row] = dscrp2

dw_uc.Object.spt_dscrp[uc_row] = Dscrp
dw_uc.Object.spt_dscrp2[uc_row] = dscrp2


SELECT moneyid
	INTO :ll_moneyid
	FROM cw_currency
	Where Name = :moneyname Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询币种信息失败,'+sqlca.SQLErrText
	GOTO ext
END IF

SELECT top 1 banktypeid
	INTO :ll_banktypeid
	FROM cw_banktype
	WHERE banktypename = :banktypename
	And banktype = 0 Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	SELECT top 1 banktypeid
		INTO :ll_banktypeid
		FROM cw_banktype
		Where banktype = 0 Using sqlca;
	IF sqlca.SQLCode <> 0 THEN
		ll_banktypeid = 0
	END IF
END IF

dw_uc.Object.u_saletask_moneyid[uc_row] = ll_moneyid
dw_uc.Object.u_saletask_banktypeid[uc_row] = ll_banktypeid

//IF UpperBound(sys_user_saletype) > 0 THEN
//	dw_uc.Object.u_saletask_typeid[uc_row] = sys_user_saletype[1]
//END IF

Long ll_status
String ls_ConfirmUser
DateTime ld_ConfirmTime

SELECT Status, ConfirmTime, ConfirmUser
	INTO :ll_status,:ld_ConfirmTime,:ls_ConfirmUser
	FROM LJFIEB_packet
	Where serialnum = :arg_sn Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询通信记录信息失败,'+tr_eb_sqlca.SQLErrText
	GOTO ext
END IF

dw_uc.Object.status_flag[uc_row] = ll_status
dw_uc.Object.dealrep[uc_row] = ls_ConfirmUser
dw_uc.Object.dealtime[uc_row] = ld_ConfirmTime


ll_rowcnt = ds_mx.Retrieve(arg_sn)

IF ll_rowcnt = 0 THEN
	rslt = 0
	arg_msg = '没有正确的明细内容'
	GOTO ext
END IF

String ls_mtrlcode_cus
Long ll_mtrlid_local
String ls_mtrlcode_local,ls_mtrlname_local,ls_mtrlmode_local

dw_child.Reset()
FOR ll_i = 1 To ll_rowcnt
	ll_row = dw_child.InsertRow(0)
	
	dw_child.Object.u_saletaskmx_printid[ll_row] = ds_mx.Object.printid[ll_i]
	
	dw_child.Object.u_mtrldef_mtrlcode[ll_row] = ds_mx.Object.sptmtrlcode[ll_i]
	dw_child.Object.mtrlname[ll_row] = ds_mx.Object.sptmtrlname[ll_i]
	dw_child.Object.u_mtrldef_mtrlmode[ll_row] = ds_mx.Object.sptmtrlmode[ll_i]
	dw_child.Object.saleqty[ll_row] = ds_mx.Object.uqty[ll_i]
	dw_child.Object.u_saletaskmx_spt_uqty[ll_row] = ds_mx.Object.uqty[ll_i]
	
	dw_child.Object.u_mtrldef_unit[ll_row] = ds_mx.Object.unit[ll_i]
	dw_child.Object.u_saletaskmx_enprice[ll_row] = ds_mx.Object.enprice[ll_i]
	dw_child.Object.u_saletaskmx_spt_enprice[ll_row] = ds_mx.Object.enprice[ll_i]
	
	dw_child.Object.u_saletaskmx_rebate[ll_row] = ds_mx.Object.rebate[ll_i]
	dw_child.Object.u_saletaskmx_taxrate[ll_row] = ds_mx.Object.tax[ll_i]
	
	dw_child.Object.u_saletaskmx_requiredate[ll_row] = ds_mx.Object.requiredate[ll_i]
	dw_child.Object.u_saletaskmx_spt_requiredate[ll_row] = ds_mx.Object.requiredate[ll_i]
	
	
	dw_child.Object.u_saletaskmx_fprice[ll_row] = ds_mx.Object.uprice[ll_i]
	dw_child.Object.u_saletaskmx_status[ll_row] = ds_mx.Object.status[ll_i]
	dw_child.Object.spt_status[ll_row] = ds_mx.Object.status[ll_i]
	dw_child.Object.u_saletaskmx_woodcode[ll_row] = ds_mx.Object.woodcode[ll_i]
	dw_child.Object.spt_woodcode[ll_row] = ds_mx.Object.woodcode[ll_i]
	dw_child.Object.u_saletaskmx_pcode[ll_row] = ds_mx.Object.pcode[ll_i]
	dw_child.Object.spt_pcode[ll_row] = ds_mx.Object.pcode[ll_i]
	
	dw_child.Object.u_saletaskmx_mxdscrp[ll_row] = ds_mx.Object.Dscrp[ll_i]
	dw_child.Object.spt_dscrp[ll_row] = ds_mx.Object.Dscrp[ll_i]
	
	dw_child.Object.bateprice[ll_row] = ds_mx.Object.enprice[ll_i] * ds_mx.Object.rebate[ll_i]
	dw_child.Object.enprice_tax[ll_row] = ds_mx.Object.enprice[ll_i] / (1 +  ds_mx.Object.tax[ll_i] )
	dw_child.Object.bateprice_tax[ll_row] = (ds_mx.Object.enprice[ll_i]  *  ds_mx.Object.rebate[ll_i])  /  (1 + ds_mx.Object.tax[ll_i] )
	
	dw_child.Object.taxamt[ll_row] = (ds_mx.Object.enprice[ll_i]  *  ds_mx.Object.rebate[ll_i]  *  ds_mx.Object.uqty[ll_i]) /  (1 + ds_mx.Object.tax[ll_i] ) *  ds_mx.Object.tax[ll_i]
	dw_child.Object.enamt_tax[ll_row] = (ds_mx.Object.uqty[ll_i] *  ds_mx.Object.enprice[ll_i]  *  ds_mx.Object.rebate[ll_i])  / (1 + ds_mx.Object.tax[ll_i] )
	dw_child.Object.fprice_tax[ll_row] = ds_mx.Object.uprice[ll_i] / ( 1 +  ds_mx.Object.tax[ll_i] )
	dw_child.Object.famt_tax[ll_row] = (ds_mx.Object.uqty[ll_i]  *  ds_mx.Object.rebate[ll_i]  *  ds_mx.Object.uprice[ll_i])  / (1 +  ds_mx.Object.tax[ll_i] )
	
	dw_child.Object.cus_mtrlcode[ll_row] = ds_mx.Object.mtrlcode[ll_i]
	dw_child.Object.cus_mtrlmode[ll_row] = ds_mx.Object.mtrlmode[ll_i]
	dw_child.Object.cus_mtrlname[ll_row] = ds_mx.Object.mtrlname[ll_i]
	
	ls_mtrlcode_cus = dw_child.Object.cus_mtrlcode[ll_row]
	ll_mtrlid_local = 0
	SELECT mtrlid
		INTO :ll_mtrlid_local
		FROM u_cusmtrlname
		WHERE cusid = :cusid
		And cusmtrlcode = :ls_mtrlcode_cus Using sqlca;
	IF sqlca.SQLCode <> 0 THEN
		ll_mtrlid_local = 0
	END IF
	
	IF ll_mtrlid_local > 0 THEN
		SELECT mtrlcode, mtrlname, mtrlmode
			INTO :ls_mtrlcode_local,:ls_mtrlname_local,:ls_mtrlmode_local
			FROM u_mtrldef
			Where mtrlid = :ll_mtrlid_local Using sqlca;
		IF sqlca.SQLCode = 0 THEN
			dw_child.Object.u_mtrldef_mtrlcode[ll_row] = ls_mtrlcode_local
			dw_child.Object.mtrlname[ll_row] = ls_mtrlname_local
			dw_child.Object.u_mtrldef_mtrlmode[ll_row] = ls_mtrlmode_local
		END IF
	END IF
	
	
	IF f_find_mtrl_ljfieb(dw_child.Object.u_mtrldef_mtrlcode[ll_row],arg_s_mtrl) = 1 THEN
		dw_child.Object.u_mtrldef_mtrlsectype[ll_row] = arg_s_mtrl.mtrlsectype[1]
		dw_child.Object.u_mtrldef_zxmtrlmode[ll_row] = arg_s_mtrl.zxmtrlmode[1]
		dw_child.Object.u_mtrldef_usermtrlmode[ll_row] = arg_s_mtrl.usermtrlmode[1]
		
		dw_child.Object.sumnetweight[ll_row] = ds_mx.Object.uqty[ll_i] * arg_s_mtrl.net_weight[1]
		dw_child.Object.sumgrossweight[ll_row] = ds_mx.Object.uqty[ll_i] * arg_s_mtrl.gross_weight[1]
		dw_child.Object.sumcubage[ll_row] = ds_mx.Object.uqty[ll_i] * arg_s_mtrl.cubage[1]
		
		dw_child.Object.u_mtrldef_prdpackcode[ll_row] = arg_s_mtrl.prdpackcode[1]
		dw_child.Object.u_mtrldef_packqty[ll_row] = arg_s_mtrl.packqty[1]
//		dw_child.Object.u_mtrldef_expday[ll_row] = arg_s_mtrl.expday[1]
		dw_child.Object.mtrlid[ll_row] = arg_s_mtrl.mtrlid[1]
//		dw_child.Object.u_saletaskmx_scidprice[ll_row] = arg_s_mtrl.scidprice[1]
		
		dw_child.Object.u_mtrldef_statusflag[ll_row] = arg_s_mtrl.statusflag[1]
		dw_child.Object.u_mtrldef_statustype[ll_row] = arg_s_mtrl.statustype[1]
		
		dw_child.Object.u_mtrldef_woodcodeflag[ll_row] = arg_s_mtrl.woodcodeflag[1]
		dw_child.Object.u_mtrldef_woodcodetype[ll_row] = arg_s_mtrl.woodcodetype[1]
		
		dw_child.Object.u_mtrldef_pcodeflag[ll_row] = arg_s_mtrl.pcodeflag[1]
		dw_child.Object.u_mtrldef_pcodetype[ll_row] = arg_s_mtrl.pcodetype[1]
		
		dw_child.AcceptText()
		
//		IF uo_price.uof_getmtrlcusprice(ll_moneyid,arg_s_mtrl.mtrlid[1],cusid,ls_1stnewprice,ls_1stzqrate,&
//			Trim(dw_child.Object.u_saletaskmx_status[ll_row]),Trim(dw_child.Object.u_saletaskmx_woodcode[ll_row]),&
//			Trim(dw_child.Object.u_saletaskmx_pcode[ll_row]),dw_child.Object.saleqty[ll_row],arg_msg) <> 1 THEN
//			
			dw_child.Object.u_saletaskmx_nprice[ll_row] = 0
//		ELSE
//			dw_child.Object.u_saletaskmx_nprice[ll_row] = ls_1stnewprice
//		END IF
		
		IF ldt_requiredate_mx < ds_mx.Object.requiredate[ll_i] THEN
			ldt_requiredate_mx = ds_mx.Object.requiredate[ll_i]
		END IF
		
	END IF
NEXT

dw_uc.Object.requiredate[uc_row] = ldt_requiredate_mx

This.TriggerEvent('ue_allowedit')
ext:
RETURN rslt


end function

public function integer wf_importnewbj (long arg_cusid, long arg_moneyid, long arg_mtrlid, string arg_status, string arg_woodcode, string arg_pcode, ref decimal arg_price, ref decimal arg_rebate, ref string arg_msg);Int rslt = 1

IF arg_moneyid = 0  THEN
	rslt = 0
	arg_msg = '请先选择币种'
	GOTO ext
END IF

IF IsNull(arg_cusid) THEN arg_cusid = 0

IF arg_cusid = 0  THEN
	rslt = 0
	arg_msg = "请选择销售客户!"
	GOTO ext
END IF


SELECT u_cus_price.fprice_bj,u_cus_price.zqrate_bj
	INTO :arg_price,:arg_rebate
	FROM u_cus_price
	WHERE ( u_cus_price.cusid = :arg_cusid ) AND
	( u_cus_price.mtrlid = :arg_mtrlid ) AND
	( u_cus_price.status = :arg_status ) AND
	( u_cus_price.pcode = :arg_pcode ) AND
	( u_cus_price.woodcode = :arg_woodcode ) and 
	( u_cus_price.moneyid = :arg_moneyid);
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "没有最新销售价!"
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	arg_price = 0
	arg_rebate = 0
END IF

RETURN rslt

end function

public function integer wf_importnewprice (long arg_cusid, long arg_moneyid, long arg_mtrlid, string arg_status, string arg_woodcode, string arg_pcode, ref decimal arg_price, ref decimal arg_rebate, ref string arg_msg);Int rslt = 1

IF arg_moneyid = 0  THEN
	rslt = 0
	arg_msg = '请先选择币种'
	GOTO ext
END IF

IF IsNull(arg_cusid) THEN arg_cusid = 0

IF arg_cusid = 0  THEN
	rslt = 0
	arg_msg = "请选择销售客户!"
	GOTO ext
END IF


SELECT u_cus_price.fprice,u_cus_price.zqrate
	INTO :arg_price,:arg_rebate
	FROM u_cus_price
	WHERE ( u_cus_price.cusid = :arg_cusid ) AND
	( u_cus_price.mtrlid = :arg_mtrlid ) AND
	( u_cus_price.status = :arg_status ) AND
	( u_cus_price.pcode = :arg_pcode ) AND
	( u_cus_price.woodcode = :arg_woodcode ) and 
	( u_cus_price.moneyid = :arg_moneyid);
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "没有最新销售价!"
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	arg_price = 0
	arg_rebate = 0
END IF

RETURN rslt

end function

on w_buytask_receive_ljfieb.create
int iCurrent
call super::create
this.dw_uc=create dw_uc
this.dw_child=create dw_child
this.mle_1=create mle_1
this.st_1=create st_1
this.st_2=create st_2
this.sle_scname=create sle_scname
this.cb_accept=create cb_accept
this.cb_feedback=create cb_feedback
this.cb_reject=create cb_reject
this.mle_2=create mle_2
this.st_3=create st_3
this.cb_1=create cb_1
this.ln_bar=create ln_bar
this.ln_bar2=create ln_bar2
this.ln_1=create ln_1
this.ln_2=create ln_2
this.r_bar=create r_bar
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.dw_uc
this.Control[iCurrent+2]=this.dw_child
this.Control[iCurrent+3]=this.mle_1
this.Control[iCurrent+4]=this.st_1
this.Control[iCurrent+5]=this.st_2
this.Control[iCurrent+6]=this.sle_scname
this.Control[iCurrent+7]=this.cb_accept
this.Control[iCurrent+8]=this.cb_feedback
this.Control[iCurrent+9]=this.cb_reject
this.Control[iCurrent+10]=this.mle_2
this.Control[iCurrent+11]=this.st_3
this.Control[iCurrent+12]=this.cb_1
this.Control[iCurrent+13]=this.ln_bar
this.Control[iCurrent+14]=this.ln_bar2
this.Control[iCurrent+15]=this.ln_1
this.Control[iCurrent+16]=this.ln_2
this.Control[iCurrent+17]=this.r_bar
end on

on w_buytask_receive_ljfieb.destroy
call super::destroy
destroy(this.dw_uc)
destroy(this.dw_child)
destroy(this.mle_1)
destroy(this.st_1)
destroy(this.st_2)
destroy(this.sle_scname)
destroy(this.cb_accept)
destroy(this.cb_feedback)
destroy(this.cb_reject)
destroy(this.mle_2)
destroy(this.st_3)
destroy(this.cb_1)
destroy(this.ln_bar)
destroy(this.ln_bar2)
destroy(this.ln_1)
destroy(this.ln_2)
destroy(this.r_bar)
end on

event open;call super::open;tr_eb_sqlca = sys_email_sqlca // 电子商务连接

IF sys_email_sqlca.DBHandle() = 0  THEN
	MessageBox('Error','电子商务数据库连接失败,请检查')
	RETURN
END IF


obj_saletask = Create uo_saletask
obj_saletask.commit_transaction = sqlca
uo_price = Create uo_cusprice

uo_fieb = Create uo_ljfieb
uo_fieb.commit_transaction = tr_eb_sqlca

s_inscust = Message.PowerObjectParm

ins_sn = s_inscust.serialnum

ins_sendid = s_inscust.sendcuscommid
ins_receid = s_inscust.receivecuscommid
ins_sendsccode = s_inscust.sendsccode
ins_reccesccode = s_inscust.receivesccode
ins_RelatedCode = s_inscust.RelatedCode
ins_addtime = s_inscust.addtime
ins_adduser = s_inscust.adduser

String ls_sccode,ls_scname
String arg_msg
Long ll_status

ls_sccode = s_inscust.receivesccode

SELECT scid,scname
	INTO  :ins_scid,:ls_scname
	FROM u_scdef
	Where sccode = :ls_sccode;
IF sqlca.SQLCode <> 0 THEN
	MessageBox('Error','查询分部信息失败,'+sqlca.SQLErrText)
	RETURN
END IF

sle_scname.Text = ls_scname
mle_1.Text = s_inscust.postscript
mle_2.Text = s_inscust.remark

SELECT status,cusid INTO :ll_status,:ins_cusid
	FROM LJFIEB_packet
	Where serialnum = :ins_sn Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	MessageBox('Error','查询通信数据失败,'+sqlca.SQLErrText)
	RETURN
END IF

IF ll_status <> 5 THEN
	cb_accept.Enabled = False
	cb_feedback.Enabled = False
	cb_reject.Enabled = False
END IF

IF wf_retrieve(ins_sn,ins_sendid,ins_sendsccode,arg_msg) = 0 THEN
	MessageBox('Error',arg_msg)
	RETURN
END IF



//更新对方状态-已打开
String ls_SerialNum

SELECT  TOP 1 NEWID() INTO :ls_SerialNum
	From u_user Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	RETURN
END IF

IF IsNull(ls_SerialNum) THEN ls_SerialNum = ''

IF ls_SerialNum = '' THEN
	RETURN
END IF

IF uo_fieb.add_packet(ls_SerialNum,'',ins_receid,ins_reccesccode,ins_sendid,ins_sendsccode,5,'打开消息','','',ins_sn,'',0,arg_msg,True) = 0 THEN
	RETURN
END IF



end event

event resize;call super::resize;ln_bar.endx = this.width
ln_bar2.endx = this.width
r_bar.width = this.width

ln_1.endx = this.width
ln_2.endx = this.width

dw_child.width = this.WorkSpaceWidth() - 10

mle_1.width = dw_child.width - dw_uc.width - 4
mle_2.width = mle_1.width

dw_child.height = this.workspaceheight() - dw_child.y - 30
end event

event close;call super::close;destroy uo_fieb
destroy obj_saletask
destroy uo_price

closewithreturn(this,ins_returncode)
end event

type cb_func from w_publ_base`cb_func within w_buytask_receive_ljfieb
boolean visible = false
end type

type cb_exit from w_publ_base`cb_exit within w_buytask_receive_ljfieb
integer x = 1207
integer width = 183
integer height = 164
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

type dw_uc from datawindow within w_buytask_receive_ljfieb
integer y = 296
integer width = 2373
integer height = 1184
integer taborder = 30
boolean bringtotop = true
string title = "none"
string dataobject = "dw_saletask_input_ljfieb"
boolean livescroll = true
borderstyle borderstyle = stylelowered!
end type

type dw_child from u_dw_rbtnfilter within w_buytask_receive_ljfieb
integer y = 1488
integer width = 3584
integer height = 768
integer taborder = 20
boolean bringtotop = true
boolean titlebar = true
string title = "单据明细内容"
string dataobject = "dw_saletaskmx_ljfieb"
boolean maxbox = true
boolean hscrollbar = true
boolean vscrollbar = true
boolean hsplitscroll = true
end type

event rowfocuschanged;call super::rowfocuschanged;	IF currentrow <= 0 THEN RETURN
	THIS.SelectRow(0,FALSE)
	THIS.SelectRow(currentrow,TRUE)
	this.setrow(currentrow)
end event

event clicked;call super::clicked;	IF row <= 0 THEN RETURN
	THIS.SelectRow(0,FALSE)
	THIS.SelectRow(row,TRUE)
	this.setrow(row)
end event

event rbuttondown;call super::rbuttondown;Long ll_row,ll_column
ll_row = This.GetRow()
ll_column = This.GetColumn()

IF ll_row <= 0 THEN RETURN
IF ll_column <= 0 THEN RETURN

IF Left( This.Describe( dwo.Name+ ".coltype"),4) = 'date' THEN
	s_calender_arg s_calender
	
	s_calender.PointerX = This.PointerX()
	s_calender.PointerY = This.PointerY()
	s_calender.X = This.X + Parent.X
	s_calender.Y = This.Y + Parent.Y
	
	OpenWithParm(w_calendar,s_calender)
	This.SetItem(ll_row,ll_column,id_date_selected)
END IF

end event

type mle_1 from multilineedit within w_buytask_receive_ljfieb
integer x = 2377
integer y = 356
integer width = 1193
integer height = 704
integer taborder = 40
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
boolean vscrollbar = true
boolean autovscroll = true
boolean displayonly = true
borderstyle borderstyle = stylelowered!
end type

type st_1 from statictext within w_buytask_receive_ljfieb
integer x = 2386
integer y = 300
integer width = 142
integer height = 56
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "附言"
boolean focusrectangle = false
end type

type st_2 from statictext within w_buytask_receive_ljfieb
integer x = 23
integer y = 204
integer width = 155
integer height = 48
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "分部"
alignment alignment = right!
boolean focusrectangle = false
end type

type sle_scname from singlelineedit within w_buytask_receive_ljfieb
integer x = 210
integer y = 188
integer width = 443
integer height = 84
integer taborder = 30
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
boolean displayonly = true
borderstyle borderstyle = stylelowered!
end type

type cb_accept from uo_imflatbutton within w_buytask_receive_ljfieb
integer width = 274
integer height = 164
integer taborder = 30
boolean bringtotop = true
string text = "接受"
string normalpicname = "ok.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;IF Not f_power_ind(5) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

IF MessageBox('询问','确定要接受当前订单,转为正式销售订单吗?',question!,yesno!) = 2 THEN RETURN

String arg_msg
Long uc_row
DateTime ld_requiredate
Long i,ll_typeid

Long arr_org_printid[]

uc_row = dw_uc.GetRow()

IF uc_row <= 0 THEN
	MessageBox('系统提示','没有可保存的内容')
	RETURN
END IF

FOR i = 1 To dw_child.RowCount()
	IF ld_requiredate < dw_child.Object.u_saletaskmx_requiredate[i] THEN
		ld_requiredate = dw_child.Object.u_saletaskmx_requiredate[i]
	END IF
NEXT


IF obj_saletask.newbegin(ins_scid,arg_msg) = 0 THEN
	MessageBox('error!',arg_msg)
	RETURN
END IF

dw_uc.AcceptText()
dw_child.AcceptText()

IF dw_uc.Object.u_saletask_banktypeid[uc_row] = 0 THEN
	MessageBox('系统提示','请先选择本厂结算方式')
	dw_uc.SetFocus()
	dw_uc.SetColumn("u_saletask_banktypeid")
	RETURN
END IF


//IF dw_uc.Object.u_saletask_typeid[uc_row] = 0 THEN
//	MessageBox('系统提示','请先选择销售订单分类')
//	dw_uc.SetFocus()
//	dw_uc.SetColumn("u_saletask_typeid")
//	RETURN
//END IF



obj_saletask.requiredate = ld_requiredate
obj_saletask.assign_emp  = dw_uc.Object.assign_emp[uc_row]
//obj_saletask.upname  = dw_uc.Object.u_saletask_upname[uc_row]
obj_saletask.Kind   = 1
obj_saletask.cusid  = dw_uc.Object.cusid[uc_row]
obj_saletask.dscrp  = dw_uc.Object.dscrp[uc_row]
obj_saletask.dscrp2  = dw_uc.Object.u_saletask_dscrp2[uc_row]
obj_saletask.taskdate  = dw_uc.Object.u_saletask_taskdate[uc_row]
obj_saletask.banktypeid  = dw_uc.Object.u_saletask_banktypeid[uc_row]
obj_saletask.moneyid  = dw_uc.Object.u_saletask_moneyid[uc_row]
obj_saletask.damt  = 0
obj_saletask.otheramt  = dw_uc.Object.u_saletask_otheramt[uc_row]
obj_saletask.relcode  = ins_RelatedCode
obj_saletask.paytype  = dw_uc.Object.u_saletask_paytype[uc_row]
obj_saletask.freight  = dw_uc.Object.u_saletask_freight[uc_row]
obj_saletask.freight_tele  = dw_uc.Object.u_saletask_freight_tele[uc_row]
obj_saletask.cus_address  = dw_uc.Object.u_saletask_cus_address[uc_row]
obj_saletask.cus_tele  = dw_uc.Object.u_saletask_cus_tele[uc_row]
obj_saletask.cus_fax  = dw_uc.Object.u_saletask_cus_fax[uc_row]
obj_saletask.mrate  = dw_uc.Object.u_saletask_mrate[uc_row]
//obj_saletask.typeid  = dw_uc.Object.u_saletask_typeid[uc_row]
obj_saletask.rel_rep  = dw_uc.Object.u_saletask_rel_rep[uc_row]
//obj_saletask.Level  = 2

obj_saletask.sendTime  = ins_addtime
obj_saletask.sendUser  = ins_adduser
obj_saletask.fiebrelcode  = ins_RelatedCode



FOR i = 1 To dw_child.RowCount()
	IF dw_child.Object.mtrlid[i] > 0 THEN
		IF obj_saletask.acceptmx(dw_child.Object.mtrlid[i],&
			dw_child.Object.saleqty[i],&
			0,0,&
			dw_child.Object.u_saletaskmx_enprice[i],&
			dw_child.Object.u_saletaskmx_rebate[i],&
			0,&
			dw_child.Object.u_saletaskmx_mxdscrp[i],&
			dw_child.Object.u_mtrldef_mtrlcode[i],&
			dw_child.Object.u_saletaskmx_status[i],&
			dw_child.Object.u_saletaskmx_woodcode[i],&
			dw_child.Object.u_saletaskmx_pcode[i],&
			dw_child.Object.u_saletaskmx_mtrlcuscode[i],&
			dw_child.Object.pid[i],&
			0,&
			ref arg_msg,&
			dw_child.Object.u_mtrldef_unit[i],&
			1,&
			'',&
			0,&
			dw_child.Object.u_saletaskmx_mxdscrp2[i],&
			0,&
			'',&
			0) = 0 THEN
			MessageBox('error!','第'+String(i)+'行,'+arg_msg)
			RETURN
		END IF
		arr_org_printid[UpperBound(arr_org_printid)+1] = dw_child.Object.u_saletaskmx_printid[i]
	END IF
NEXT

IF obj_saletask.savesubmit(publ_operator,arg_msg,True) = 0 THEN
	MessageBox('error!',arg_msg)
	RETURN
END IF

//更新本地通信记录
UPDATE LJFIEB_packet
	SET status = 6,
	Complete =  1,
	ConfirmTime = getdate(),
	ConfirmUser = :publ_operator
	Where SerialNum = :ins_sn Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	ROLLBACK Using tr_eb_sqlca;
	MessageBox('Error','更新本地通信记录失败,'+tr_eb_sqlca.SQLErrText)
	RETURN
END IF

// DONE: 获取附件并保存
//====================================================================
// 保存附件
//====================================================================
uo_fj_mng_billtype ls_uo_btfj
ls_uo_btfj = Create uo_fj_mng_billtype
Long ll_classid = 0, ll_fileid, ll_cnt = 0
s_fileinfo s_file
datastore ds_file
ds_file = Create datastore
ds_file.DataObject = 'ds_ljfieb_file_receive'
ds_file.SetTransObject(tr_eb_sqlca)

Long ll_scid, ll_taskid, ll_j

SELECT scid,TaskID
	INTO :ll_scid, :ll_taskid
	FROM LJFIEB_tempbuyTask
	WHERE SerialNum = :ins_sn
	Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	ROLLBACK Using tr_eb_sqlca;
	MessageBox('Error','更新本地通信记录失败,'+tr_eb_sqlca.SQLErrText)
	RETURN
END IF

// DONE: 获取销售订单附件分类

SELECT TOP 1 ClassID
INTO :ll_classid
FROM U_FileClass WHERE billtype = 102;
IF sqlca.SQLCode <> 0 THEN
	MessageBox('Error','查询销售订单附件分类失败,'+sqlca.SQLErrText)
	RETURN
END IF



//====================================================================
// 保存附件
//====================================================================
// DONE: 采购订单附件billtype
ds_file.Retrieve(ins_sn, 401,ll_scid, ll_taskid, 0)
FOR ll_j = 1 To ds_file.RowCount()
	s_file.DisplayName = ds_file.Object.DisplayName[ll_j]
	s_file.Filename = ds_file.Object.Filename[ll_j]
	s_file.ClassID = ll_classid
	s_file.FileType = ds_file.Object.FileType[ll_j]
	s_file.dscrp = ds_file.Object.dscrp[ll_j]
	s_file.Opdate = ds_file.Object.Opdate[ll_j]
	s_file.Opemp = ds_file.Object.Opemp[ll_j]
	s_file.relid = obj_saletask.TaskID
	s_file.relid_mx = 0
	s_file.scid = ins_scid
	s_file.billtype = 102 // DONE: 销售订单附件billtype
	s_file.relcode = obj_saletask.taskcode
	s_file.relcode_mx = ''
	
	ll_fileid = ds_file.Object.fileid[ll_j]
	SelectBlob filedata
	Into :s_file.filedata
	From LJFIEB_file
	Where SerialNum = :ins_sn
	And fileid = :ll_fileid
	Using tr_eb_sqlca;
	IF tr_eb_sqlca.SQLCode <> 0 THEN
		ROLLBACK;
		MessageBox('Error','查询附件数据失败,'+tr_eb_sqlca.SQLErrText)
		RETURN
	END IF
	IF ls_uo_btfj.uf_save_fj( s_file, ll_fileid, sys_fileDB_sqlca , arg_msg ) <> 1 THEN
		ROLLBACK;
		MessageBox('Error','保存附件失败,'+arg_msg)
		RETURN
	END IF
NEXT

// DONE: 获取销售订单明细附件分类
SELECT TOP 1 ClassID
INTO :ll_classid
FROM U_FileClass WHERE billtype = 9102;
IF sqlca.SQLCode <> 0 THEN
	MessageBox('Error','查询销售订单明细附件分类失败,'+sqlca.SQLErrText)
	RETURN
END IF


//====================================================================
// 保存明细附件
//====================================================================
FOR i = 1 To UpperBound(arr_org_printid)
	// DONE: 采购订单明细附件billtype
	ds_file.Retrieve(ins_sn, 9401,ll_scid, ll_taskid, arr_org_printid[i])
	FOR ll_j = 1 To ds_file.RowCount()
		s_file.DisplayName = ds_file.Object.DisplayName[ll_j]
		s_file.Filename = ds_file.Object.Filename[ll_j]
		s_file.ClassID = ll_classid
		s_file.FileType = ds_file.Object.FileType[ll_j]
		s_file.dscrp = ds_file.Object.dscrp[ll_j]
		s_file.Opdate = ds_file.Object.Opdate[ll_j]
		s_file.Opemp = ds_file.Object.Opemp[ll_j]
		s_file.relid = obj_saletask.TaskID
		s_file.relid_mx = ll_j
		s_file.scid = ins_scid
		s_file.billtype = 9102 // DONE: 销售订单附件billtype
		s_file.relcode = obj_saletask.taskcode
		s_file.relcode_mx = ''
		
		ll_fileid = ds_file.Object.fileid[ll_j]
		SelectBlob filedata
		Into :s_file.filedata
		From LJFIEB_file
		Where SerialNum = :ins_sn
		And fileid = :ll_fileid
		Using tr_eb_sqlca;
		IF tr_eb_sqlca.SQLCode <> 0 THEN
			ROLLBACK;
			MessageBox('Error','查询附件数据失败,'+tr_eb_sqlca.SQLErrText)
			RETURN
		END IF
		IF ls_uo_btfj.uf_save_fj( s_file, ll_fileid, sys_fileDB_sqlca , arg_msg ) <> 1 THEN
			ROLLBACK;
			MessageBox('Error','保存附件失败,'+arg_msg)
			RETURN
		END IF
	NEXT
	
NEXT

String ls_SerialNum

SELECT  TOP 1 NEWID() INTO :ls_SerialNum
	From u_user Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	ROLLBACK Using sqlca;
	MessageBox('Error','生成序列号失败,'+sqlca.SQLErrText)
	RETURN
END IF

IF IsNull(ls_SerialNum) THEN ls_SerialNum = ''

IF ls_SerialNum = '' THEN
	MessageBox('Error','错误的发送序列号')
	RETURN
END IF


IF uo_fieb.add_packet(ls_SerialNum,'',ins_receid,ins_reccesccode,ins_sendid,ins_sendsccode,6,'接受订单','','',ins_sn,ins_RelatedCode,0,arg_msg,True) = 0 THEN
	MessageBox('系统提示','发送确认指令失败 '+arg_msg)
	RETURN
END IF

ins_returncode = obj_saletask.taskcode

IF MessageBox('系统提示','成功生成销售订单:'+ins_returncode+',是否马上打开?',question!,yesno!) = 2 THEN ins_returncode = ''

Close(Parent)


end event

type cb_feedback from uo_imflatbutton within w_buytask_receive_ljfieb
integer x = 293
integer width = 421
integer height = 164
integer taborder = 10
boolean bringtotop = true
string text = "反馈修改内容"
string normalpicname = "p1.BMP"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;IF Not f_power_ind(1576) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

If dw_uc.GetRow() <= 0 Then Return

IF dw_child.RowCount() <= 0 THEN
	MessageBox('系统提示','没有可反馈的明细内容')
	RETURN
END IF

IF MessageBox('询问','确认要反馈此单据的修改内容吗?',question!,yesno!) = 2 THEN RETURN

s_buytaskmx_feedback_ljfieb arg_s_mx[]
Long ll_i
String arg_summary,arg_postscript,arg_remark
String arg_msg,ls_postscript,ls_postscript_mx
string ls_mtrlcode
s_packet_ljfieb s_pack,s_return

dw_child.AcceptText()
dw_uc.AcceptText()

For ll_i = 1 To dw_child.RowCount()
	
	ls_postscript_mx = ''
	
	If dw_child.Object.u_saletaskmx_spt_uqty[ll_i] <> dw_child.Object.saleqty[ll_i] Then
		ls_postscript_mx = ls_postscript_mx + '回复数量'
		ls_postscript_mx += '(' + string(dw_child.Object.saleqty[ll_i], '#,##0.##') + '->' + string(dw_child.Object.u_saletaskmx_spt_uqty[ll_i], '#,##0.##') + ')'
	End If
	
	If dw_child.Object.u_saletaskmx_spt_enprice[ll_i] <> dw_child.Object.u_saletaskmx_enprice[ll_i] Then
		If Trim(ls_postscript_mx) = '' Then
			ls_postscript_mx = ls_postscript_mx + '回复单价'
		Else
			ls_postscript_mx = ls_postscript_mx + ',回复单价'
		End If
		ls_postscript_mx += '(' + string(dw_child.Object.u_saletaskmx_enprice[ll_i], '#,##0.##') + '->' + string(dw_child.Object.u_saletaskmx_spt_enprice[ll_i], '#,##0.##') + ')'
	End If
	
	If dw_child.Object.u_saletaskmx_spt_requiredate[ll_i] <> dw_child.Object.u_saletaskmx_requiredate[ll_i] Then
		If Trim(ls_postscript_mx) = '' Then
			ls_postscript_mx = ls_postscript_mx + '回复交期'
		Else
			ls_postscript_mx = ls_postscript_mx + ',回复交期'
		End If
		ls_postscript_mx += '(' + string(dw_child.Object.u_saletaskmx_requiredate[ll_i], 'yyyy-MM-dd') + '->' + string(dw_child.Object.u_saletaskmx_spt_requiredate[ll_i], 'yyyy-MM-dd') + ')'
	End If
	
	If dw_child.Object.spt_status[ll_i] <> dw_child.Object.u_saletaskmx_status[ll_i] Then
		If Trim(ls_postscript_mx) = '' Then
			ls_postscript_mx = ls_postscript_mx + '回复'+sys_option_change_status
		Else
			ls_postscript_mx = ls_postscript_mx + ',回复'+sys_option_change_status
		End If
		ls_postscript_mx += '(' + dw_child.Object.u_saletaskmx_status[ll_i] + '->' + dw_child.Object.spt_status[ll_i] + ')'
	End If
	
	If dw_child.Object.spt_woodcode[ll_i] <> dw_child.Object.u_saletaskmx_woodcode[ll_i] Then
		If Trim(ls_postscript_mx) = '' Then
			ls_postscript_mx = ls_postscript_mx + '回复'+sys_option_change_woodcode
		Else
			ls_postscript_mx = ls_postscript_mx + ',回复'+sys_option_change_woodcode
		End If
		ls_postscript_mx += '(' + dw_child.Object.u_saletaskmx_woodcode[ll_i] + '->' + dw_child.Object.spt_woodcode[ll_i] + ')'
	End If
	
	If dw_child.Object.spt_pcode[ll_i] <> dw_child.Object.u_saletaskmx_pcode[ll_i] Then
		If Trim(ls_postscript_mx) = '' Then
			ls_postscript_mx = ls_postscript_mx + '回复'+sys_option_change_pcode
		Else
			ls_postscript_mx = ls_postscript_mx + ',回复'+sys_option_change_pcode
		End If
		ls_postscript_mx += '(' + dw_child.Object.u_saletaskmx_pcode[ll_i] + '->' + dw_child.Object.spt_pcode[ll_i] + ')'
	End If
	
	If dw_child.Object.spt_dscrp[ll_i] <> dw_child.Object.u_saletaskmx_mxdscrp[ll_i] Then
		If Trim(ls_postscript_mx) = '' Then
			ls_postscript_mx = ls_postscript_mx + '回复明细备注'
		Else
			ls_postscript_mx = ls_postscript_mx + ',回复明细备注'
		End If
		ls_postscript_mx += '(' + dw_child.Object.u_saletaskmx_mxdscrp[ll_i] + '->' + dw_child.Object.spt_dscrp[ll_i] + ')'
	End If
	
	If Trim(ls_postscript_mx) <> '' Then
		ls_postscript_mx = '第'+String(ll_i)+'行,'+ls_postscript_mx+';'+'~r~n'
		ls_postscript = ls_postscript + ls_postscript_mx
	End If
	
Next

s_pack.summary = '订单:'+ins_RelatedCode+' 内容反馈'
s_pack.postscript = '订单:' + dw_uc.Object.taskcode[dw_uc.GetRow()] + '内容反馈' + '~r~n' + ls_postscript


OpenWithParm(w_dscrp_edit_ljfieb,s_pack)

s_return = Message.PowerObjectParm

IF s_return.returnflag <> 1 THEN RETURN

arg_summary = s_return.summary
arg_postscript = s_return.postscript
arg_remark = s_return.remark

FOR ll_i = 1 To dw_child.RowCount()
	arg_s_mx[ll_i].printid = dw_child.Object.u_saletaskmx_printid[ll_i]
	arg_s_mx[ll_i].spt_uqty = dw_child.Object.u_saletaskmx_spt_uqty[ll_i]
	arg_s_mx[ll_i].spt_enprice = dw_child.Object.u_saletaskmx_spt_enprice[ll_i]
	arg_s_mx[ll_i].spt_Requiredate = dw_child.Object.u_saletaskmx_spt_requiredate[ll_i]
	arg_s_mx[ll_i].spt_status = dw_child.Object.spt_status[ll_i]
	arg_s_mx[ll_i].spt_woodcode = dw_child.Object.spt_woodcode[ll_i]
	arg_s_mx[ll_i].spt_pcode = dw_child.Object.spt_pcode[ll_i]
	arg_s_mx[ll_i].spt_dscrp = dw_child.Object.spt_dscrp[ll_i]
NEXT

IF uo_fieb.feedback_buytask(ins_sn,arg_s_mx,arg_summary,arg_postscript,arg_remark,arg_msg,True,dw_uc.Object.spt_dscrp[dw_uc.GetRow()], dw_uc.Object.spt_dscrp2[dw_uc.GetRow()]) = 0 THEN
	MessageBox('Error',arg_msg)
	RETURN
END IF

MessageBox('系统提示','反馈成功!')
Close(Parent)


end event

type cb_reject from uo_imflatbutton within w_buytask_receive_ljfieb
integer x = 731
integer width = 219
integer height = 164
integer taborder = 30
boolean bringtotop = true
string text = "拒绝"
string normalpicname = "DELETE.BMP"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;IF Not f_power_ind(1577) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

String arg_summary,arg_postscript,arg_remark
s_packet_ljfieb s_pack,s_return
Int rslt = 1
String arg_msg
String ls_SerialNum

//s_pack.summary = '拒绝订单:'+ins_RelatedCode

OpenWithParm(w_dscrp_edit_ljfieb,s_pack)

s_return = Message.PowerObjectParm

IF s_return.returnflag <> 1 THEN RETURN

//arg_summary = s_return.summary
arg_postscript = s_return.postscript
arg_remark = s_return.remark

//更新本地通信记录
UPDATE LJFIEB_packet
	SET status = 10,
	Complete = 1,
	ConfirmTime = getdate(),
	ConfirmUser = :publ_operator
	Where SerialNum = :ins_sn Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '更新本地通信记录失败,'+tr_eb_sqlca.SQLErrText
	GOTO ext
END IF


SELECT  TOP 1 NEWID() INTO :ls_SerialNum
	From u_user Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '生成序列号失败,'+sqlca.SQLErrText
	GOTO ext
END IF

IF IsNull(ls_SerialNum) THEN ls_SerialNum = ''

IF ls_SerialNum = '' THEN
	rslt = 0
	arg_msg = '错误的发送序列号'
	GOTO ext
END IF

INSERT INTO LJFIEB_tempbuyTask
	(scid, TaskID, TaskCode, orderid, kind, sptID, requiredate, accomplishdate, finishemp,
	Status, Opemp, Modemp, moddate, Assign_Emp, Permit_Emp, Permit_date, Dscrp,
	opdate, stopemp, ctmint, printnum, relcode, banktypeid, train, reason, billtype,
	firpermitemp, firpermitdate, billamt, moneyid, mrate, serialnum,banktypename,moneyname,cusid)
	SELECT scid, TaskID, TaskCode, orderid, kind, sptID, requiredate, accomplishdate,
	finishemp, 11, Opemp, Modemp, moddate, Assign_Emp, Permit_Emp,
	Permit_date, Dscrp, opdate, stopemp, ctmint, printnum, relcode, banktypeid, train,
	reason, billtype, firpermitemp, firpermitdate, billamt, moneyid, mrate, :ls_SerialNum,banktypename,moneyname,cusid
	FROM LJFIEB_tempbuyTask
	Where SerialNum = :ins_sn Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '插入临时采购订单表失败,'+tr_eb_sqlca.SQLErrText
	GOTO ext
END IF

IF uo_fieb.add_packet(ls_SerialNum,'LJFIEB_tempbuyTask',ins_receid,ins_reccesccode,ins_sendid,ins_sendsccode,11,arg_summary,arg_postscript,arg_remark,ins_sn,ins_RelatedCode,0,arg_msg,False) = 0 THEN
	rslt = 0
	arg_msg = '发送确认指令失败 '+arg_msg
	GOTO ext
END IF
ext:
IF rslt = 1 THEN
	COMMIT Using tr_eb_sqlca;
	MessageBox('系统提示','操作成功')
	Close(Parent)
ELSE
	ROLLBACK Using tr_eb_sqlca;
	MessageBox('系统提示',arg_msg)
END IF


end event

type mle_2 from multilineedit within w_buytask_receive_ljfieb
integer x = 2377
integer y = 1136
integer width = 1193
integer height = 336
integer taborder = 50
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
boolean vscrollbar = true
boolean autovscroll = true
boolean displayonly = true
borderstyle borderstyle = stylelowered!
end type

type st_3 from statictext within w_buytask_receive_ljfieb
integer x = 2382
integer y = 1076
integer width = 137
integer height = 48
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "备注"
boolean focusrectangle = false
end type

type cb_1 from uo_imflatbutton within w_buytask_receive_ljfieb
integer x = 969
integer width = 219
integer height = 164
integer taborder = 40
boolean bringtotop = true
string text = "匹配"
string normalpicname = "update2.BMP"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;openwithparm(w_mtrl_receive_ljfieb, '')
string arg_msg
IF wf_retrieve(ins_sn,ins_sendid,ins_sendsccode,arg_msg) = 0 THEN
	MessageBox('Error',arg_msg)
	RETURN
END IF
end event

type ln_bar from line within w_buytask_receive_ljfieb
long linecolor = 268435456
integer linethickness = 4
integer beginy = 172
integer endx = 3200
integer endy = 172
end type

type ln_bar2 from line within w_buytask_receive_ljfieb
long linecolor = 16777215
integer linethickness = 4
integer beginx = 9
integer beginy = 176
integer endx = 3273
integer endy = 176
end type

type ln_1 from line within w_buytask_receive_ljfieb
long linecolor = 268435456
integer linethickness = 4
integer beginy = 284
integer endx = 3250
integer endy = 284
end type

type ln_2 from line within w_buytask_receive_ljfieb
long linecolor = 16777215
integer linethickness = 4
integer beginy = 288
integer endx = 3282
integer endy = 288
end type

type r_bar from rectangle within w_buytask_receive_ljfieb
long linecolor = 16777215
integer linethickness = 4
long fillcolor = 1073741824
integer x = 3351
integer width = 87
integer height = 68
end type

event constructor;this.fillcolor = 14215660
this.linecolor = 14215660
this.x = -1
this.y = -1
this.height = ln_bar.beginy - 5

end event