Q5/ws_objects/Ew_define.pbl.src/f_insert_0_mtrlware.srf

$PBExportHeader$f_insert_0_mtrlware.srf
global type f_insert_0_mtrlware from function_object
end type

forward prototypes
global function integer f_insert_0_mtrlware (ref long arg_mtrlwareid, long arg_mtrlid, string arg_mtrlcode, long arg_storageid, long arg_sptid, string arg_status, string arg_woodcode, string arg_pcode, string arg_plancode, decimal arg_cost, ref string arg_msg)
end prototypes

global function integer f_insert_0_mtrlware (ref long arg_mtrlwareid, long arg_mtrlid, string arg_mtrlcode, long arg_storageid, long arg_sptid, string arg_status, string arg_woodcode, string arg_pcode, string arg_plancode, decimal arg_cost, ref string arg_msg);Int rslt = 1
Long cnt
Long ls_mtrlwareid,ls_scid
String ls_woodcode_dscrp,ls_status_dscrp,ls_pcode_dscrp,ls_dscrp

IF trim(sys_option_change_status) <> '' THEN
	ls_status_dscrp = sys_option_change_status
	ls_dscrp = ls_status_dscrp+':'+arg_status+' '
END IF

IF trim(sys_option_change_woodcode) <> '' THEN
	ls_woodcode_dscrp = sys_option_change_woodcode
	ls_dscrp = ls_dscrp+ls_woodcode_dscrp+':'+arg_woodcode+' '
END IF

IF trim(sys_option_change_pcode) <> '' THEN
	ls_pcode_dscrp = sys_option_change_pcode
	ls_dscrp = ls_dscrp+ls_pcode_dscrp+':'+arg_pcode
END IF

SELECT scid INTO :ls_scid
	FROM u_storage
	Where storageid = :arg_storageid;	
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询仓库分部失败,请检查'
	rslt = 0
	GOTO ext
END IF

SELECT count(*) INTO :cnt FROM u_mtrlware
	WHERE mtrlid = :arg_mtrlid
	AND storageid = :arg_storageid
	AND sptid = :arg_sptid
	AND dxflag = 0
	AND woodcode = :arg_woodcode
	AND pcode = :arg_pcode
	AND status = :arg_status
	AND plancode = :arg_plancode
	AND scid = :ls_scid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询物料:'+arg_mtrlcode+'是否有库存失败,请检查'
	rslt = 0
	GOTO ext
END IF

IF cnt = 1 THEN	
	SELECT mtrlwareid INTO :ls_mtrlwareid FROM u_mtrlware
		WHERE mtrlid = :arg_mtrlid
		AND storageid = :arg_storageid
		AND sptid = :arg_sptid
		AND dxflag = 0
		AND woodcode = :arg_woodcode
		AND pcode = :arg_pcode
		AND status = :arg_status
		AND plancode = :arg_plancode
		AND scid = :ls_scid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询物料:'+arg_mtrlcode+'是否有库存失败,请检查'
		rslt = 0
		GOTO ext
	END IF
	
	arg_mtrlwareid = ls_mtrlwareid	
	GOTO ext
END IF

IF arg_cost = 0 THEN	
	SELECT planprice INTO :arg_cost
		FROM  u_mtrldef
		Where mtrlid = :arg_mtrlid;
	IF sqlca.SQLCode <> 0 THEN
		arg_msg = '查询计划价失败!!'
		rslt = 0
		GOTO ext
	END IF	
END IF

ls_mtrlwareid = f_sys_scidentity(ls_scid,"u_mtrlware","mtrlwareid",arg_msg,false,sqlca)

INSERT INTO u_mtrlware(scid,mtrlwareid,mtrlid,storageid,noallocqty,woodcode,pcode,plancode,status,sptid,cost)
	Values(:ls_scid,:ls_mtrlwareid,:arg_mtrlid,:arg_storageid,0,:arg_woodcode,:arg_pcode,:arg_plancode,:arg_status,:arg_sptid,:arg_cost);
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '物料:'+arg_mtrlcode+' '+ls_dscrp+' 加0库存失败或物料已经有库存,请检查'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

arg_mtrlwareid = ls_mtrlwareid
ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSE
	COMMIT;
END IF

RETURN rslt

end function