Q5/ws_objects/Ew_gz.pbl.src/w_gz_loanwage.srw

$PBExportHeader$w_gz_loanwage.srw
forward
global type w_gz_loanwage from w_publ_1ton_share_detail
end type
type ddlb_status from dropdownlistbox within w_gz_loanwage
end type
type st_2 from statictext within w_gz_loanwage
end type
end forward

global type w_gz_loanwage from w_publ_1ton_share_detail
integer x = 0
integer y = 400
integer height = 1972
string title = "借支单"
event ue_fj_edit ( )
event ue_fj_view ( )
ddlb_status ddlb_status
st_2 st_2
end type
global w_gz_loanwage w_gz_loanwage

type variables
uo_loanwage uo_loanwage_dq
Int cur_flag = -1


end variables

forward prototypes
public function integer wf_refresh_curuc (long arg_billid)
public subroutine wf_check_billfj ()
public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg)
end prototypes

event ue_fj_edit();IF dw_edit_mode THEN
	MessageBox('提示','编辑状态下不可用', Information!, OK! )
	RETURN
END IF

//IF NOT f_power_ind(1446) THEN
//	MessageBox(publ_operator,'你没有使用权限！')
//	RETURN
//END IF

s_edit_index_tran s_pic
Long ll_ConnectionID
String arg_msg
Long ls_row
ls_row = dw_uc.GetRow() 
IF ls_row <= 0 THEN
	RETURN
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	MessageBox('提示','没有指定附件数据库连接'+arg_msg, Information!, OK! )
	RETURN
END IF

s_pic.f_long = 721 //采购订单的mainID
s_pic.f_string = dw_uc.Object.u_gz_loanwage_billcode[ls_row]
s_pic.g_long = dw_uc.Object.u_gz_loanwage_billid[ls_row]
s_pic.e_long = 0
s_pic.sqltransaction = sys_filedb_sqlca


OpenWithParm(w_fj_bill_mng,s_pic)
//wf_check_billfj()
end event

event ue_fj_view();IF dw_edit_mode THEN
	MessageBox('提示','编辑状态下不可用', Information!, OK! )
	RETURN
END IF

s_edit_index_tran s_pic
Long ll_ConnectionID
String arg_msg
Long ls_row
ls_row = dw_uc.GetRow()
IF ls_row <= 0 THEN
	RETURN
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	MessageBox('提示','没有指定附件数据库连接'+arg_msg, Information!, OK! )
	RETURN
END IF

s_pic.f_long = 721 //采购订单的mainID
s_pic.f_string = dw_uc.Object.u_gz_loanwage_billcode[ls_row]
s_pic.g_long = dw_uc.Object.u_gz_loanwage_billid[ls_row]
s_pic.e_long = 0
s_pic.sqltransaction = sys_filedb_sqlca


OpenWithParm(w_fj_bill_view,s_pic)



end event

public function integer wf_refresh_curuc (long arg_billid);IF arg_billid <= 0 OR IsNull(arg_billid) THEN RETURN 0
Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN RETURN 0

long billid 
long wageid 
string empcode 
datetime billdate
decimal loanamt 
string loanreason 
string cardcode  
long returndate 
string dscrp
long empid 
string billcode 
long wagemth 
datetime moddate  
string modemp 
datetime auditdate  
int flag 
string auditrep 
datetime opdate 
string opemp 
string empname 

  SELECT u_gz_loanwage.billid,   
         u_gz_loanwage.wageid,   
         u_rs_empinfo.Empcode,   
         u_gz_loanwage.billdate,   
         u_gz_loanwage.loanamt,   
         u_gz_loanwage.loanreason,   
         u_gz_loanwage.cardcode,   
         u_gz_loanwage.returndate,   
         u_gz_loanwage.dscrp,   
         u_gz_loanwage.empid,   
         u_gz_loanwage.billcode,   
         u_gz_loanwage.wagemth,   
         u_gz_loanwage.moddate,   
         u_gz_loanwage.modemp,   
         u_gz_loanwage.auditdate,   
         u_gz_loanwage.flag,   
         u_gz_loanwage.auditrep,   
         u_gz_loanwage.opdate,   
         u_gz_loanwage.opemp,   
         u_rs_empinfo.Empname  
	 into :billid,   
         :wageid,   
         :Empcode,   
         :billdate,   
         :loanamt,   
         :loanreason,   
         :cardcode,   
         :returndate,   
         :dscrp,   
         :empid,   
         :billcode,   
         :wagemth,   
         :moddate,   
         :modemp,   
         :auditdate,   
         :flag,   
         :auditrep,   
         :opdate,   
         :opemp,   
         :Empname
    FROM u_gz_loanwage,   
         u_rs_empinfo  
   WHERE ( u_gz_loanwage.empid = u_rs_empinfo.empid )   
	  and ( u_gz_loanwage.billid = :arg_billid );

IF sqlca.SQLCode <> 0 THEN
	MessageBox('系统提示',"查询借支单操作失败"+sqlca.SQLErrText, Information!, OK! )
	RETURN 0
END IF
dw_pageretr.Object.u_gz_loanwage_billid[uc_row]=arg_billid
dw_pageretr.Object.u_gz_loanwage_wageid[uc_row]=wageid
dw_pageretr.object.u_rs_empinfo_empcode[uc_row]=empcode
dw_pageretr.object.u_gz_loanwage_billdate[uc_row]=billdate
dw_pageretr.object.u_gz_loanwage_loanamt[uc_row]=loanamt
dw_pageretr.object.u_gz_loanwage_loanreason[uc_row]=loanreason
dw_pageretr.object.u_gz_loanwage_cardcode[uc_row]=cardcode
dw_pageretr.object.u_gz_loanwage_returndate[uc_row]=returndate
dw_pageretr.object.u_gz_loanwage_dscrp[uc_row]=dscrp
dw_pageretr.object.u_gz_loanwage_empid[uc_row]=empid
dw_pageretr.object.u_gz_loanwage_billcode[uc_row]=billcode
dw_pageretr.object.u_gz_loanwage_wagemth[uc_row]=wagemth
dw_pageretr.object.u_gz_loanwage_moddate[uc_row]=moddate
dw_pageretr.object.u_gz_loanwage_modemp[uc_row]=modemp
dw_pageretr.object.u_gz_loanwage_auditdate[uc_row]=auditdate
dw_pageretr.object.u_gz_loanwage_flag[uc_row]=flag
dw_pageretr.object.u_gz_loanwage_auditrep[uc_row]=auditrep
dw_pageretr.object.u_gz_loanwage_opdate[uc_row]=opdate
dw_pageretr.object.u_gz_loanwage_opemp[uc_row]=opemp
dw_pageretr.object.u_rs_empinfo_empname[uc_row]=empname

dw_uc.Reset()
dw_pageretr.RowsCopy(dw_pageretr.GetRow(), dw_pageretr.GetRow(), Primary!, dw_uc, 1, Primary!)

dw_uc.ResetUpdate()
dw_uc.SetRedraw(TRUE)

return 1



end function

public subroutine wf_check_billfj ();String arg_msg
Long ll_ConnectionID
Long cur_billtype
long ll_relid,ll_relid_mx,ll_scid
Long ls_filecount = 0
Int rslt = 1

uo_fj_mng_billtype ls_uo_fjbt
ls_uo_fjbt = CREATE uo_fj_mng_billtype
 
Long row,uc_relid
row = dw_pageretr.GetRow()
IF row > 0 THEN
	ll_relid = dw_pageretr.Object.u_gz_loanwage_billid[row]
	ll_scid = 0
	ll_relid_mx = 0
ELSE
	rslt = 0
	GOTO ext
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

cur_billtype = 721 //客户投拆单的 mainiD

ls_uo_fjbt.uf_check_billfj( cur_billtype, ll_relid,ll_relid_mx,ll_scid, sys_fileDB_sqlca, arg_msg, ls_filecount)

IF ls_filecount > 0 THEN
	rslt = 1
	GOTO ext
ELSE
	rslt = 0
	GOTO ext
END IF

ext:

wf_encl(rslt)

DESTROY ls_uo_fjbt
end subroutine

public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg);//==============================================================================
// 函数: w_publ_1ton_share_detail::wf_xls_retrievedata()
//------------------------------------------------------------------------------
// 描述:  此函数需要 重载,复制祖先范例代码,然后修改retrieve参数部分两处即可
//------------------------------------------------------------------------------

Long LS_ROW,ll_id,i,ll_scid
LS_ROW = dw_uc.GetRow()
IF LS_ROW <= 0 THEN
	arg_msg = '没有目标单据!'
	RETURN 0
END IF

//修改点:获取 指定retriev参数
ll_id = dw_uc.Object.#1[LS_ROW]
ll_scid = 0

//查询所选模版是否含有图片信息
Long ll_ifpic
Long ll_classid
SELECT ifpic
	INTO :ll_ifpic
	FROM U_XLS_Templates
	Where id = :ll_xls_Templatesid;
IF sqlca.SQLCode <> 0 THEN
	ll_ifpic = 0
END IF

Long ll_i,ll_j
Long ll_mtrlid
Long ll_fileid

Blob ls_filedata
SetNull(ls_filedata)
String Pathname,ls_filename,ls_filetype
String errmsg
uo_fj_mng_billtype  ls_uo_fjbt
ls_uo_fjbt = CREATE uo_fj_mng_billtype

s_xls_pic_list s_pic //结构数组-用于保存图片路径

IF ll_ifpic = 1 THEN //如果含有图片信息,则查询本类型单据需要带出哪类附件

	SELECT classid
		INTO :ll_classid
		FROM u_billpic_fileclass
		Where (billtype = 728);
	IF sqlca.SQLCode <> 0 THEN
		ll_classid = 0
	END IF
	
	IF ll_classid > 0 THEN //如果已经指定好附件类型,则循环明细表查询每个明细的图片信息.
		FOR ll_i = 1 TO dw_child.RowCount()
			ll_mtrlid = dw_child.Object.mtrlid[ll_i]
			//取该附件类型中的第一个附件.
			SELECT top 1 fileid,DisplayName,FileType INTO :ll_fileid,:ls_filename,:ls_filetype
				FROM u_file
				WHERE relid = :ll_mtrlid
				AND classid = :ll_classid
				AND (filetype = 'bmp' OR filetype = 'rle' OR filetype = 'wmf'
				OR filetype = 'tif' OR filetype = 'jpg' OR filetype = 'gif' OR filetype = 'jpeg')
				USING sys_fileDB_sqlca;
			IF sys_fileDB_sqlca.SQLCode <> 0 THEN
				ll_fileid = 0
			END IF
			IF ll_fileid > 0 THEN
				Pathname = sys_cur_path+ins_fjtemppath+'\'+String(Today(),'yymmdd')+String(Now(),'hhmmss')+'_'+ls_filename+'.'+ls_filetype
				IF Trim(Pathname) <> '' THEN
					IF ls_uo_fjbt.uf_getfjbolb_fromdb( ll_fileid, ls_filedata, sys_fileDB_sqlca, arg_msg) = 0 THEN
						RETURN  0
					END IF
					
					IF f_saveblobtofile(ls_filedata,Pathname,errmsg) = 0 THEN
						RETURN 0
					ELSE
						
						s_pic.path[ll_i] = Pathname
						//记录临时文件位置,本窗口退出后删除
						wf_addlog_tempfilepathname(Pathname)
						
					END IF
				ELSE
					s_pic.path[ll_i] = ''
				END IF
			ELSE
				s_pic.path[ll_i] = ''
			END IF
		NEXT
	END IF
	//
END IF

////可选设置///
arg_obj_st.uo_const.create_new_pwd( )  //创建随机密码 
if sys_option_xls_ifuse_passwd = 1 then arg_obj_st.uo_const.pwd = trim(sys_option_xls_user_passwd)   //默认加密密码    默认为随即密码


boolean xls_locked
xls_locked = not (sys_option_xls_lock = 1)

/// Excel 的可选设置
if arg_obj_st.of_setoption(arg_ationid,  xls_locked,true,arg_msg) <> 1 then
		return 0
end if


for i = 1 to arg_str_billlist.count
	////可选操作///
	arg_str_billlist.bill[i].ds_data = create datastore                                  //
	arg_str_billlist.bill[i].ds_data.dataobject = arg_str_billlist.bill[i].datawindow       //
	arg_str_billlist.bill[i].ds_data.settransobject(sqlca)
	
	//修改点:注意retrieve 参数与上文对应
	arg_str_billlist.bill[i].ds_data.retrieve(ll_scid,ll_id)

next 

return 1
end function

on w_gz_loanwage.create
int iCurrent
call super::create
this.ddlb_status=create ddlb_status
this.st_2=create st_2
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.ddlb_status
this.Control[iCurrent+2]=this.st_2
end on

on w_gz_loanwage.destroy
call super::destroy
destroy(this.ddlb_status)
destroy(this.st_2)
end on

event ue_usual_query_retr;call super::ue_usual_query_retr;string ls_querystrpart=''
ls_newselect=lower(ori_oldselect)
if trim(sle_usual_query.text)<>'' then
	if pos(trim(sle_usual_query.text),'%')=0 then
		ls_querystrpart="(u_gz_loanwage.billcode like '%"+trim(sle_usual_query.text)+"%')"
	else
		ls_querystrpart="(u_gz_loanwage.billcode like '"+trim(sle_usual_query.text)+"')"
	end if

	if pos(ls_newselect," where ") <> 0 then
	   ls_newselect=ls_newselect+" and ("+ls_querystrpart+')'
	else
		ls_newselect=ls_newselect+" where ("+ls_querystrpart+')'
	end if
end if
wf_retrieveuc(dw_pageretr,ls_newselect,1)  
this.triggerevent('retrieve_pageretr')

end event

event ue_usual_query_filt;call super::ue_usual_query_filt;string obj_expr=''  
if trim(sle_usual_query.text)<>'' then 
	if pos(trim(sle_usual_query.text),'%')=0 then
		obj_expr=obj_expr+'( u_gz_loanwage_billcode like "%'+trim(sle_usual_query.text)+'%" )'
	else
		obj_expr=obj_expr+'( u_gz_loanwage_billcode like "'+trim(sle_usual_query.text)+'" )'
	end if 
end if

dw_pageretr.setfilter(obj_expr)

dw_pageretr.setredraw(false)
dw_pageretr.filter()
if dw_pageretr.rowcount()>=1 then
	dw_pageretr.selectrow(0,false)
	dw_pageretr.selectrow(1,true)
end if
dw_pageretr.setredraw(true)
end event

event close;call super::close;destroy uo_loanwage_dq
wf_del_tempfilepathname()
end event

event open;call super::open;uc_column_int=9    //uc dw前6列可以编辑
uo_loanwage_dq =create uo_loanwage
end event

event refresh_interface;call super::refresh_interface;ddlb_status.enabled=not dw_edit_mode
end event

event retrieve_pageretr;Boolean cb_nextpage_enabled,cb_retrieveall_enabled
Boolean cb_func_enabled,cb_retrieve_enabled

cb_nextpage_enabled = cb_nextpage.Enabled
cb_retrieveall_enabled = cb_retrieveall.Enabled
cb_func_enabled = cb_func.Enabled

cb_nextpage.Enabled = FALSE
cb_retrieveall.Enabled = FALSE
cb_func.Enabled = FALSE

dw_uc.Retrieve()
dw_pageretr.Retrieve(cur_flag)
IF dw_pageretr.RowCount() > 0 THEN
	dw_pageretr.SetRow(1)
	dw_pageretr.TriggerEvent(RowFocusChanged!)
END IF

THIS.TriggerEvent('retrieve_childdw')

cb_nextpage.Enabled = cb_nextpage_enabled
cb_retrieveall.Enabled = cb_retrieveall_enabled
cb_func.Enabled = cb_func_enabled



end event

event ue_f9;call super::ue_f9;if not dw_edit_mode then return
long uc_row,ls_j
s_empselect s_select
string tmp_empcode


uc_row = dw_uc.getrow()
if uc_row = 0 then
	messagebox('系统提示','请选定借支单!', Information!, OK! )
	return
end if
dw_uc.accepttext()
tmp_empcode = trim(dw_uc.object.u_rs_empinfo_empcode[uc_row])
if not isvalid(w_empinfo_choice) then
	openwithparm(w_empinfo_choice,tmp_empcode)
			
	s_select = message.powerobjectparm //接受返回结构
	if s_select.empid > 0 then
		dw_uc.setredraw(false)
		dw_uc.object.u_gz_loanwage_empid[uc_row] = s_select.empid
		dw_uc.object.u_rs_empinfo_empcode[uc_row] = s_select.empcode
		dw_uc.object.u_rs_empinfo_empname[uc_row] = s_select.empname
		dw_uc.setcolumn('u_gz_loanwage_billdate')
		dw_uc.setredraw(true)
	end if
end if
	



      
end event

event ue_viewprint;call super::ue_viewprint;if not f_power_ind(481) then
	messagebox('提示','你没有使用权限！', Information!, OK! )
	return
end if


Long LS_ROW
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('提示','没有打印目标单据!', Information!, OK! )
	RETURN
END IF



S_print_MSG LS_PRMSG

IF ls_newname <> '' THEN
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.u_gz_loanwage_flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('提示','目标单据还未审核,不能打印!', Information!, OK! )
			RETURN
		END IF
	END IF
	ls_prmsg.obj_dwNAME = ls_newname
ELSE	
	ls_prmsg.obj_dwNAME = 'dw_rp_gz_loanwage_edit'
END IF

LS_PRMSG.TAG_TEXT = '借支单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.retr_pram_falg = 2
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_gz_loanwage_billid[LS_ROW]
OpenWithParm(w_publ_preview,LS_PRMSG)

//**更新打印次料
String arg_msg
printnum = Message.DoubleParm
f_update_printnum('u_gz_loanwage',printnum,0,dw_pageretr.Object.u_gz_loanwage_billid[LS_ROW],'','',arg_msg,TRUE)

end event

event ue_print;call super::ue_print;//--直接打印
IF NOT f_power_ind(481) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

uo_print_preview uo_print
S_print_MSG LS_PRMSG
IF dw_pageretr.RowCount() = 0 THEN
	MessageBox('提示','没有可打印的单据！', Information!, OK! )
	RETURN
END IF

IF MessageBox ("询问","是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN


IF ls_newname <> '' THEN
	
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.u_gz_loanwage_flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('询问','目标单据还未审核,不能打印!', Information!, OK! )
			RETURN
		END IF
	END IF
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	LS_PRMSG.obj_dwNAME = 'dw_rp_gz_loanwage_edit'
END IF

LS_PRMSG.retr_pram_falg = 2
LS_PRMSG.TAG_TEXT = '借支单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_gz_loanwage_billid[dw_pageretr.GetRow()]
uo_print.FACT_PRINT_MSG = LS_PRMSG

String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("提示",arg_msg, Information!, OK! )
	RETURN
END IF
uo_print.ds_print()

//**更新打印次料
f_update_printnum('u_gz_loanwage',1,0,dw_pageretr.Object.u_gz_loanwage_billid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)

end event

event ue_addzy;call super::ue_addzy;IF dw_edit_mode THEN
	MessageBox('提示',"编辑状态下不可以使用!", Information!, OK! )
	return
END IF

if not f_power_ind(772) then
	messagebox('提示','你没有使用权限！', Information!, OK! )
	return
end if

string arg_msg=''
string ls_str
long uc_row
s_inputbox s_sreu

uc_row=dw_pageretr.getrow()
if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!', Information!, OK! )
	return
end if
s_sreu.title='请输入要补充到备注的内容'
s_sreu.old_text=''
openwithparm(w_inputbox,s_sreu)
ls_str=message.stringparm
if trim(ls_str)='' or isnull(ls_str) then return

if uo_loanwage_dq.add_dscrp(dw_pageretr.object.u_gz_loanwage_billid[uc_row],ls_str,arg_msg)=0 then
	messagebox('error!',arg_msg)
	return
else
	messagebox('提示','添加备注操作成功!', Information!, OK! )
	wf_refresh_curuc(dw_pageretr.object.u_gz_loanwage_billid[uc_row])
end if
end event

event resize;ln_bar.endx = this.width
ln_bar2.endx = this.width
r_bar.width = this.width
end event

type cb_func from w_publ_1ton_share_detail`cb_func within w_gz_loanwage
end type

type cb_exit from w_publ_1ton_share_detail`cb_exit within w_gz_loanwage
integer x = 2267
end type

type sle_usual_query from w_publ_1ton_share_detail`sle_usual_query within w_gz_loanwage
integer x = 192
integer width = 530
end type

type cb_retrieveall from w_publ_1ton_share_detail`cb_retrieveall within w_gz_loanwage
integer x = 2889
end type

type em_pagerowno from w_publ_1ton_share_detail`em_pagerowno within w_gz_loanwage
integer x = 2551
integer y = 40
integer width = 320
end type

type dw_pageretr from w_publ_1ton_share_detail`dw_pageretr within w_gz_loanwage
event dwnkey pbm_dwnkey
integer x = 2071
integer width = 1486
integer height = 1592
string dataobject = "dw_gz_loanwage_index"
end type

event dw_pageretr::dwnkey;call super::dwnkey;Int h = 0

end event

event dw_pageretr::constructor;call super::constructor; titleclick_sort_use=true  //单击标题排序功能开关
 RBUTTON_FILTER_USE=true  //右键查询功能开关

end event

event dw_pageretr::rowfocuschanged;call super::rowfocuschanged;wf_check_billfj()
end event

type st_1 from w_publ_1ton_share_detail`st_1 within w_gz_loanwage
integer x = 18
integer y = 208
end type

type cb_nextpage from w_publ_1ton_share_detail`cb_nextpage within w_gz_loanwage
integer x = 3040
end type

type dw_uc from w_publ_1ton_share_detail`dw_uc within w_gz_loanwage
integer width = 2062
integer height = 1592
string dataobject = "dw_gz_loanwage_edit"
end type

event dw_uc::dwnkey;PARENT.TriggerEvent('user_key')
IF Key = KeyDownArrow! THEN RETURN 1
IF dw_edit_mode THEN
	
	
	String ls_empcode
	String ls_empname
	Long ll_empid,li_row
	dw_uc.AcceptText()
	li_row = dw_uc.GetRow()
	
	IF dw_uc.GetColumnName ( ) = 'u_rs_empinfo_empcode' AND Key = keyenter! THEN
		ls_empcode = Trim(dw_uc.Object.u_rs_empinfo_empcode[li_row])
		SELECT empid,empname INTO :ll_empid,:ls_empname FROM u_rs_empinfo Where empcode = :ls_empcode;
		dw_uc.SetRedraw(FALSE)
		IF sqlca.SQLCode <> 0 THEN
			PARENT.TriggerEvent('ue_f9')
			RETURN 1
		ELSE
			dw_uc.Object.u_gz_loanwage_empid[li_row] = ll_empid
			dw_uc.Object.u_rs_empinfo_empname[li_row] = ls_empname
		END IF
		dw_uc.SetRedraw(TRUE)
		dw_uc.SetColumn("u_gz_loanwage_billdate")
		RETURN 1
		
	ELSE
		IF  Key = keyenter!  OR Key = KeyDownArrow! THEN //
			keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
			keybd_event ( 9, 0, 2, 0 ) // 释放tab 
			RETURN 1
		ELSEIF Key = keyuparrow! THEN
			keybd_event ( 16, 0, 0 , 0 )
			keybd_event ( 9, 0, 0 , 0 )
			keybd_event ( 9, 0, 2, 0 )
			keybd_event ( 16, 0, 2, 0 )
			RETURN 1
		END IF
	END IF
END IF


end event

event dw_uc::clicked;call super::clicked;if not dw_edit_mode then return

if row <= 0 then return

if dwo.name='p_p' then
	parent.TRIGGEREVENT('ue_f9')	
end if
end event

type gb_2 from w_publ_1ton_share_detail`gb_2 within w_gz_loanwage
end type

type dw_child from w_publ_1ton_share_detail`dw_child within w_gz_loanwage
integer x = 1029
integer y = 2408
integer height = 604
end type

type cb_viewprint from w_publ_1ton_share_detail`cb_viewprint within w_gz_loanwage
integer x = 1623
end type

type cb_print from w_publ_1ton_share_detail`cb_print within w_gz_loanwage
integer x = 1431
end type

type cb_add from w_publ_1ton_share_detail`cb_add within w_gz_loanwage
end type

event cb_add::clicked;if not f_power_ind(204) then
	messagebox('提示','你没有使用权限！', Information!, OK! )
	return
end if


string arg_msg = ''
long uc_row

if dw_edit_mode then
	dw_uc.accepttext()
	uc_row = dw_uc.getrow()
	if uc_row <= 0 then
		messagebox('提示','请选定当前目标单据!', Information!, OK! )
		return
	end if
	
	if not dw_uc.object.u_gz_loanwage_billdate[uc_row] > datetime(2000-01-01,now()) then
		messagebox('提示','不合理计件日期', Information!, OK! )
		return
	end if
	
	if dw_uc.object.u_gz_loanwage_empid[uc_row] = 0 then
		messagebox('提示','请先选择员工', Information!, OK! )
		return
	end if
		
	
	
	uo_loanwage_dq.empid = dw_uc.object.u_gz_loanwage_empid[uc_row]
	uo_loanwage_dq.billdate = dw_uc.object.u_gz_loanwage_billdate[uc_row]
	uo_loanwage_dq.loanamt = dw_uc.object.u_gz_loanwage_loanamt[uc_row]
	uo_loanwage_dq.wageid = dw_uc.object.u_gz_loanwage_wageid[uc_row]
	uo_loanwage_dq.loanreason  = dw_uc.object.u_gz_loanwage_loanreason[uc_row]
	uo_loanwage_dq.cardcode  = dw_uc.object.u_gz_loanwage_cardcode[uc_row]
	uo_loanwage_dq.dscrp  = dw_uc.object.u_gz_loanwage_dscrp[uc_row]
	uo_loanwage_dq.returndate  = dw_uc.object.u_gz_loanwage_returndate[uc_row]
		
//	 u_gz_loanwage_wageid 
//	 u_gz_loanwage_billdate
//	 u_gz_loanwage_loanamt
//	 u_gz_loanwage_loanreason 
//	 u_gz_loanwage_cardcode 
//	 u_gz_loanwage_returndate
//	 u_gz_loanwage_dscrp 
//	 u_gz_loanwage_empid 
	
	if uo_loanwage_dq.save(arg_msg,true) = 0 then
		messagebox('错误',arg_msg, StopSign!, OK! )
		return
	end if
//	messagebox('提示','保存操作成功!')
	//write ini
	f_SetProfileString (sys_empid,dw_uc.DataObject, "ddlb_wageid",String(dw_uc.Object.u_gz_loanwage_wageid[dw_uc.GetRow()]))
	//
	long ll_row
	ll_row = dw_pageretr.getrow()
	dw_pageretr.SelectRow(0,FALSE)
	dw_pageretr.SelectRow(ll_row,TRUE)
	
	wf_refresh_curuc(uo_loanwage_dq.billid)	
else
	if uo_loanwage_dq.newbegin(arg_msg) = 0 then
		messagebox('错误',arg_msg, StopSign!, OK! )
		return
	end if
end if

call super::clicked


if dw_edit_mode then	
	//read ini
	string ls_wageid
	ls_wageid = f_ProfileString (sys_empid,dw_uc.DataObject, "ddlb_wageid",'0')
	dw_uc.object.u_gz_loanwage_wageid[dw_uc.getrow()]=long(ls_wageid)	
	dw_uc.setcolumn('u_gz_loanwage_wageid')
	//
else
	parent.triggerevent("retrieve_childdw")
end if
this.triggerevent('refresh_interface')

// billid
// empcode 
// u_sc_taskworkmx_procode
// u_sc_taskworkmx_proname 
// workprice 
// amount 
// workhour
// u_sc_taskworkmx_mxdscrp 
// empid 
// u_sc_taskworkmx_printid
// empname 
// pid 
// amt 




end event

type cb_edit from w_publ_1ton_share_detail`cb_edit within w_gz_loanwage
end type

event cb_edit::clicked;if not f_power_ind(204) then
	messagebox('提示','你没有使用权限！', Information!, OK! )
	return
end if


string arg_msg=''
long uc_row

uc_row=dw_pageretr.getrow()
if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!', Information!, OK! )
	return
end if

if not dw_edit_mode then
	if uo_loanwage_dq.updatebegin(dw_pageretr.object.u_gz_loanwage_billid[uc_row],arg_msg)=0 then
		messagebox('Error!',arg_msg)
		return
	end if
end if

call super::clicked

end event

type cb_delet from w_publ_1ton_share_detail`cb_delet within w_gz_loanwage
end type

event cb_delet::clicked;call super::clicked;if not f_power_ind(627) then
	messagebox('提示','你没有使用权限！', Information!, OK! )
	return
end if

if dw_edit_mode then return

string arg_msg=''
long uc_row

uc_row=dw_pageretr.getrow()

if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!', Information!, OK! )
	return
end if

IF MessageBox ("询问","是否确定要删除当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN


if uo_loanwage_dq.del(dw_pageretr.object.u_gz_loanwage_billid[uc_row],arg_msg)=0 then
	messagebox('错误',arg_msg, StopSign!, OK! )
ELSE
	//日志
	long ls_id
	string ls_code
	ls_id=dw_pageretr.object.u_gz_loanwage_billid[uc_row]
	ls_code=dw_pageretr.object.u_gz_loanwage_billcode[uc_row]
	f_setsysoplog('借支单','删除,id:'+string(ls_id)+',code:'+ls_code,arg_msg,true)
	//--
	
	MESSAGEBOX('提示','删除单据'+string(dw_pageretr.object.u_gz_loanwage_billcode[uc_row])+'成功!')	
	dw_pageretr.deleterow(uc_row)
	dw_pageretr.postevent(rowfocuschanged!)
end if

end event

type cb_addzy from w_publ_1ton_share_detail`cb_addzy within w_gz_loanwage
end type

event cb_addzy::clicked;call super::clicked;m_Dfc_Control_PopupMenu dmPopupMenu
string menustr


menustr="Text=增加备注~tEvent=ue_addzy"
menustr = menustr + "|" + "Text=-"
menustr = menustr + "|" + "Text=查看附件~tEvent=ue_fj_view"
menustr = menustr + "|" + "Text=添加附件~tEvent=ue_fj_edit"
	
if len(trim(menustr))<>0 then
	dmPopupMenu = Create m_Dfc_Control_PopupMenu
	dmPopupMenu.mf_BuildMenu(This, menustr)
	dmPopupMenu.mf_PopMenu()
	Destroy dmPopupMenu
end if
end event

type cb_auditing from w_publ_1ton_share_detail`cb_auditing within w_gz_loanwage
end type

event cb_auditing::clicked;call super::clicked;IF Not f_power_ind(205) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

s_taskwork_abnormity_audit s_audit
OpenWithParm(w_gz_loanwage_audit,1)
s_audit = Message.PowerObjectParm

IF s_audit.audit_month = 0 THEN RETURN

String arg_msg
IF uo_loanwage_dq.auditing(s_audit.audit_wageid,s_audit.audit_month,arg_msg,True) = 0 THEN
	MessageBox('提示','借支单审核失败,原因>>'+arg_msg, Information!, OK! )
	RETURN
END IF
MessageBox('提示','借支单审核成功', Information!, OK! )


Parent.TriggerEvent('retrieve_pageretr')


end event

type cb_xm from w_publ_1ton_share_detail`cb_xm within w_gz_loanwage
boolean visible = false
end type

type cb_retrieve from w_publ_1ton_share_detail`cb_retrieve within w_gz_loanwage
end type

type cb_xls from w_publ_1ton_share_detail`cb_xls within w_gz_loanwage
integer x = 1815
end type

type cb_help from w_publ_1ton_share_detail`cb_help within w_gz_loanwage
integer x = 2117
end type

type cb_auditing_cancel from w_publ_1ton_share_detail`cb_auditing_cancel within w_gz_loanwage
end type

event cb_auditing_cancel::clicked;call super::clicked;IF NOT f_power_ind(902) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

s_taskwork_abnormity_audit s_audit
OpenWithParm(w_gz_loanwage_audit,0)
s_audit = Message.PowerObjectParm

IF s_audit.audit_month = 0 THEN RETURN

String arg_msg
IF uo_loanwage_dq.c_auditing(s_audit.audit_wageid,s_audit.audit_month,arg_msg,TRUE) = 0 THEN
	MessageBox('提示','借支单撤审失败,原因>>'+arg_msg, Information!, OK! )
	RETURN
END IF


//日志
String ls_month
ls_month = String(s_audit.audit_month)
f_setsysoplog('借支品单','撤审,月份:'+ls_month,arg_msg,TRUE)
//--

MessageBox('提示','借支单撤审成功', Information!, OK! )

PARENT.TriggerEvent('retrieve_pageretr')
end event

type p_msg from w_publ_1ton_share_detail`p_msg within w_gz_loanwage
end type

type p_help from w_publ_1ton_share_detail`p_help within w_gz_loanwage
end type

type p_encl from w_publ_1ton_share_detail`p_encl within w_gz_loanwage
end type

type p_other from w_publ_1ton_share_detail`p_other within w_gz_loanwage
end type

type gb_3 from w_publ_1ton_share_detail`gb_3 within w_gz_loanwage
end type

type ln_bar from w_publ_1ton_share_detail`ln_bar within w_gz_loanwage
end type

type ln_bar2 from w_publ_1ton_share_detail`ln_bar2 within w_gz_loanwage
end type

type r_bar from w_publ_1ton_share_detail`r_bar within w_gz_loanwage
end type

type ln_1 from w_publ_1ton_share_detail`ln_1 within w_gz_loanwage
end type

type ln_2 from w_publ_1ton_share_detail`ln_2 within w_gz_loanwage
end type

type ddlb_status from dropdownlistbox within w_gz_loanwage
integer x = 955
integer y = 188
integer width = 421
integer height = 300
integer taborder = 10
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
string text = "[全部]"
boolean sorted = false
string item[] = {"[全部]","待审核","已审核"}
borderstyle borderstyle = stylelowered!
end type

event selectionchanged;if index=1 then 
	cur_flag=-1
elseif index=2 then 
	cur_flag=0
elseif index=3 then 
	cur_flag=1
end if
parent.triggerevent('retrieve_pageretr')
end event

type st_2 from statictext within w_gz_loanwage
integer x = 763
integer y = 204
integer width = 219
integer height = 48
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "状  态"
boolean focusrectangle = false
end type