Q5/ws_objects/Ew_buy.pbl.src/w_amerce.srw

$PBExportHeader$w_amerce.srw
forward
global type w_amerce from w_publ_1ton_share_detail
end type
type ddlb_status from dropdownlistbox within w_amerce
end type
type ddlb_scid from uo_ddlb_scid within w_amerce
end type
type st_3 from statictext within w_amerce
end type
type st_2 from statictext within w_amerce
end type
end forward

global type w_amerce from w_publ_1ton_share_detail
integer height = 2036
string title = "供应商罚款单"
event ue_fj_edit ( )
event ue_fj_view ( )
ddlb_status ddlb_status
ddlb_scid ddlb_scid
st_3 st_3
st_2 st_2
end type
global w_amerce w_amerce

type variables
uo_amerce uo_amerce_ms
int cur_flag=-1
long cur_scid  //分店ID

end variables

forward prototypes
public function integer wf_refresh_curuc (long arg_scid, long arg_billid)
public subroutine wf_check_billfj ()
public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg)
end prototypes

event ue_fj_edit();IF dw_edit_mode THEN
	MessageBox('提示','编辑状态下不可用', Information!, OK! )
	RETURN
END IF

//IF NOT f_power_ind(1446) THEN
//	MessageBox(publ_operator,'你没有使用权限！')
//	RETURN
//END IF

s_edit_index_tran s_pic
Long ll_ConnectionID
String arg_msg
Long ls_row
ls_row = dw_pageretr.GetRow() 
IF ls_row <= 0 THEN
	RETURN
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	MessageBox('提示','没有指定附件数据库连接'+arg_msg, Information!, OK! )
	RETURN
END IF

s_pic.f_long = 418 //采购订单的mainID
s_pic.f_string = dw_pageretr.Object.u_spt_amerce_billcode[ls_row]
s_pic.g_long = dw_pageretr.Object.u_spt_amerce_billid[ls_row]
s_pic.e_long = dw_pageretr.Object.u_spt_amerce_scid[ls_row]
s_pic.sqltransaction = sys_filedb_sqlca


OpenWithParm(w_fj_bill_mng,s_pic)
//wf_check_billfj()
end event

event ue_fj_view();IF dw_edit_mode THEN
	MessageBox('提示','编辑状态下不可用', Information!, OK! )
	RETURN
END IF

s_edit_index_tran s_pic
Long ll_ConnectionID
String arg_msg
Long ls_row
ls_row = dw_pageretr.GetRow()
IF ls_row <= 0 THEN
	RETURN
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	MessageBox('提示','没有指定附件数据库连接'+arg_msg, Information!, OK! )
	RETURN
END IF

s_pic.f_long = 418 //采购订单的mainID
s_pic.f_string = dw_pageretr.Object.u_spt_amerce_billcode[ls_row]
s_pic.g_long = dw_pageretr.Object.u_spt_amerce_billid[ls_row]
s_pic.e_long = dw_pageretr.Object.u_spt_amerce_scid[ls_row]
s_pic.sqltransaction = sys_filedb_sqlca


OpenWithParm(w_fj_bill_view,s_pic)



end event

public function integer wf_refresh_curuc (long arg_scid, long arg_billid);IF arg_billid <= 0 OR IsNull(arg_billid) THEN RETURN 0
Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN RETURN 0


DateTime billdate
String sptcode
Decimal amerceamt
String relcode
String amercereason
String billcode
Long sptid
DateTime moddate
String modemp
DateTime auditdate
Int flag
String auditrep
DateTime opdate
String opemp
String Name
Long print_num
string inrep
long  moneyid
Long itemid
String itemcode,itemname
SELECT
u_spt_amerce.billdate,
u_spt.sptcode,
u_spt_amerce.amerceamt,
u_spt_amerce.relcode,
u_spt_amerce.amercereason,
u_spt_amerce.billcode,
u_spt_amerce.sptid,
u_spt_amerce.moddate,
u_spt_amerce.modemp,
u_spt_amerce.auditdate,
u_spt_amerce.flag,
u_spt_amerce.auditrep,
u_spt_amerce.opdate,
u_spt_amerce.opemp,
u_spt.Name,
u_spt_amerce.printnum,
u_spt_amerce.inrep,
u_spt_amerce.moneyid,
u_spt_amerce.itemid,
u_itemdef.itemcode, 
u_itemdef.itemname
INTO
:billdate,
:sptcode,
:amerceamt,
:relcode,
:amercereason,
:billcode,
:sptid,
:moddate,
:modemp,
:auditdate,
:flag,
:auditrep,
:opdate,
:opemp,
:Name,
:print_num,
:inrep,
:moneyid,
:itemid,
:itemcode,
:itemname
FROM u_spt,
u_spt_amerce
LEFT OUTER JOIN u_itemdef ON u_spt_amerce.itemid = u_itemdef.itemid   
Where ( u_spt.sptid = u_spt_amerce.sptid )
AND u_spt_amerce.scid = :arg_scid
AND u_spt_amerce.billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	MessageBox('错误',"查询罚款单操作失败"+sqlca.SQLErrText, StopSign!, OK! )
	RETURN 0
END IF

dw_pageretr.Object.u_spt_amerce_billdate[uc_row] = billdate
dw_pageretr.Object.u_spt_sptcode[uc_row] = sptcode
dw_pageretr.Object.u_spt_amerce_amerceamt[uc_row] = amerceamt
dw_pageretr.Object.u_spt_amerce_relcode[uc_row] = relcode
dw_pageretr.Object.u_spt_amerce_amercereason[uc_row] = amercereason
dw_pageretr.Object.u_spt_amerce_scid[uc_row] = arg_scid
dw_pageretr.Object.u_spt_amerce_billcode[uc_row] = billcode
dw_pageretr.Object.u_spt_amerce_sptid[uc_row] = sptid
dw_pageretr.Object.u_spt_amerce_moddate[uc_row] = moddate
dw_pageretr.Object.u_spt_amerce_modemp[uc_row] = modemp
dw_pageretr.Object.u_spt_amerce_auditdate[uc_row] = auditdate
dw_pageretr.Object.u_spt_amerce_flag[uc_row] = flag
dw_pageretr.Object.u_spt_amerce_auditrep[uc_row] = auditrep
dw_pageretr.Object.u_spt_amerce_opdate[uc_row] = opdate
dw_pageretr.Object.u_spt_amerce_opemp[uc_row] = opemp
dw_pageretr.Object.u_spt_name[uc_row] = Name
dw_pageretr.Object.u_spt_amerce_printnum[uc_row] = print_num
dw_pageretr.Object.u_spt_amerce_billid[uc_row] = arg_billid
dw_pageretr.Object.u_spt_amerce_scid[uc_row] = arg_scid
dw_pageretr.Object.u_spt_amerce_inrep[uc_row] = inrep
dw_pageretr.Object.u_spt_amerce_moneyid[uc_row] = moneyid
dw_pageretr.Object.u_spt_amerce_itemid[uc_row] = itemid
dw_pageretr.Object.u_itemdef_itemcode[uc_row] = itemcode
dw_pageretr.Object.u_itemdef_itemname[uc_row] = itemname
dw_uc.Reset()
dw_pageretr.RowsCopy(dw_pageretr.GetRow(), dw_pageretr.GetRow(), Primary!, dw_uc, 1, Primary!)

dw_uc.ResetUpdate()
dw_uc.SetRedraw(TRUE)

RETURN 1





end function

public subroutine wf_check_billfj ();String arg_msg
Long ll_ConnectionID
Long cur_billtype
long ll_relid,ll_relid_mx,ll_scid
Long ls_filecount = 0
Int rslt = 1

uo_fj_mng_billtype ls_uo_fjbt
ls_uo_fjbt = CREATE uo_fj_mng_billtype
 
Long row,uc_relid
row = dw_pageretr.GetRow()
IF row > 0 THEN
	ll_relid = dw_pageretr.Object.u_spt_amerce_billid[row]
	ll_scid = dw_pageretr.Object.u_spt_amerce_scid[row]
	ll_relid_mx = 0
ELSE
	rslt = 0
	GOTO ext
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

cur_billtype = 418 //客户投拆单的 mainiD

ls_uo_fjbt.uf_check_billfj( cur_billtype, ll_relid,ll_relid_mx,ll_scid, sys_fileDB_sqlca, arg_msg, ls_filecount)

IF ls_filecount > 0 THEN
	rslt = 1
	GOTO ext
ELSE
	rslt = 0
	GOTO ext
END IF

ext: 
wf_encl(rslt)
DESTROY ls_uo_fjbt
end subroutine

public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg);//==============================================================================
// 函数: w_publ_1ton_share_detail::wf_xls_retrievedata()
//------------------------------------------------------------------------------
// 描述:  此函数需要 重载,复制祖先范例代码,然后修改retrieve参数部分两处即可
//------------------------------------------------------------------------------

Long LS_ROW,ll_id,i,ll_scid
LS_ROW = dw_uc.GetRow()
IF LS_ROW <= 0 THEN
	arg_msg = '没有目标单据!'
	RETURN 0
END IF

//修改点:获取 指定retriev参数
ll_id = dw_uc.Object.#1[LS_ROW]
ll_scid = dw_uc.Object.u_spt_amerce_scid[LS_ROW]

//查询所选模版是否含有图片信息
Long ll_ifpic
Long ll_classid
SELECT ifpic
	INTO :ll_ifpic
	FROM U_XLS_Templates
	Where id = :ll_xls_Templatesid;
IF sqlca.SQLCode <> 0 THEN
	ll_ifpic = 0
END IF

Long ll_i,ll_j
Long ll_mtrlid
Long ll_fileid

Blob ls_filedata
SetNull(ls_filedata)
String Pathname,ls_filename,ls_filetype
String errmsg
uo_fj_mng_billtype  ls_uo_fjbt
ls_uo_fjbt = CREATE uo_fj_mng_billtype

s_xls_pic_list s_pic //结构数组-用于保存图片路径

IF ll_ifpic = 1 THEN //如果含有图片信息,则查询本类型单据需要带出哪类附件

	SELECT classid
		INTO :ll_classid
		FROM u_billpic_fileclass
		Where (billtype = 418);
	IF sqlca.SQLCode <> 0 THEN
		ll_classid = 0
	END IF
	
	IF ll_classid > 0 THEN //如果已经指定好附件类型,则循环明细表查询每个明细的图片信息.
		FOR ll_i = 1 TO dw_child.RowCount()
			ll_mtrlid = dw_child.Object.mtrlid[ll_i]
			//取该附件类型中的第一个附件.
			SELECT top 1 fileid,DisplayName,FileType INTO :ll_fileid,:ls_filename,:ls_filetype
				FROM u_file
				WHERE relid = :ll_mtrlid
				AND classid = :ll_classid
				AND (filetype = 'bmp' OR filetype = 'rle' OR filetype = 'wmf'
				OR filetype = 'tif' OR filetype = 'jpg' OR filetype = 'gif' OR filetype = 'jpeg')
				USING sys_fileDB_sqlca;
			IF sys_fileDB_sqlca.SQLCode <> 0 THEN
				ll_fileid = 0
			END IF
			IF ll_fileid > 0 THEN
				Pathname = sys_cur_path+ins_fjtemppath+'\'+String(Today(),'yymmdd')+String(Now(),'hhmmss')+'_'+ls_filename+'.'+ls_filetype
				IF Trim(Pathname) <> '' THEN
					IF ls_uo_fjbt.uf_getfjbolb_fromdb( ll_fileid, ls_filedata, sys_fileDB_sqlca, arg_msg) = 0 THEN
						RETURN  0
					END IF
					
					IF f_saveblobtofile(ls_filedata,Pathname,errmsg) = 0 THEN
						RETURN 0
					ELSE
						
						s_pic.path[ll_i] = Pathname
						//记录临时文件位置,本窗口退出后删除
						wf_addlog_tempfilepathname(Pathname)
						
					END IF
				ELSE
					s_pic.path[ll_i] = ''
				END IF
			ELSE
				s_pic.path[ll_i] = ''
			END IF
		NEXT
	END IF
	//
END IF

////可选设置///
arg_obj_st.uo_const.create_new_pwd( )  //创建随机密码 
if sys_option_xls_ifuse_passwd = 1 then arg_obj_st.uo_const.pwd = trim(sys_option_xls_user_passwd)   //默认加密密码    默认为随即密码


boolean xls_locked
xls_locked = not (sys_option_xls_lock = 1)

/// Excel 的可选设置
if arg_obj_st.of_setoption(arg_ationid,  xls_locked,true,arg_msg) <> 1 then
		return 0
end if


for i = 1 to arg_str_billlist.count
	////可选操作///
	arg_str_billlist.bill[i].ds_data = create datastore                                  //
	arg_str_billlist.bill[i].ds_data.dataobject = arg_str_billlist.bill[i].datawindow       //
	arg_str_billlist.bill[i].ds_data.settransobject(sqlca)
	
	//修改点:注意retrieve 参数与上文对应
	arg_str_billlist.bill[i].ds_data.retrieve(ll_scid,ll_id)

next 

return 1
end function

on w_amerce.create
int iCurrent
call super::create
this.ddlb_status=create ddlb_status
this.ddlb_scid=create ddlb_scid
this.st_3=create st_3
this.st_2=create st_2
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.ddlb_status
this.Control[iCurrent+2]=this.ddlb_scid
this.Control[iCurrent+3]=this.st_3
this.Control[iCurrent+4]=this.st_2
end on

on w_amerce.destroy
call super::destroy
destroy(this.ddlb_status)
destroy(this.ddlb_scid)
destroy(this.st_3)
destroy(this.st_2)
end on

event ue_usual_query_retr;call super::ue_usual_query_retr;String ls_querystrpart = ''
ls_newselect = Lower(ori_oldselect)
IF Trim(sle_usual_query.Text) <> '' THEN
	IF Pos(Trim(sle_usual_query.Text),'%') = 0 THEN
		ls_querystrpart = "(u_spt_amerce.billcode like '%"+Trim(sle_usual_query.Text)+"%')"
	ELSE
		ls_querystrpart = "(u_spt_amerce.billcode like '"+Trim(sle_usual_query.Text)+"')"
	END IF
	
	IF Pos(ls_newselect," where ") <> 0 THEN
		ls_newselect = ls_newselect+" and ("+ls_querystrpart+')'
	ELSE
		ls_newselect = ls_newselect+" where ("+ls_querystrpart+')'
	END IF
END IF
wf_retrieveuc(dw_pageretr,ls_newselect,1)
THIS.TriggerEvent('retrieve_pageretr')


end event

event ue_usual_query_filt;call super::ue_usual_query_filt;string obj_expr=''  
if trim(sle_usual_query.text)<>'' then 
	if pos(trim(sle_usual_query.text),'%')=0 then
		obj_expr=obj_expr+'( u_spt_amerce_billcode like "%'+trim(sle_usual_query.text)+'%" )'
	else
		obj_expr=obj_expr+'( u_spt_amerce_billcode like "'+trim(sle_usual_query.text)+'" )'
	end if 
end if

dw_pageretr.setfilter(obj_expr)

dw_pageretr.setredraw(false)
dw_pageretr.filter()
if dw_pageretr.rowcount()>=1 then
	dw_pageretr.selectrow(0,false)
	dw_pageretr.selectrow(1,true)
end if
dw_pageretr.setredraw(true)
end event

event close;call super::close;destroy uo_amerce_ms
end event

event open;call super::open;uc_column_int=10    //uc dw前6列可以编辑
uo_amerce_ms =create uo_amerce
end event

event refresh_interface;call super::refresh_interface;ddlb_status.enabled=not dw_edit_mode
ddlb_scid.enabled=not dw_edit_mode
end event

event retrieve_pageretr;Boolean cb_firstpage_enabled,cb_nextpage_enabled,cb_retrieveall_enabled
Boolean cb_priorpage_enabled,cb_func_enabled,cb_retrieve_enabled

cb_nextpage_enabled = cb_nextpage.Enabled
cb_retrieveall_enabled = cb_retrieveall.Enabled
cb_func_enabled = cb_func.Enabled

cb_nextpage.Enabled = FALSE
cb_retrieveall.Enabled = FALSE
cb_func.Enabled = FALSE

dw_uc.Retrieve() //dw_uc的dw改左select top 0 并肯不带参数
dw_pageretr.Retrieve(cur_scid,cur_flag,sys_user_spttype)
IF dw_pageretr.RowCount() > 0 THEN
	dw_pageretr.SetRow(1)
	dw_pageretr.TriggerEvent(RowFocusChanged!)
END IF

THIS.TriggerEvent('retrieve_childdw')

cb_nextpage.Enabled = cb_nextpage_enabled
cb_retrieveall.Enabled = cb_retrieveall_enabled
cb_func.Enabled = cb_func_enabled



end event

event ue_f9;call super::ue_f9;//用于选择明细内容,被F9[默认]
IF NOT dw_edit_mode THEN RETURN

Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row = 0 THEN
	MessageBox('提示','请选定进仓单!', Information!, OK! )
	RETURN
END IF
dw_uc.AcceptText()

THIS.Enabled = FALSE

IF NOT IsValid(W_spt_edit) THEN
	s_edit_index_tran s_ch_tran //传递参数使用
	s_ch_tran.if_retrieve_all = FALSE //是否一次RETRIEVE所有行
	s_ch_tran.work_mode = 1 //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid = 0 //目标定位PKID (备用)
	//查询列(物料编码)部分内容,用于初步筛选
	s_ch_tran.arg_string_code = Upper(Trim(dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()]))
	
	OpenWithParm(W_spt_edit,s_ch_tran) //调用
	
	S_spt S_INSCUST
	S_INSCUST = Message.PowerObjectParm //接受返回结构
	
	IF S_INSCUST.sptid > 0 THEN //正常返回值则可以取以下值
		dw_uc.SetRedraw(FALSE)
		dw_uc.Object.u_spt_amerce_sptid[uc_row] = S_INSCUST.sptid
		dw_uc.Object.u_spt_name[uc_row] = S_INSCUST.Name
		dw_uc.Object.u_spt_sptcode[uc_row] = S_INSCUST.sptcode
		dw_uc.Object.u_spt_amerce_banktypeid[uc_row] = S_INSCUST.dftbanktypeid
		dw_uc.Object.u_spt_amerce_moneyid[uc_row] = S_INSCUST.dftmoneyid
		dw_uc.SetRedraw(TRUE)
		dw_uc.SetColumn("u_spt_amerce_inrep")
	END IF
END IF

THIS.Enabled = TRUE

end event

event ue_viewprint;call super::ue_viewprint;IF Not (f_power_ind(383) OR f_power_ind(423)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

Long LS_ROW
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('提示','没有打印目标单据!', Information!, OK! )
	RETURN
END IF

S_print_MSG LS_PRMSG

IF ls_newname <> '' THEN
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.u_spt_amerce_flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('提示','目标单据还未审核,不能打印!', Information!, OK! )
			RETURN
		END IF
	END IF
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	LS_PRMSG.obj_dwNAME = 'dw_rp_spt_amerce_edit'
END IF

LS_PRMSG.TAG_TEXT = '罚款单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.retr_pram_falg = 12
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_scid = dw_pageretr.Object.u_spt_amerce_scid[LS_ROW]
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_spt_amerce_billid[LS_ROW]
OpenWithParm(w_publ_preview,LS_PRMSG)

//**更新打印次料
String arg_msg
printnum = Message.DoubleParm
f_update_printnum('u_spt_amerce',printnum,dw_pageretr.Object.u_spt_amerce_scid[LS_ROW],dw_pageretr.Object.u_spt_amerce_billid[LS_ROW],'','',arg_msg,TRUE)

end event

event ue_print;call super::ue_print;IF Not (f_power_ind(383) OR f_power_ind(423)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

//--直接打印
uo_print_preview uo_print
S_print_MSG LS_PRMSG
IF dw_pageretr.RowCount() = 0 THEN
	MessageBox('提示','没有可打印的单据！', Information!, OK! )
	RETURN
END IF

IF MessageBox ('询问',"是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN

IF ls_newname <> '' THEN
	
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.u_spt_amerce_flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('提示','目标单据还未审核,不能打印!', Information!, OK! )
			RETURN
		END IF
	END IF
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	LS_PRMSG.obj_dwNAME = 'dw_rp_spt_amerce_edit'
END IF

LS_PRMSG.retr_pram_falg = 12
LS_PRMSG.TAG_TEXT = '罚款单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_scid = dw_pageretr.Object.u_spt_amerce_scid[dw_pageretr.GetRow()]
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_spt_amerce_billid[dw_pageretr.GetRow()]
uo_print.FACT_PRINT_MSG = LS_PRMSG

String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("错误",arg_msg, StopSign!, OK! ) 
	RETURN
END IF
uo_print.ds_print()

//**更新打印次料
f_update_printnum('u_spt_amerce',1,dw_pageretr.Object.u_spt_amerce_scid[dw_pageretr.GetRow()],dw_pageretr.Object.u_spt_amerce_billid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)

end event

event ue_addzy;call super::ue_addzy;IF dw_edit_mode THEN
	MessageBox('提示',"编辑状态下不可以使用!", Information!, OK! )
	RETURN
END IF

IF Not (f_power_ind(780) OR f_power_ind(783)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

String arg_msg = ''
String ls_str
Long uc_row
s_inputbox s_sreu

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!', Information!, OK! )
	RETURN
END IF
s_sreu.Title = '请输入要补充到备注的内容'
s_sreu.old_text = ''
OpenWithParm(w_inputbox,s_sreu)
ls_str = Message.StringParm
IF Trim(ls_str) = '' OR IsNull(ls_str) THEN RETURN

IF uo_amerce_ms.add_dscrp(dw_pageretr.Object.u_spt_amerce_scid[uc_row],dw_pageretr.Object.u_spt_amerce_billid[uc_row],ls_str,arg_msg) = 0 THEN
	MessageBox('error!',arg_msg)
	RETURN
ELSE
	MessageBox('提示','添加备注操作成功!', Information!, OK! )
	wf_refresh_curuc(dw_pageretr.Object.u_spt_amerce_scid[uc_row],dw_pageretr.Object.u_spt_amerce_billid[uc_row])
END IF



end event

event resize;ln_bar.endx = this.width
ln_bar2.endx = this.width
r_bar.width = this.width
end event

event ue_rpt_print;call super::ue_rpt_print;IF Not (f_power_ind(383) OR f_power_ind(423)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

Long row,uc_relid,ll_scid
row = dw_pageretr.GetRow()
IF row = 0 THEN
	RETURN
END IF
uo_rpt_print_preview uo_print
S_rpt_print_MSG LS_PRMSG

IF dw_pageretr.RowCount() = 0 THEN
	MessageBox('提示','没有可打印的单据！', Information!, OK! )
	RETURN
END IF

IF ls_rpname = '' THEN RETURN

IF li_auditprint = 1 THEN
	IF dw_pageretr.Object.u_spt_amerce_flag[row] = 0 THEN
		MessageBox('提示','目标单据还未审核,不能打印!', Information!, OK! )
		RETURN
	END IF
END IF

IF MessageBox ("询问","是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN


LS_PRMSG.retr_pram_falg = 12
LS_PRMSG.TAG_TEXT = '赔偿单'
LS_PRMSG.rpname = ls_rpname
LS_PRMSG.FILTER_STRING = ''

LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.rpid = ls_msgprintid_rpt
LS_PRMSG.retr_scid = dw_pageretr.Object.u_spt_amerce_scid[row]
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_spt_amerce_billid[row]

uo_print.FACT_PRINT_MSG = LS_PRMSG

String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("错误",arg_msg, StopSign!, OK! ) 
	RETURN
END IF
uo_print.ds_print()


//**更新打印次料
f_update_printnum('u_spt_amerce',1,dw_pageretr.Object.u_spt_amerce_scid[dw_pageretr.GetRow()],dw_pageretr.Object.u_spt_amerce_billid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)




end event

event ue_rpt_viewprint;call super::ue_rpt_viewprint;IF Not (f_power_ind(383) OR f_power_ind(423)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! ) 
	RETURN
END IF

Long row,uc_relid,ll_scid
row = dw_pageretr.GetRow()
IF row = 0 THEN
	RETURN
END IF

IF ls_rpname = '' THEN RETURN

IF li_auditprint = 1 THEN
	IF dw_pageretr.Object.u_spt_amerce_flag[row] = 0 THEN
		MessageBox('提示','目标单据还未审核,不能打印!', Information!, OK! ) 
		RETURN
	END IF
END IF

s_rpt_print_msg s_print
s_print.retr_pram_falg = 12
s_print.rpid = ls_msgprintid_rpt
s_print.retr_flag = TRUE
s_print.tag_text = THIS.Title

s_print.rpname  = ls_rpname
s_print.retr_scid = dw_pageretr.Object.u_spt_amerce_scid[row]
s_print.retr_pramnmb = dw_pageretr.Object.u_spt_amerce_billid[row]
OpenWithParm(w_rpt_preview,s_print)


//**更新打印次料
string arg_msg
f_update_printnum('u_spt_amerce',1,dw_pageretr.Object.u_spt_amerce_scid[dw_pageretr.GetRow()],dw_pageretr.Object.u_spt_amerce_billid[dw_pageretr.GetRow()],'','',arg_msg,TRUE)




end event

event ue_f7;//用于选择明细内容,被F9[默认]
IF NOT dw_edit_mode THEN RETURN

Long uc_row
String ls_itemcode
uc_row = dw_uc.GetRow()
ls_itemcode = Trim(dw_uc.Object.u_itemdef_itemcode[uc_row])

IF uc_row = 0 THEN
	MessageBox('提示','请选定单据!',information!,ok!)
	RETURN
END IF

dw_uc.AcceptText()
IF NOT IsValid(w_itemdef_response) THEN
	s_edit_index_tran s_ch_tran //传递参数使用
	s_ch_tran.if_retrieve_all = local_retrieve_all  //是否一次retrieve所有行
	s_ch_tran.work_mode = 1                         //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid = 0                          //目标定位pkid (备用)	
	s_ch_tran.arg_string_code = ls_itemcode         //查询列(物料编码)部分内容,用于初步筛选
	
	OpenWithParm(w_itemdef_response,s_ch_tran) //调用
	
	s_itemdef s_inscust
	s_inscust = Message.PowerObjectParm //接受返回结构
	
	IF s_inscust.itemid > 0 THEN //正常返回值则可以取以下值
		dw_uc.SetRedraw(FALSE)
		dw_uc.Object.u_spt_amerce_itemid[uc_row] = s_inscust.itemid
		dw_uc.Object.u_itemdef_itemcode[uc_row] = s_inscust.itemcode
		dw_uc.Object.u_itemdef_itemname[uc_row] = s_inscust.itemname
		
		dw_uc.SetColumn("u_spt_amerce_amercereason")
		dw_uc.SetRedraw(TRUE)
	END IF
END IF

end event

type cb_func from w_publ_1ton_share_detail`cb_func within w_amerce
end type

type cb_exit from w_publ_1ton_share_detail`cb_exit within w_amerce
integer x = 2267
end type

type sle_usual_query from w_publ_1ton_share_detail`sle_usual_query within w_amerce
integer x = 192
integer y = 188
integer width = 549
end type

type cb_retrieveall from w_publ_1ton_share_detail`cb_retrieveall within w_amerce
integer x = 2729
end type

type em_pagerowno from w_publ_1ton_share_detail`em_pagerowno within w_amerce
integer x = 2418
integer y = 36
integer width = 320
end type

type dw_pageretr from w_publ_1ton_share_detail`dw_pageretr within w_amerce
event dwnkey pbm_dwnkey
integer x = 1993
integer width = 1559
integer height = 1644
string dataobject = "dw_amerce_index"
end type

event dw_pageretr::dwnkey;call super::dwnkey;Int h = 0

end event

event dw_pageretr::constructor;call super::constructor; titleclick_sort_use=true  //单击标题排序功能开关
 RBUTTON_FILTER_USE=true  //右键查询功能开关

end event

event dw_pageretr::rowfocuschanged;call super::rowfocuschanged;wf_check_billfj()
end event

type st_1 from w_publ_1ton_share_detail`st_1 within w_amerce
integer y = 208
string text = "编码含"
end type

type cb_nextpage from w_publ_1ton_share_detail`cb_nextpage within w_amerce
integer x = 2880
end type

type dw_uc from w_publ_1ton_share_detail`dw_uc within w_amerce
integer width = 1984
integer height = 1644
string dataobject = "dw_amerce_edit"
end type

event dw_uc::dwnkey;parent.triggerevent('user_key')

if key = KeyDownArrow! then return 1

if dw_edit_mode then
	if dw_uc.GetColumnName ( )='u_spt_sptcode' and key = KeyEnter! then 
		String ls_code,ls_name,ls_find_code
		Long ls_sptid
		Long cnt = 0
		Boolean if_find = FALSE
		
		dw_uc.AcceptText()
		ls_code = Upper(Trim(dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()]))
		SELECT   u_spt.sptid,
			u_spt.name,
			u_spt.sptcode
			INTO	:ls_sptid,:ls_name,:ls_code
			FROM u_spt
			Where ( sptcode = :ls_code OR Name = :ls_code );
		IF sqlca.SQLCode <> 0 THEN
			IF Pos(Trim(ls_code),'%') = 0 THEN
				ls_find_code = '%'+ Trim(ls_code) + '%'
			ELSE
				ls_find_code = Trim(ls_code)
			END IF
			
			SELECT count(*) INTO :cnt
				FROM u_spt
				Where ( sptcode Like :ls_find_code OR Name Like :ls_find_code );
			IF sqlca.SQLCode <> 0 THEN
				PARENT.TriggerEvent('ue_f9')
				RETURN 1
			END IF
			IF cnt <> 1 THEN
				PARENT.TriggerEvent('ue_f9')
				RETURN 1
			ELSE
				SELECT u_spt.sptid,
					u_spt.sptcode,
					u_spt.name
					INTO	:ls_sptid,:ls_code,:ls_name
					FROM u_spt
					Where ( sptcode Like :ls_find_code OR Name Like :ls_find_code );
				IF sqlca.SQLCode <> 0 THEN
					
					PARENT.TriggerEvent('ue_f9')
					RETURN 1
				ELSE
					if_find = TRUE
				END IF
			END IF
		ELSE
			if_find = TRUE
		END IF
		
		IF if_find THEN
			dw_uc.SetRedraw(FALSE)
			dw_uc.Object.u_spt_amerce_sptid[dw_uc.GetRow()] = ls_sptid
			dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()] = ls_code
			dw_uc.Object.u_spt_name[dw_uc.GetRow()] = ls_name
			dw_uc.SetRedraw(TRUE)
			dw_uc.SetColumn("u_spt_amerce_inrep")
			RETURN 1
		END IF
		
 		 
	else
		if  key = KeyEnter! Then //
			keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
			keybd_event ( 9, 0, 2, 0 ) // 释放tab 
			Return 1
		end If
	end if
end if

end event

event dw_uc::clicked;call super::clicked;if not dw_edit_mode then return
if row <= 0 then return

if dwo.name='p_p' then
	parent.TRIGGEREVENT('ue_f9')
end if
end event

event dw_uc::doubleclicked;IF dw_edit_mode And row > 0  THEN
	IF dwo.Name = 'u_itemdef_itemcode' or dwo.Name = 'u_itemdef_itemname' THEN
		PARENT.TriggerEvent('ue_f7')
	ELSE
		Parent.TriggerEvent('ue_f9')
	END IF
END IF

end event

type gb_2 from w_publ_1ton_share_detail`gb_2 within w_amerce
end type

type dw_child from w_publ_1ton_share_detail`dw_child within w_amerce
integer x = 1029
integer y = 2408
integer height = 604
end type

type cb_viewprint from w_publ_1ton_share_detail`cb_viewprint within w_amerce
integer x = 1623
end type

type cb_print from w_publ_1ton_share_detail`cb_print within w_amerce
integer x = 1431
end type

type cb_add from w_publ_1ton_share_detail`cb_add within w_amerce
end type

event cb_add::clicked;IF Not (f_power_ind(116) OR f_power_ind(421)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! ) 
	RETURN
END IF


String arg_msg = ''
Long uc_row

IF dw_edit_mode THEN
	dw_uc.AcceptText()
	uc_row = dw_uc.GetRow()
	IF uc_row <= 0 THEN
		MessageBox('提示','请选定当前目标单据!', Information!, OK! ) 
		RETURN
	END IF
	
	IF NOT dw_uc.Object.u_spt_amerce_billdate[uc_row] > DateTime(2000-01-01,Now()) THEN
		MessageBox('提示','不合理日期', Information!, OK! ) 
		dw_uc.SetFocus()
		dw_uc.SetColumn('u_spt_amerce_billdate')
		RETURN
	END IF
	
	IF Trim(dw_uc.Object.u_spt_amerce_inrep[uc_row]) = '' THEN
		MessageBox('提示','请输入经手人', Information!, OK! ) 
		dw_uc.SetFocus()
		dw_uc.SetColumn('u_spt_amerce_inrep')
		RETURN
	END IF
	
	IF dw_uc.Object.u_spt_amerce_banktypeid[uc_row] = 0 THEN
		MessageBox('提示','请选择结算方式', Information!, OK! ) 
		dw_uc.SetFocus()
		dw_uc.SetColumn('u_spt_amerce_banktypeid')
		RETURN
	END IF
	
	IF dw_uc.Object.u_spt_amerce_moneyid[uc_row] = 0 THEN
		MessageBox('提示','请选择币种', Information!, OK! ) 
		dw_uc.SetFocus()
		dw_uc.SetColumn('u_spt_amerce_moneyid')
		RETURN
	END IF
	
	
	uo_amerce_ms.sptid = dw_uc.Object.u_spt_amerce_sptid[uc_row]
	uo_amerce_ms.billdate = dw_uc.Object.u_spt_amerce_billdate[uc_row]
	uo_amerce_ms.amerceamt = dw_uc.Object.u_spt_amerce_amerceamt[uc_row]
	uo_amerce_ms.amercereason  = dw_uc.Object.u_spt_amerce_amercereason[uc_row]
	uo_amerce_ms.relcode  = dw_uc.Object.u_spt_amerce_relcode[uc_row]
	uo_amerce_ms.inrep  = dw_uc.Object.u_spt_amerce_inrep[uc_row]
	uo_amerce_ms.banktypeid  = dw_uc.Object.u_spt_amerce_banktypeid[uc_row]
	uo_amerce_ms.moneyid  = dw_uc.Object.u_spt_amerce_moneyid[uc_row]
	uo_amerce_ms.itemid  = dw_uc.Object.u_spt_amerce_itemid[uc_row]
	IF uo_amerce_ms.Save(arg_msg,TRUE) = 0 THEN
		MessageBox('错误',arg_msg, StopSign!, OK! )
		RETURN
	END IF
	//	messagebox(publ_operator,'保存操作成功!')
	
	long ll_row
	ll_row = dw_pageretr.getrow()
	dw_pageretr.SelectRow(0,FALSE)
	dw_pageretr.SelectRow(ll_row,TRUE)
	wf_refresh_curuc(cur_scid,uo_amerce_ms.billid)
ELSE
	IF uo_amerce_ms.newbegin(cur_scid,arg_msg) = 0 THEN
		MessageBox('错误',arg_msg, StopSign!, OK! )
		RETURN
	END IF
END IF

CALL SUPER::Clicked


IF dw_edit_mode THEN
	Long li_itemid
	String ls_itemcode,ls_itemname
	SELECT itemid,itemcode,itemname
	into :li_itemid,:ls_itemcode,:ls_itemname
	FROM u_itemdef where dfttype = 9;
	IF SQLCA.SQLCODE = 0 THEN
		dw_uc.Object.u_spt_amerce_itemid[dw_uc.GetRow()] = li_itemid
		dw_uc.Object.u_itemdef_itemcode[dw_uc.GetRow()] = ls_itemcode
		dw_uc.Object.u_itemdef_itemname[dw_uc.GetRow()] = ls_itemname
	END IF
ELSE
	PARENT.TriggerEvent("retrieve_childdw")
END IF








end event

type cb_edit from w_publ_1ton_share_detail`cb_edit within w_amerce
end type

event cb_edit::clicked;IF Not (f_power_ind(116) OR f_power_ind(421)) THEN
	MessageBox(publ_operator,'你没有使用权限！')
	RETURN
END IF


String arg_msg = ''
Long uc_row

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('系统提示','请选定当前目标单据!')
	RETURN
END IF

IF NOT dw_edit_mode THEN
	IF uo_amerce_ms.updatebegin(dw_pageretr.Object.u_spt_amerce_scid[uc_row],dw_pageretr.Object.u_spt_amerce_billid[uc_row],arg_msg) = 0 THEN
		MessageBox('Error!',arg_msg)
		RETURN
	END IF
END IF

CALL SUPER::Clicked


end event

type cb_delet from w_publ_1ton_share_detail`cb_delet within w_amerce
end type

event cb_delet::clicked;call super::clicked;if not (f_power_ind(616) or f_power_ind(623)) then
	messagebox('提示','你没有使用权限！', Information!, OK! ) 
	return
end if

if dw_edit_mode then return

string arg_msg=''
long uc_row

uc_row=dw_pageretr.getrow()

if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!', Information!, OK! ) 
	return
end if

IF MessageBox ("询问","是否确定要删除当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN


if uo_amerce_ms.del(dw_pageretr.object.u_spt_amerce_scid[uc_row],dw_pageretr.object.u_spt_amerce_billid[uc_row],arg_msg)=0 then
	messagebox('错误',arg_msg, StopSign!, OK! ) 
ELSE
	//日志
	long ls_id
	string ls_code
	ls_id=dw_pageretr.object.u_spt_amerce_billid[uc_row]
	ls_code=dw_pageretr.object.u_spt_amerce_billcode[uc_row]
	f_setsysoplog('罚款单','删除,id:'+string(ls_id)+',code:'+ls_code,arg_msg,true)
	//--
	
	MESSAGEBOX('提示','删除单据'+string(dw_pageretr.object.u_spt_amerce_billcode[uc_row])+'成功!', Information!, OK! ) 
	dw_pageretr.deleterow(uc_row)
	dw_pageretr.postevent(rowfocuschanged!)
end if

end event

type cb_addzy from w_publ_1ton_share_detail`cb_addzy within w_amerce
end type

event cb_addzy::clicked;call super::clicked;m_Dfc_Control_PopupMenu dmPopupMenu
string menustr


menustr="Text=增加备注~tEvent=ue_addzy"
menustr = menustr + "|" + "Text=-"
menustr = menustr + "|" + "Text=查看附件~tEvent=ue_fj_view"
menustr = menustr + "|" + "Text=添加附件~tEvent=ue_fj_edit"

if len(trim(menustr))<>0 then
	dmPopupMenu = Create m_Dfc_Control_PopupMenu
	dmPopupMenu.mf_BuildMenu(This, menustr)
	dmPopupMenu.mf_PopMenu()
	Destroy dmPopupMenu
end if
end event

type cb_auditing from w_publ_1ton_share_detail`cb_auditing within w_amerce
end type

event cb_auditing::clicked;call super::clicked;IF Not (f_power_ind(883) OR f_power_ind(884)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

IF dw_edit_mode THEN RETURN
String arg_msg = ''

Long pagerert_row

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!', Information!, OK! )
	RETURN
END IF

IF MessageBox ("询问","是否确定要审核当前单据?",question!,yesno! ) = 2 THEN RETURN


IF uo_amerce_ms.auditing(dw_pageretr.Object.u_spt_amerce_scid[pagerert_row],dw_pageretr.Object.u_spt_amerce_billid[pagerert_row],arg_msg,TRUE) = 0 THEN
	MessageBox('error!',arg_msg)
ELSE
	MessageBox('提示','审核成功!', Information!, OK! )
	wf_refresh_curuc(dw_pageretr.Object.u_spt_amerce_scid[pagerert_row],dw_pageretr.Object.u_spt_amerce_billid[pagerert_row])
END IF



end event

type cb_xm from w_publ_1ton_share_detail`cb_xm within w_amerce
boolean visible = false
end type

event cb_xm::clicked;//
end event

type cb_retrieve from w_publ_1ton_share_detail`cb_retrieve within w_amerce
end type

type cb_xls from w_publ_1ton_share_detail`cb_xls within w_amerce
integer x = 1815
end type

type cb_help from w_publ_1ton_share_detail`cb_help within w_amerce
integer x = 2117
end type

type cb_auditing_cancel from w_publ_1ton_share_detail`cb_auditing_cancel within w_amerce
end type

event cb_auditing_cancel::clicked;call super::clicked;IF Not (f_power_ind(117) OR f_power_ind(422)) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF

IF dw_edit_mode THEN RETURN
String arg_msg = ''

Long pagerert_row

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!', Information!, OK! )
	RETURN
END IF

IF MessageBox ("询问","是否确定要撤消审核当前单据?",question!,yesno! ) = 2 THEN RETURN


IF uo_amerce_ms.c_auditing(dw_pageretr.Object.u_spt_amerce_scid[pagerert_row],dw_pageretr.Object.u_spt_amerce_billid[pagerert_row],arg_msg,TRUE) = 0 THEN
	MessageBox('错误',arg_msg, StopSign!, OK! ) 
ELSE
	
	//日志
	Long ls_id
	String ls_code
	ls_id = dw_pageretr.Object.u_spt_amerce_billid[pagerert_row]
	ls_code = dw_pageretr.Object.u_spt_amerce_billcode[pagerert_row]
	f_setsysoplog('罚款单','撤审,id:'+String(ls_id)+',code:'+ls_code,arg_msg,TRUE)
	//--
	
	MessageBox('提示','撤消审核成功!', Information!, OK! )
	wf_refresh_curuc(dw_pageretr.Object.u_spt_amerce_scid[pagerert_row],dw_pageretr.Object.u_spt_amerce_billid[pagerert_row])
END IF

end event

type p_msg from w_publ_1ton_share_detail`p_msg within w_amerce
end type

type p_help from w_publ_1ton_share_detail`p_help within w_amerce
end type

type p_encl from w_publ_1ton_share_detail`p_encl within w_amerce
end type

type p_other from w_publ_1ton_share_detail`p_other within w_amerce
end type

type gb_3 from w_publ_1ton_share_detail`gb_3 within w_amerce
end type

type ln_bar from w_publ_1ton_share_detail`ln_bar within w_amerce
end type

type ln_bar2 from w_publ_1ton_share_detail`ln_bar2 within w_amerce
end type

type r_bar from w_publ_1ton_share_detail`r_bar within w_amerce
end type

type ln_1 from w_publ_1ton_share_detail`ln_1 within w_amerce
end type

type ln_2 from w_publ_1ton_share_detail`ln_2 within w_amerce
end type

type ddlb_status from dropdownlistbox within w_amerce
integer x = 1687
integer y = 188
integer width = 549
integer height = 300
integer taborder = 10
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
string text = "[全部]"
boolean sorted = false
string item[] = {"[全部]","待审核","已审核"}
borderstyle borderstyle = stylelowered!
end type

event selectionchanged;if index=1 then 
	cur_flag=-1
elseif index=2 then 
	cur_flag=0
elseif index=3 then 
	cur_flag=1
end if
parent.triggerevent('retrieve_pageretr')
end event

type ddlb_scid from uo_ddlb_scid within w_amerce
integer x = 946
integer y = 188
integer width = 549
integer height = 1120
end type

event constructor;call super::constructor;cur_scid=this.uo_scid
end event

event selectionchanged;call super::selectionchanged;cur_scid=this.uo_scid
parent.triggerevent("retrieve_pageretr")
end event

type st_3 from statictext within w_amerce
integer x = 1509
integer y = 208
integer width = 219
integer height = 48
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "状  态"
boolean focusrectangle = false
end type

type st_2 from statictext within w_amerce
integer x = 763
integer y = 208
integer width = 219
integer height = 48
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "分　部"
boolean focusrectangle = false
end type