Q5/ws_objects/Ew_define.pbl.src/w_cust_member.srw

$PBExportHeader$w_cust_member.srw
forward
global type w_cust_member from w_publ_edit_choice
end type
end forward

global type w_cust_member from w_publ_edit_choice
integer width = 3273
integer height = 1660
string title = "会员类型"
boolean minbox = true
windowtype windowtype = popup!
end type
global w_cust_member w_cust_member

type variables
s_cust_member INS_RT_STRU
end variables

on w_cust_member.create
call super::create
end on

on w_cust_member.destroy
call super::destroy
end on

event close;call super::close;CLOSEWITHRETURN(THIS,INS_RT_STRU)
end event

type cb_func from w_publ_edit_choice`cb_func within w_cust_member
end type

type cb_exit from w_publ_edit_choice`cb_exit within w_cust_member
integer x = 987
end type

type cb_add from w_publ_edit_choice`cb_add within w_cust_member
end type

event cb_add::clicked;call super::clicked;IF NOT f_power_ind(955) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

Long i,ll_memberid
String errmsg

IF dw_edit_mode THEN
	dw_uc.AcceptText()
	IF dw_uc.GetNextModified(0, Primary!) = 0 THEN
		MessageBox('提示','没有任何修改，不可以保存!', Information!, OK! )
		RETURN
	END IF
	
	dw_uc.Object.membername[dw_uc.GetRow()] = Trim(dw_uc.Object.membername[dw_uc.GetRow()])
	dw_uc.Object.dscrp[dw_uc.GetRow()] = Trim(dw_uc.Object.dscrp[dw_uc.GetRow()])
	
	IF dw_uc.Object.membername[dw_uc.GetRow()] = '' THEN
		MessageBox('提示','请输入名称!', Information!, OK! )
		RETURN
	END IF
	
	IF dw_uc.Object.memberid[dw_uc.GetRow()] = 0 THEN
		ll_memberid = f_sys_scidentity(0,"u_cust_member","memberid",errmsg,FALSE,sqlca)
		IF ll_memberid <= 0 THEN
			MessageBox("提示",errmsg, Information!, OK! )
			RETURN
		ELSE
			dw_uc.Object.memberid[dw_uc.GetRow()] = ll_memberid
		END IF
		dw_uc.Object.opdate[dw_uc.GetRow()] = Today()
		dw_uc.Object.opemp[dw_uc.GetRow()] = publ_operator
	ELSE
		dw_uc.Object.moddate[dw_uc.GetRow()] = Today()
		dw_uc.Object.modemp[dw_uc.GetRow()] = publ_operator
	END IF
	
	String ls_errmsg
	IF dw_uc.UPDATE() = -1 THEN
		IF Pos(ins_sqlerrtext,"Cannot insert duplicate key row") > 0 THEN
			ls_errmsg = "关键内容重复"
		ELSE
			ls_errmsg = "因为网络或其他原因>"+ins_sqlerrtext
		END IF
		ROLLBACK;
		MessageBox ("提示",ls_errmsg+",保存操作失败!",Exclamation!,OK!)
		LS_UPDATE_FLAG = FALSE
		RETURN
	ELSE
		COMMIT;
		LS_UPDATE_FLAG = TRUE
		
		FOR i = 1 TO 6
			dw_uc.SetTabOrder ( i, 0 )
		NEXT
	END IF
	ins_sqlerrtext = ""
ELSE
	Long	li_row, li_cur_row
	li_cur_row = dw_uc.GetRow()
	li_row = dw_uc.InsertRow (0)
	FOR i = 1 TO 6
		dw_uc.SetTabOrder ( i, i*10 )
	NEXT
	dw_uc.SelectRow(0,FALSE)
	dw_uc.ScrollToRow (li_row)
	dw_uc.SelectRow(li_row,TRUE)
	
	dw_uc.SetFocus()
	dw_uc.SetColumn("membername")
	modifyrow_no = li_row
END IF

dw_edit_mode = NOT dw_edit_mode

WF_FACE_CHANGE()
end event

type cb_edit from w_publ_edit_choice`cb_edit within w_cust_member
end type

event cb_edit::clicked;call super::clicked;IF NOT f_power_ind(955) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF
Long i
IF dw_edit_mode THEN
	IF dw_uc.GetItemStatus(dw_uc.GetRow(), 0, Primary!) = NewModified! OR dw_uc.GetItemStatus(dw_uc.GetRow(), 0, Primary!) = New! THEN
		dw_uc.DeleteRow(dw_uc.GetRow())
	ELSE
		dw_uc.ReselectRow(dw_uc.GetRow())
	END IF
	FOR i = 1 TO 6
		dw_uc.SetTabOrder ( i, 0 )
	NEXT
	modifyrow_no = 0
ELSE
	modifyrow_no = dw_uc.GetRow()
	FOR i = 1 TO 6
		dw_uc.SetTabOrder ( i, i*10 )
	NEXT
	dw_uc.SetFocus()
	
	dw_uc.SelectRow(0,FALSE)
	dw_uc.ScrollToRow (modifyrow_no)
	dw_uc.SelectRow(modifyrow_no,TRUE)
	
END IF

dw_edit_mode = NOT dw_edit_mode
WF_FACE_CHANGE()

end event

type cb_delet from w_publ_edit_choice`cb_delet within w_cust_member
end type

event cb_delet::clicked;call super::clicked;IF NOT f_power_ind(955) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF


Long cnt,ll_memberid

IF dw_uc.GetRow() <= 0 THEN
	MessageBox('提示','请选择资料', Information!, OK! )
	RETURN
END IF

ll_memberid = dw_uc.Object.memberid[dw_uc.GetRow()]

IF MessageBox ("询问","是否确定要删除当前记录?(选择确定后记录将不可恢复)",Question!,YesNo! ) = 2 THEN
	RETURN
END IF

SELECT count(*) INTO :cnt
	FROM u_cust
	Where memberid = :ll_memberid;
IF sqlca.SQLCode <> 0 THEN
	MessageBox('提示','查询资料是否已用于客户资料失败,'+sqlca.SQLErrText, Information!, OK! )
	RETURN
END IF

IF cnt > 0 THEN
	MessageBox('提示','资料已用于客户资料,不能删除', Information!, OK! )
	RETURN
END IF

dw_uc.SetRedraw (FALSE)
dw_uc.DeleteRow (0)
dw_uc.TriggerEvent (RowFocusChanged!)

IF dw_uc.UPDATE() = -1 THEN
	ROLLBACK;
	MessageBox ("提示","删除记录操作失败!",Exclamation!,OK!)
ELSE
	COMMIT;
END IF

dw_uc.SetRedraw (TRUE)




end event

type cb_choice from w_publ_edit_choice`cb_choice within w_cust_member
boolean enabled = false
end type

event cb_choice::clicked;call super::clicked;LONG rOW
ROW=dw_uc.getrow()
if ROW<=0 then 
	messagebox('系统提示','请先选择目标行!',StopSign!)
	return
end if

INS_RT_STRU.memberid=dw_uc.OBJECT.memberid[ROW]
INS_RT_STRU.membername=dw_uc.OBJECT.membername[ROW]
INS_RT_STRU.pricelistid=dw_uc.OBJECT.pricelistid[ROW]
INS_RT_STRU.updatescore=dw_uc.OBJECT.updatescore[ROW]
INS_RT_STRU.scoretype=dw_uc.OBJECT.scoretype[ROW]

CLOSE(PARENT)
end event

type dw_uc from w_publ_edit_choice`dw_uc within w_cust_member
event dwnkey pbm_dwnkey
integer y = 180
integer width = 3246
integer height = 1360
string dataobject = "dw_cust_member"
end type

event dw_uc::dwnkey;call super::dwnkey;IF  Key = KeyEnter! THEN //
	keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
	keybd_event ( 9, 0, 2, 0 ) // 释放tab 
	RETURN 1
END IF


end event

event dw_uc::doubleclicked;call super::doubleclicked;if cb_choice.Enabled then
	IF row <= 0 then return 
	cb_choice.triggerevent(clicked!)
end if
end event

type cb_rtr from w_publ_edit_choice`cb_rtr within w_cust_member
end type

type cb_help from w_publ_edit_choice`cb_help within w_cust_member
boolean visible = false
end type

type ln_bar from w_publ_edit_choice`ln_bar within w_cust_member
end type

type ln_bar2 from w_publ_edit_choice`ln_bar2 within w_cust_member
end type

type r_bar from w_publ_edit_choice`r_bar within w_cust_member
end type