Q5/ws_objects/Ew_ware.pbl.src/w_mtrlware_trans.srw

$PBExportHeader$w_mtrlware_trans.srw
forward
global type w_mtrlware_trans from w_publ_1ton_share_detail
end type
type ddlb_status from dropdownlistbox within w_mtrlware_trans
end type
type st_2 from statictext within w_mtrlware_trans
end type
type st_3 from statictext within w_mtrlware_trans
end type
type ddlb_scid from uo_ddlb_scid within w_mtrlware_trans
end type
end forward

global type w_mtrlware_trans from w_publ_1ton_share_detail
integer height = 2300
string title = "客存调整单"
boolean maxbox = true
windowstate windowstate = maximized!
long dw_pageretr_w = 35303956
long dw_child_h = 33933388
long dw_child_w = 35654924
event insert_childrow ( )
event ue_resetmx ( )
event ue_fj_edit ( )
event ue_fj_view ( )
ddlb_status ddlb_status
st_2 st_2
st_3 st_3
ddlb_scid ddlb_scid
end type
global w_mtrlware_trans w_mtrlware_trans

type variables
uo_mtrlware_trans uo_ware
long cur_flag= -1 //-1：全部，0未审
long cur_scid  //分店ID
string ol_cdw_str = ''
end variables

forward prototypes
public function integer wf_flagstatus_rf ()
public function integer wf_refresh_curuc (long arg_scid, long arg_billid)
public subroutine wf_check_billfj ()
public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg)
public function integer wf_print_retrievedata (ref s_print_pic_list arg_s_pic, ref string arg_msg)
end prototypes

event insert_childrow();Long li_row
li_row = dw_child.InsertRow(0)
dw_child.ScrollToRow(li_row)


dw_child.Object.u_mtrldef_mtrlcode[li_row] = dw_uc.Object.u_mtrldef_mtrlcode[dw_uc.GetRow()]
dw_child.Object.u_mtrldef_mtrlmode[li_row] = dw_uc.Object.u_mtrldef_mtrlmode[dw_uc.GetRow()]
dw_child.Object.u_mtrlware_transmx_mtrlid[li_row] = dw_uc.Object.u_mtrlware_trans_mtrlid[dw_uc.GetRow()]
dw_child.Object.u_mtrldef_mtrlname[li_row] = dw_uc.Object.u_mtrldef_mtrlname[dw_uc.GetRow()]
dw_child.Object.u_mtrlware_transmx_fprice[li_row] = dw_uc.Object.u_mtrlware_trans_cost[dw_uc.GetRow()]

dw_child.Object.u_mtrlware_transmx_plancode[li_row] = dw_uc.Object.u_mtrlware_trans_plancode[dw_uc.GetRow()]
dw_child.Object.u_mtrlware_transmx_status[li_row] = dw_uc.Object.u_mtrlware_trans_status[dw_uc.GetRow()]
dw_child.Object.u_mtrlware_transmx_woodcode[li_row] = dw_uc.Object.u_mtrlware_trans_woodcode[dw_uc.GetRow()]
dw_child.Object.u_mtrlware_transmx_pcode[li_row] = dw_uc.Object.u_mtrlware_trans_pcode[dw_uc.GetRow()]

dw_child.SetColumn ('u_cust_cuscode')


end event

event ue_resetmx();IF NOT dw_edit_mode THEN
	MessageBox('提示',"非编辑状态下不可以使用!",information!,ok!)
	RETURN
END IF

long ls_i
if dw_child.rowcount() > 0 then
	for ls_i = 1 to dw_child.rowcount()
		dw_child.object.u_mtrldef_mtrlcode[ls_i] = dw_uc.object.u_mtrldef_mtrlcode[dw_uc.getrow()]
		dw_child.object.u_mtrldef_mtrlmode[ls_i] = dw_uc.object.u_mtrldef_mtrlmode[dw_uc.getrow()]
		dw_child.object.u_mtrlware_transmx_mtrlid[ls_i] = dw_uc.object.u_mtrlware_trans_mtrlid[dw_uc.getrow()]
		dw_child.object.u_mtrldef_mtrlname[ls_i] = dw_uc.object.u_mtrldef_mtrlname[dw_uc.getrow()]
		dw_child.object.u_mtrlware_transmx_fprice[ls_i] = dw_uc.object.u_mtrlware_trans_cost[dw_uc.getrow()]
		dw_child.object.u_mtrlware_transmx_status[ls_i] = dw_uc.object.u_mtrlware_trans_status[dw_uc.getrow()]
		dw_child.object.u_mtrlware_transmx_pcode[ls_i] = dw_uc.object.u_mtrlware_trans_pcode[dw_uc.getrow()]
		dw_child.object.u_mtrlware_transmx_plancode[ls_i] = dw_uc.object.u_mtrlware_trans_plancode[dw_uc.getrow()]
		dw_child.object.u_mtrlware_transmx_woodcode[ls_i] = dw_uc.object.u_mtrlware_trans_woodcode[dw_uc.getrow()]
	next
end if
end event

event ue_fj_edit();IF dw_edit_mode THEN
	MessageBox('提示','编辑状态下不可用',information!,ok!)
	RETURN
END IF

//IF NOT f_power_ind(1098) THEN
//	MessageBox(publ_operator,'你没有使用权限！')
//	RETURN
//END IF

s_edit_index_tran s_pic
Long ll_ConnectionID
String arg_msg
Long ls_row
ls_row = dw_uc.GetRow()
IF ls_row <= 0 THEN
	RETURN
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	MessageBox('提示','没有指定附件数据库连接'+arg_msg,information!,ok!)
	RETURN
END IF

s_pic.f_long = 322 //销售订单的mainID
s_pic.f_string = dw_uc.Object.u_mtrlware_trans_billcode[ls_row]
s_pic.g_long = dw_uc.Object.u_mtrlware_trans_billid[ls_row]
s_pic.e_long = dw_uc.Object.u_mtrlware_trans_scid[ls_row]
s_pic.sqltransaction = sys_filedb_sqlca


OpenWithParm(w_fj_bill_mng,s_pic)
wf_check_billfj()
end event

event ue_fj_view();IF dw_edit_mode THEN
	MessageBox('提示','编辑状态下不可用',information!,ok!)
	RETURN
END IF

s_edit_index_tran s_pic
Long ll_ConnectionID
String arg_msg
Long ls_row
ls_row = dw_uc.GetRow()
IF ls_row <= 0 THEN
	RETURN
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	MessageBox('提示','没有指定附件数据库连接'+arg_msg,information!,ok!)
	RETURN
END IF

s_pic.f_long = 322 //销售订单的mainID
s_pic.f_string = dw_uc.Object.u_mtrlware_trans_billcode[ls_row]
s_pic.g_long = dw_uc.Object.u_mtrlware_trans_billid[ls_row]
s_pic.e_long = dw_uc.Object.u_mtrlware_trans_scid[ls_row]
s_pic.sqltransaction = sys_filedb_sqlca


OpenWithParm(w_fj_bill_view,s_pic)



end event

public function integer wf_flagstatus_rf ();//====================================================================
// Function: wf_flagstatus_rf()
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments:(None)
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.12.26
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


long pagerert_row

pagerert_row=dw_pageretr.getrow()
if pagerert_row<=0 then	
	cb_auditing.enabled=false
	goto ext
end if

if dw_edit_mode then
	cb_auditing.enabled=false
	cb_auditing_cancel.enabled=false
else
	if dw_pageretr.object.u_mtrlware_trans_flag[pagerert_row]=0 then
		cb_auditing.enabled=true
		cb_auditing_cancel.enabled=false
	elseif dw_pageretr.object.u_mtrlware_trans_flag[pagerert_row]=1 then
		cb_auditing.enabled=false
		cb_auditing_cancel.enabled=true
	end if
end if

ext:
return 0
end function

public function integer wf_refresh_curuc (long arg_scid, long arg_billid);wf_flagstatus_rf() //wf_refresh_curuc
IF arg_billid <= 0 OR IsNull(arg_billid) THEN RETURN 0
Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN RETURN 0

Long storageid
DateTime billdate
String inrep
String part
String mtrlcode
Decimal transqty
String dscrp
String billcode
Long mtrlwareid
Long mtrlid
Long relid
String plancode
String status
DateTime opdate
String opemp
String Modemp
DateTime moddate
Int flag
DateTime auditingdate
String auditingrep
Decimal cost
String storagename
String cuscode
String Name
String mtrlname
String mtrlmode


SELECT u_mtrlware_trans.storageid,
	u_mtrlware_trans.billdate,
	u_mtrlware_trans.inrep,
	u_mtrlware_trans.part,
	u_mtrldef.mtrlcode,
	u_mtrlware_trans.transqty,
	u_mtrlware_trans.dscrp,
	u_mtrlware_trans.billcode,
	u_mtrlware_trans.mtrlwareid,
	u_mtrlware_trans.mtrlid,
	u_mtrlware_trans.relid,
	u_mtrlware_trans.plancode,
	u_mtrlware_trans.status,
	u_mtrlware_trans.opdate,
	u_mtrlware_trans.opemp,
	u_mtrlware_trans.Modemp,
	u_mtrlware_trans.moddate,
	u_mtrlware_trans.flag,
	u_mtrlware_trans.auditingdate,
	u_mtrlware_trans.auditingrep,
	u_mtrlware_trans.cost,
	u_storage.storagename,
	u_cust.cuscode,
	u_cust.name,
	u_mtrldef.mtrlname,
	u_mtrldef.mtrlmode
	INTO :storageid,
	:billdate,
	:inrep,
	:part,
	:mtrlcode,
	:transqty,
	:dscrp,
	:billcode,
	:mtrlwareid,
	:mtrlid,
	:relid,
	:plancode,
	:status,
	:opdate,
	:opemp,
	:Modemp,
	:moddate,
	:flag,
	:auditingdate,
	:auditingrep,
	:cost,
	:storagename,
	:cuscode,
	:Name,
	:mtrlname,
	:mtrlmode
	FROM u_mtrlware_trans LEFT OUTER JOIN u_cust ON u_mtrlware_trans.relid = u_cust.cusid,
	u_storage,
	u_mtrldef
	WHERE ( u_storage.storageid = u_mtrlware_trans.storageid ) AND
	( u_mtrlware_trans.mtrlid = u_mtrldef.mtrlid ) AND
	( u_mtrlware_trans.scid = :arg_scid ) AND
	( u_mtrlware_trans.billid = :arg_billid );
IF sqlca.SQLCode <> 0 THEN
	MessageBox('错误',"查询操作失败(错误单据唯一码)",stopsign!,ok!)
	RETURN 0
END IF

dw_pageretr.Object.u_mtrlware_trans_storageid[uc_row] = storageid
dw_pageretr.Object.u_mtrlware_trans_billdate[uc_row] = billdate
dw_pageretr.Object.u_mtrlware_trans_inrep[uc_row] = inrep
dw_pageretr.Object.u_mtrlware_trans_part[uc_row] = part
dw_pageretr.Object.u_mtrldef_mtrlcode[uc_row] = mtrlcode
dw_pageretr.Object.u_mtrlware_trans_transqty[uc_row] = transqty
dw_pageretr.Object.u_mtrlware_trans_dscrp[uc_row] = dscrp
dw_pageretr.Object.u_mtrlware_trans_billcode[uc_row] = billcode
dw_pageretr.Object.u_mtrlware_trans_mtrlwareid[uc_row] = mtrlwareid
dw_pageretr.Object.u_mtrlware_trans_mtrlid[uc_row] = mtrlid
dw_pageretr.Object.u_mtrlware_trans_relid[uc_row] = relid
dw_pageretr.Object.u_mtrlware_trans_plancode[uc_row] = plancode
dw_pageretr.Object.u_mtrlware_trans_status[uc_row] = status
dw_pageretr.Object.u_mtrlware_trans_opdate[uc_row] = opdate
dw_pageretr.Object.u_mtrlware_trans_opemp[uc_row] = opemp
dw_pageretr.Object.u_mtrlware_trans_Modemp[uc_row] = Modemp
dw_pageretr.Object.u_mtrlware_trans_moddate[uc_row] = moddate
dw_pageretr.Object.u_mtrlware_trans_flag[uc_row] = flag
dw_pageretr.Object.u_mtrlware_trans_auditingdate[uc_row] = auditingdate
dw_pageretr.Object.u_mtrlware_trans_auditingrep[uc_row] = auditingrep
dw_pageretr.Object.u_mtrlware_trans_cost[uc_row] = cost
dw_pageretr.Object.u_storage_storagename[uc_row] = storagename
dw_pageretr.Object.u_cust_cuscode[uc_row] = cuscode
dw_pageretr.Object.u_cust_name[uc_row] = Name
dw_pageretr.Object.u_mtrldef_mtrlname[uc_row] = mtrlname
dw_pageretr.Object.u_mtrldef_mtrlmode[uc_row] = mtrlmode
dw_pageretr.Object.u_mtrlware_trans_scid[uc_row] = arg_scid
dw_pageretr.Object.u_mtrlware_trans_billid[uc_row] = arg_billid

dw_uc.Reset()
dw_pageretr.RowsCopy(dw_pageretr.GetRow(),dw_pageretr.GetRow(), Primary!, dw_uc, 1, Primary!)

dw_uc.ResetUpdate()
dw_uc.SetRedraw(TRUE)


wf_flagstatus_rf()
 
RETURN 1


end function

public subroutine wf_check_billfj ();String arg_msg
Long ll_ConnectionID
Long cur_billtype
long ll_relid,ll_relid_mx,ll_scid
Long ls_filecount = 0
Int rslt = 1

uo_fj_mng_billtype ls_uo_fjbt
ls_uo_fjbt = CREATE uo_fj_mng_billtype
 
Long row,uc_relid
row = dw_pageretr.GetRow()
IF row > 0 THEN
	ll_relid = dw_pageretr.Object.u_mtrlware_trans_billid[row]
	ll_scid = dw_pageretr.Object.u_mtrlware_trans_scid[row]
	ll_relid_mx = 0
ELSE
	rslt = 0
	GOTO ext
END IF

IF f_get_outerconnection(ll_ConnectionID,arg_msg) = 0 THEN
	rslt = 0
	GOTO ext
END IF

cur_billtype = 322 //客户投拆单的 mainiD

ls_uo_fjbt.uf_check_billfj( cur_billtype, ll_relid,ll_relid_mx,ll_scid, sys_fileDB_sqlca, arg_msg, ls_filecount)

IF ls_filecount > 0 THEN
	rslt = 1
	GOTO ext
ELSE
	rslt = 0
	GOTO ext
END IF

ext:

wf_encl(rslt)

DESTROY ls_uo_fjbt
end subroutine

public function integer wf_xls_retrievedata (long arg_ationid, ref s_xls_billlist arg_str_billlist, ref uo_sendtoexcel arg_obj_st, ref string arg_msg);//==============================================================================
// 函数: w_publ_1ton_share_detail::wf_xls_retrievedata()
//------------------------------------------------------------------------------
// 描述:  此函数需要 重载,复制祖先范例代码,然后修改retrieve参数部分两处即可
//------------------------------------------------------------------------------

Long LS_ROW,ll_id,i,ll_scid
LS_ROW = dw_uc.GetRow()
IF LS_ROW <= 0 THEN
	arg_msg = '没有目标单据!'
	RETURN 0
END IF

//修改点:获取 指定retriev参数
ll_id = dw_uc.Object.#1[LS_ROW]
ll_scid = dw_uc.Object.u_mtrlware_trans_scid[LS_ROW]

//查询所选模版是否含有图片信息
Long ll_ifpic
Long ll_classid
SELECT ifpic
	INTO :ll_ifpic
	FROM U_XLS_Templates
	Where id = :ll_xls_Templatesid;
IF sqlca.SQLCode <> 0 THEN
	ll_ifpic = 0
END IF

Long ll_i,ll_j
Long ll_mtrlid
Long ll_fileid

Blob ls_filedata
SetNull(ls_filedata)
String Pathname,ls_filename,ls_filetype
String errmsg
uo_fj_mng_billtype  ls_uo_fjbt
ls_uo_fjbt = CREATE uo_fj_mng_billtype

s_xls_pic_list s_pic //结构数组-用于保存图片路径

IF ll_ifpic = 1 THEN //如果含有图片信息,则查询本类型单据需要带出哪类附件

	SELECT classid
		INTO :ll_classid
		FROM u_billpic_fileclass
		Where (billtype = 335);
	IF sqlca.SQLCode <> 0 THEN
		ll_classid = 0
	END IF
	
	IF ll_classid > 0 THEN //如果已经指定好附件类型,则循环明细表查询每个明细的图片信息.
		FOR ll_i = 1 TO dw_child.RowCount()
			ll_mtrlid = dw_child.Object.u_mtrlware_transmx_mtrlid[ll_i]
			//取该附件类型中的第一个附件.
			SELECT top 1 fileid,DisplayName,FileType INTO :ll_fileid,:ls_filename,:ls_filetype
				FROM u_file
				WHERE relid = :ll_mtrlid
				AND classid = :ll_classid
				AND (filetype = 'bmp' OR filetype = 'rle' OR filetype = 'wmf'
				OR filetype = 'tif' OR filetype = 'jpg' OR filetype = 'gif' OR filetype = 'jpeg')
				USING sys_fileDB_sqlca;
			IF sys_fileDB_sqlca.SQLCode <> 0 THEN
				ll_fileid = 0
			END IF
			IF ll_fileid > 0 THEN
				Pathname = sys_cur_path+ins_fjtemppath+'\'+String(Today(),'yymmdd')+String(Now(),'hhmmss')+'_'+ls_filename+'.'+ls_filetype
				IF Trim(Pathname) <> '' THEN
					IF ls_uo_fjbt.uf_getfjbolb_fromdb( ll_fileid, ls_filedata, sys_fileDB_sqlca, arg_msg) = 0 THEN
						RETURN  0
					END IF
					
					IF f_saveblobtofile(ls_filedata,Pathname,errmsg) = 0 THEN
						RETURN 0
					ELSE
						
						s_pic.path[ll_i] = Pathname
						//记录临时文件位置,本窗口退出后删除
						wf_addlog_tempfilepathname(Pathname)
						
					END IF
				ELSE
					s_pic.path[ll_i] = ''
				END IF
			ELSE
				s_pic.path[ll_i] = ''
			END IF
		NEXT
	END IF
	//
END IF

////可选设置///
arg_obj_st.uo_const.create_new_pwd( )  //创建随机密码 
if sys_option_xls_ifuse_passwd = 1 then arg_obj_st.uo_const.pwd = trim(sys_option_xls_user_passwd)   //默认加密密码    默认为随即密码


boolean xls_locked
xls_locked = not (sys_option_xls_lock = 1)

/// Excel 的可选设置
if arg_obj_st.of_setoption(arg_ationid,  xls_locked,true,arg_msg) <> 1 then
		return 0
end if


for i = 1 to arg_str_billlist.count
	////可选操作///
	arg_str_billlist.bill[i].ds_data = create datastore                                  //
	arg_str_billlist.bill[i].ds_data.dataobject = arg_str_billlist.bill[i].datawindow       //
	arg_str_billlist.bill[i].ds_data.settransobject(sqlca)
	
	//修改点:注意retrieve 参数与上文对应
	arg_str_billlist.bill[i].ds_data.retrieve(ll_scid,ll_id)

next 

return 1
end function

public function integer wf_print_retrievedata (ref s_print_pic_list arg_s_pic, ref string arg_msg);Long LS_ROW,ll_id,i,ll_scid
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	arg_msg = '没有目标单据!'
	RETURN 0
END IF

//修改点:获取 指定retriev参数
ll_id = dw_pageretr.Object.#1[LS_ROW]
ll_scid = dw_pageretr.Object.u_mtrlware_trans_scid[LS_ROW]


Long ll_i,ll_j
Long ll_mtrlid
Long ll_fileid

Blob ls_filedata
SetNull(ls_filedata)
String Pathname,ls_filename,ls_filetype
String errmsg
uo_fj_mng_billtype  ls_uo_fjbt
ls_uo_fjbt = CREATE uo_fj_mng_billtype

Long ll_classid
SELECT classid
	INTO :ll_classid
	FROM u_billpic_fileclass
	Where (billtype = 102);
IF sqlca.SQLCode <> 0 THEN
	ll_classid = 0
END IF

IF ll_classid > 0 THEN //如果已经指定好附件类型,则循环明细表查询每个明细的图片信息.
	FOR ll_i = 1 TO dw_child.RowCount()
		ll_mtrlid = dw_child.Object.u_mtrlware_transmx_mtrlid[ll_i]
		arg_s_pic.mtrlid[ll_i] = ll_mtrlid
		//取该附件类型中的第一个附件.
		SELECT top 1 fileid,DisplayName,FileType INTO :ll_fileid,:ls_filename,:ls_filetype
			FROM u_file
			WHERE relid = :ll_mtrlid
			AND classid = :ll_classid
			AND (filetype = 'bmp' OR filetype = 'rle' OR filetype = 'wmf'
			OR filetype = 'tif' OR filetype = 'jpg' OR filetype = 'gif' OR filetype = 'jpeg')
			USING sys_fileDB_sqlca;
		IF sys_fileDB_sqlca.SQLCode <> 0 THEN
			ll_fileid = 0
		END IF
		IF ll_fileid > 0 THEN
			Pathname = sys_cur_path+ins_fjtemppath+'\'+String(Today(),'yymmdd')+String(Now(),'hhmmss')+'_'+ls_filename+'.'+ls_filetype
			IF Trim(Pathname) <> '' THEN
				IF ls_uo_fjbt.uf_getfjbolb_fromdb( ll_fileid, ls_filedata, sys_fileDB_sqlca, arg_msg) = 0 THEN
					RETURN  0
				END IF
				
				IF f_saveblobtofile(ls_filedata,Pathname,errmsg) = 0 THEN
					RETURN 0
				ELSE
					
					arg_s_pic.path[ll_i] = Pathname
					//记录临时文件位置,本窗口退出后删除
					wf_addlog_tempfilepathname(Pathname) 
				END IF
			ELSE
				arg_s_pic.path[ll_i] = ''
			END IF
		ELSE
			arg_s_pic.path[ll_i] = ''
		END IF
	NEXT
END IF
RETURN 1 
end function

on w_mtrlware_trans.create
int iCurrent
call super::create
this.ddlb_status=create ddlb_status
this.st_2=create st_2
this.st_3=create st_3
this.ddlb_scid=create ddlb_scid
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.ddlb_status
this.Control[iCurrent+2]=this.st_2
this.Control[iCurrent+3]=this.st_3
this.Control[iCurrent+4]=this.ddlb_scid
end on

on w_mtrlware_trans.destroy
call super::destroy
destroy(this.ddlb_status)
destroy(this.st_2)
destroy(this.st_3)
destroy(this.ddlb_scid)
end on

event open;THIS.TriggerEvent('ue_before_open')
wf_movetocenter()
ds_copy_bill = CREATE datastore
ds_copy_bill.DataObject = dw_child.dataobject
ds_copy_bill.SetTransObject(sqlca)
OLD_TITLE = THIS.Title

s_tran = Message.PowerObjectParm
IF NOT IsNull(s_tran) THEN
	retrieve_all = s_tran.if_retrieve_all
	mode = s_tran.work_mode
	arg_pkid = s_tran.arg_pkid
	arg_string_code = s_tran.arg_string_code
	if_sharedata = s_tran.if_sharedata //是否应用sharedata，当retrieve_all＝true是生效
	ds_share = s_tran.ds_share
END IF

dw_pageretr.RBUTTON_FILTER_USE = TRUE //右键查询功能开关
dw_pageretr.titleclick_sort_use = TRUE  //单击标题排序功能开关

dw_pageretr.SetTransObject (sqlca)
pkcolumndbtname = wf_get_pkcolumndbtname(dw_pageretr) //取第一列为关键字

ori_oldselect = dw_pageretr.DESCRIBE("DataWindow.Table.Select")
//====================================================================
// Script - w_inware_cp inherited from w_publ_1ton_share_detail for open 
// Reason: 
//--------------------------------------------------------------------
// Modified By: yyx		Date: 2003.12.01
//--------------------------------------------------------------------
ori_oldselect = f_modify_selectstr(ori_oldselect)//只显示所管的仓库单据
//====================================================================


ls_newselect = ori_oldselect
ds_curquery = CREATE DATASTORE
ds_curquery.DataObject = 'd_extr_find'
ds_curquery.SetTransObject (sqlca)

wf_editindex_lockf()

sle_usual_query.Text = Trim(arg_string_code)
IF NOT retrieve_all THEN
	THIS.TriggerEvent("ue_usual_query_RETR") //修改ls_newselect,retrieve
ELSE
	IF  if_sharedata THEN
		ds_share.ShareData(dw_pageretr)
	ELSE
		wf_retrieveuc(dw_pageretr,ls_newselect,1)
		THIS.TriggerEvent('RETRIEVE_pageretr')
	END IF
END IF

IF retrieve_all THEN
	THIS.TriggerEvent("ue_usual_query_filt")
END IF

uc_column_int = 9 //uc dw前5列可以编辑
child_column_int = 5 //子dw前5列可以编辑
uo_ware = CREATE uo_mtrlware_trans
uo_ware.commit_transaction = sqlca

s_hide_col s_col
s_col.col_1 = 'u_mtrlware_transmx_fprice'
s_col.col_2 = 'amt'

f_hide_col(1473,dw_child,s_col)

s_hide_col s_col_mtrlsectype
s_col_mtrlsectype.col_1 = 'u_mtrldef_mtrlsectype'
f_hide_col(1308,dw_child,s_col_mtrlsectype) 

s_hide_col s_col_zxmtrlmode
s_col_zxmtrlmode.col_1 = 'u_mtrldef_zxmtrlmode'
f_hide_col(1309,dw_child,s_col_zxmtrlmode) 


end event

event close;call super::close;destroy uo_ware
wf_del_tempfilepathname()
end event

event refresh_interface;call super::refresh_interface;wf_flagstatus_rf()

ddlb_status.enabled = not dw_edit_mode

if dw_edit_mode then
	ddlb_scid.enabled=false
else
	if sys_scid > 0 then
		ddlb_scid.enabled=false
	else
		ddlb_scid.enabled=true
	end if
end if



end event

event retrieve_childdw;call super::retrieve_childdw;long row,uc_relid,ll_scid
row=dw_pageretr.getrow()

if row>0 then 
	ll_scid=dw_pageretr.object.u_mtrlware_trans_scid[row]
	uc_relid=dw_pageretr.object.u_mtrlware_trans_billid[row]
	dw_child.SetRedraw (false)
	dw_child.retrieve(uc_relid,ll_scid)
	dw_child.SetRedraw (true)
else
	dw_child.reset()
end if

end event

event retrieve_pageretr;boolean cb_firstpage_enabled,cb_nextpage_enabled,cb_retrieveall_enabled
boolean cb_priorpage_enabled,cb_func_enabled,cb_retrieve_enabled

 
cb_nextpage_enabled=cb_nextpage.enabled
cb_retrieveall_enabled=cb_retrieveall.enabled 
cb_func_enabled=cb_func.enabled

 
cb_nextpage.enabled=false
cb_retrieveall.enabled=false 
cb_func.enabled=false
//只显未自已管的仓库
datawindowchild childdw
string new_sqlstr,modify_str

dw_uc.SetTransObject (sqlca)
dw_uc.getchild("u_mtrlware_trans_storageid",childdw)
childdw.SetTransObject (sqlca)

new_sqlstr=childdw.Describe("DataWindow.Table.Select")
if len(ol_cdw_str) = 0 then ol_cdw_str = new_sqlstr
new_sqlstr=f_modify_selectstr(ol_cdw_str)
modify_str="DataWindow.Table.Select='" + new_sqlstr +"'"
childdw.modify ( modify_str )
if childdw.retrieve(cur_scid) = 0 then
		childdw.InsertRow(0)
END IF
//childdw.retrieve()
dw_uc.Retrieve() //dw_uc的dw改左select top 0 并肯不带参数
dw_pageretr.Retrieve(cur_scid,cur_flag)
IF dw_pageretr.RowCount() > 0 THEN 
	dw_pageretr.SetRow(1)
	dw_pageretr.triggerevent(rowfocuschanged!)
end if
this.triggerevent('retrieve_childdw')

 
cb_nextpage.enabled=cb_nextpage_enabled
cb_retrieveall.enabled=cb_retrieveall_enabled 
cb_func.enabled=cb_func_enabled



end event

event ue_usual_query_filt;call super::ue_usual_query_filt;string ls_querystrpart=''
ls_newselect=lower(ori_oldselect)
if trim(sle_usual_query.text)<>'' then
	if pos(trim(sle_usual_query.text),'%')=0 then
		ls_querystrpart="(u_mtrlware_trans_billcode like '%"+trim(sle_usual_query.text)+"%')"
	else
		ls_querystrpart="(u_mtrlware_trans_billcode like '"+trim(sle_usual_query.text)+"')"
	end if

	if Pos(ls_newselect," where ") <> 0 then
	   ls_newselect=ls_newselect+" AND ("+ls_querystrpart+')'
	else
		ls_newselect=ls_newselect+" where ("+ls_querystrpart+')'
	end if
end if
wf_retrieveuc(dw_pageretr,ls_newselect,1)  
this.triggerevent('retrieve_pageretr')

end event

event ue_usual_query_retr;call super::ue_usual_query_retr;string ls_querystrpart=''
ls_newselect=lower(ori_oldselect)
if trim(sle_usual_query.text)<>'' then
	if pos(trim(sle_usual_query.text),'%')=0 then
		ls_querystrpart="(u_mtrlware_trans.billcode like '%"+trim(sle_usual_query.text)+"%')"
	else
		ls_querystrpart="(u_mtrlware_trans.billcode like '"+trim(sle_usual_query.text)+"')"
	end if

	if Pos(ls_newselect," where ") <> 0 then
	   ls_newselect=ls_newselect+" AND ("+ls_querystrpart+')'
	else
		ls_newselect=ls_newselect+" where ("+ls_querystrpart+')'
	end if
end if
wf_retrieveuc(dw_pageretr,ls_newselect,1)  
this.triggerevent('retrieve_pageretr')
end event

event ue_f8;call super::ue_f8;if not dw_edit_mode then return
long child_row

dw_child.accepttext()	
child_row=dw_child.getrow()
if child_row <= 0 then return
 

if not isvalid(w_cust_edit) then 
	s_edit_index_tran s_ch_tran  //传递参数使用
	s_ch_tran.if_retrieve_all=false  //是否一次RETRIEVE所有行
	s_ch_tran.work_mode=1            //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid=0             //目标定位PKID (备用)
	//查询列(物料编码)部分内容,用于初步筛选
	
	
	s_ch_tran.arg_string_code=upper(trim(dw_child.object.u_cust_cuscode[dw_child.getrow()]))

	OPENwithparm(W_cust_edit,s_ch_tran)  //调用

	s_custom S_INSCUST
	S_INSCUST=Message.PowerObjectParm  //接受返回结构

	IF S_INSCUST.cusid>0 THEN //正常返回值则可以取以下值
		dw_child.setredraw(false)
		dw_child.object.u_mtrlware_transmx_rel_cusid_sptid[child_row]=S_INSCUST.cusid
		dw_child.object.u_cust_name[child_row]=S_INSCUST.name
		dw_child.object.u_cust_cuscode[child_row]=S_INSCUST.cuscode	
		dw_child.setredraw(true)	
		
		dw_child.setcolumn("u_mtrlware_transmx_qty")
		    
	END IF
end if
 

end event

event ue_f9;call super::ue_f9;//用于选择明细内容,被f8[默认]\dw_child.doubleclicked调用
IF NOT dw_edit_mode THEN RETURN
Long ins_storageid = 0,uc_row

uc_row = dw_uc.GetRow()
IF uc_row <= 0 THEN RETURN

ins_storageid = dw_uc.Object.u_mtrlware_trans_storageid[uc_row]
IF ins_storageid = 0 OR IsNull(ins_storageid) THEN
	MessageBox('提示','请先选择仓库',information!,ok!)
	RETURN
END IF


IF NOT IsValid(w_mtrlware_storageid_ch) THEN
	s_edit_index_tran s_tranf8 //传递参数使用
	s_tranf8.if_retrieve_all = FALSE  //是否一次retrieve所有行
	s_tranf8.arg_pkid = 0             //目标定位pkid (备用)
	s_tranf8.arg_string_code = ''     //查询列(物料编码)部分内容,用于初步筛选 
	s_tranf8.b_long = - 1           //选择原料或产品
	s_tranf8.d_long = ins_storageid
	s_tranf8.c_long = -1
	dw_uc.AcceptText()
	IF uc_row > 0 THEN s_tranf8.arg_string_code = Trim(dw_uc.Object.u_mtrldef_mtrlcode[uc_row])
	OpenWithParm(w_mtrlware_storageid_ch,s_tranf8) //调用
	
	s_mtrlware_noalloc_array s_inscust
	s_inscust = Message.PowerObjectParm //接受返回结构
	
	IF s_inscust.mtrlwareid[1] > 0 THEN
		dw_uc.Object.u_mtrlware_trans_mtrlwareid[uc_row] = s_inscust.mtrlwareid[1]
		dw_uc.Object.u_mtrlware_trans_mtrlid[uc_row] = s_inscust.mtrlid[1]
		dw_uc.Object.u_mtrldef_mtrlcode[uc_row]    = s_inscust.u_mtrldef_mtrlcode[1]
		dw_uc.Object.u_mtrldef_mtrlname[uc_row]    = s_inscust.u_mtrldef_mtrlname[1]
		dw_uc.Object.u_mtrldef_mtrlmode[uc_row]    = s_inscust.u_mtrldef_mtrlmode[1]
		dw_uc.Object.u_mtrlware_trans_transqty[uc_row]       = s_inscust.noallocqty[1]
		dw_uc.Object.u_mtrlware_trans_cost[uc_row]     = s_inscust.cost[1]
		dw_uc.Object.u_mtrlware_trans_plancode[uc_row] = s_inscust.plancode[1]
		dw_uc.Object.u_mtrlware_trans_status[uc_row] = s_inscust.status[1]
		dw_uc.Object.u_mtrlware_trans_relid[uc_row] = s_inscust.sptid[1]
		dw_uc.Object.u_mtrlware_trans_woodcode[uc_row] = s_inscust.woodcode[1]
		dw_uc.Object.u_mtrlware_trans_pcode[uc_row] = s_inscust.pcode[1]
		dw_uc.Object.u_mtrldef_zxmtrlmode[uc_row] = s_inscust.u_mtrldef_zxmtrlmode[1]
		dw_uc.Object.u_mtrldef_mtrlsectype[uc_row]  = s_inscust.u_mtrldef_mtrlsectype[1]
		
		String ls_cuscode,ls_cusname
		SELECT cuscode,name INTO :ls_cuscode,:ls_cusname
			FROM u_cust
			Where cusid = :s_inscust.sptid[1];
		IF sqlca.SQLCode <> 0 THEN
			ls_cuscode = ''
			ls_cusname = ''
		END IF
		dw_uc.Object.u_cust_cuscode[uc_row] = ls_cuscode
		dw_uc.Object.u_cust_name[uc_row] = ls_cusname
		dw_uc.SetColumn('u_mtrlware_trans_transqty')
		
		//设置第一条明细
		IF dw_child.RowCount() > 0 THEN
			Long i
			FOR i = 1 TO dw_child.RowCount()
				dw_child.Object.u_mtrldef_mtrlcode[i] = s_inscust.u_mtrldef_mtrlcode[1]
				dw_child.Object.u_mtrldef_mtrlname[i] = s_inscust.u_mtrldef_mtrlname[1]
				dw_child.Object.u_mtrlware_transmx_mtrlid[i] = s_inscust.mtrlid[1]
				dw_child.Object.u_mtrldef_mtrlmode[i] = s_inscust.u_mtrldef_mtrlmode[1]
				dw_child.Object.u_mtrlware_transmx_fprice[i] = s_inscust.cost[1]
				
				dw_child.Object.u_mtrlware_transmx_plancode[i] = s_inscust.plancode[1]
				dw_child.Object.u_mtrlware_transmx_status[i] = s_inscust.status[1]
				dw_child.Object.u_mtrlware_transmx_woodcode[i] = s_inscust.woodcode[1]
				dw_child.Object.u_mtrlware_transmx_pcode[i] = s_inscust.pcode[1]
				dw_child.Object.u_mtrldef_zxmtrlmode[i] = s_inscust.u_mtrldef_zxmtrlmode[1]
				dw_child.Object.u_mtrldef_mtrlsectype[i]  = s_inscust.u_mtrldef_mtrlsectype[1]
			NEXT
		END IF
	END IF
END IF



end event

event ue_addzy;call super::ue_addzy;IF dw_edit_mode THEN
	MessageBox('提示',"编辑状态下不可以使用!",information!,ok!)
	return
END IF

if not f_power_ind(789) then
	messagebox('提示','你没有使用权限！',information!,ok!)
	return
end if

string arg_msg='',LS_STR
long uc_row
s_inputbox S_SREU

uc_row=dw_pageretr.getrow()
if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!',information!,ok!)
	return
end if
S_SREU.TITLE='请输入要补充到备注的内容'
S_SREU.OLD_TEXT=''
openwithparm(w_inputbox,S_SREU)
LS_STR=Message.StringParm
if trim(LS_STR)='' or isnull(LS_STR) then return

if uo_ware.add_dscrp(cur_scid,dw_pageretr.object.u_mtrlware_trans_billid[uc_row],LS_STR,arg_msg)=0 then
	messagebox('错误',arg_msg,stopsign!,ok!)
	return
else
	messagebox('提示','添加备注操作成功!',stopsign!,ok!)
	wf_refresh_curuc(cur_scid,dw_pageretr.object.u_mtrlware_trans_billid[uc_row])
end if

end event

event ue_f10;call super::ue_f10;IF NOT dw_edit_mode THEN RETURN

Long child_row
Int if_addmxdscrp
String ls_mxdscrp
s_addqty_input s_input

dw_child.AcceptText( )

child_row = dw_child.GetRow()

IF child_row <= 0 THEN RETURN

IF dw_child.Object.u_mtrlware_transmx_mtrlid[child_row] <= 0 THEN RETURN

ls_mxdscrp = dw_child.Object.u_mtrlware_transmx_mxdscrp[child_row]

IF NOT IsValid(w_addqty_input) THEN
	OpenWithParm(w_addqty_input,ls_mxdscrp)
	
	s_input = Message.PowerObjectParm
	
	IF s_input.addqty = -1 THEN RETURN
	
	if_addmxdscrp = Integer(f_ProfileString (sys_empid,'addqty_input', "if_addmxdscrp", '0'))
	IF if_addmxdscrp = 1 THEN 
		dw_child.Object.u_mtrlware_transmx_mxdscrp[child_row] = s_input.addqtystr
	END IF 
	dw_child.Object.u_mtrlware_transmx_addqty[child_row]  = s_input.addqty
	dw_child.Object.u_mtrlware_transmx_qty[child_row]  = s_input.qty
END IF


end event

event ue_viewprint;call super::ue_viewprint; 
Long LS_ROW
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('提示','没有打印目标单据!',information!,ok!)
	RETURN
END IF

S_print_MSG LS_PRMSG

IF ls_newname <> '' THEN
	 
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	LS_PRMSG.obj_dwNAME = 'dw_rp_mtrlware_trans_print'
END IF

LS_PRMSG.TAG_TEXT = '客存调整单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.retr_pram_falg = 15
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_scid = cur_scid
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_mtrlware_trans_billid[LS_ROW]
LS_PRMSG.rowcnt = dw_child.rowcount()


IF ifpic = 1 THEN
	String ls_msg
	IF wf_print_retrievedata(LS_PRMSG.s_pic,ls_msg) = 0 THEN
		MessageBox('提示','下载图片失败!',information!,OK!)
		RETURN
	END IF 
END IF


OpenWithParm(w_publ_preview,LS_PRMSG)
IF ifpic = 1 THEN
	Long li
	FOR li = 1 TO  UpperBound(LS_PRMSG.s_pic.path)
		IF Len(Trim(LS_PRMSG.s_pic.path[li])) > 0  THEN
			FileDelete(LS_PRMSG.s_pic.path[li])
		END IF
	NEXT
END IF

end event

event ue_print;call super::ue_print; 

//--直接打印
uo_print_preview uo_print
S_print_MSG LS_PRMSG
IF dw_pageretr.RowCount() = 0 THEN
	MessageBox('提示','没有可打印的单据！',information!,ok!)
	RETURN
END IF

IF MessageBox ("询问","是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN


IF ls_newname <> '' THEN
	 
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	LS_PRMSG.obj_dwNAME = 'dw_rp_mtrlware_trans_print'
END IF

LS_PRMSG.retr_pram_falg = 15
LS_PRMSG.TAG_TEXT = '客存调整单'

LS_PRMSG.FILTER_STRING = ''

LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_scid = cur_scid
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_mtrlware_trans_billid[dw_pageretr.GetRow()]
LS_PRMSG.rowcnt = dw_child.RowCount()
IF ifpic = 1 THEN
	String ls_msg
	IF wf_print_retrievedata(LS_PRMSG.s_pic,ls_msg) = 0 THEN
		MessageBox('提示','下载图片失败!',information!,OK!)
		RETURN
	END IF 
END IF
uo_print.FACT_PRINT_MSG = LS_PRMSG

String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("错误",arg_msg,stopsign!,ok!)
	RETURN
END IF
uo_print.ds_print()
IF ifpic = 1 THEN
	Long li
	FOR li = 1 TO  UpperBound(LS_PRMSG.s_pic.path)
		IF Len(Trim(LS_PRMSG.s_pic.path[li])) > 0  THEN
			FileDelete(LS_PRMSG.s_pic.path[li])
		END IF
	NEXT
END IF

end event

type cb_func from w_publ_1ton_share_detail`cb_func within w_mtrlware_trans
end type

type cb_exit from w_publ_1ton_share_detail`cb_exit within w_mtrlware_trans
end type

type sle_usual_query from w_publ_1ton_share_detail`sle_usual_query within w_mtrlware_trans
integer x = 183
integer y = 188
integer width = 549
end type

type cb_retrieveall from w_publ_1ton_share_detail`cb_retrieveall within w_mtrlware_trans
integer x = 3003
end type

type em_pagerowno from w_publ_1ton_share_detail`em_pagerowno within w_mtrlware_trans
integer width = 320
end type

type dw_pageretr from w_publ_1ton_share_detail`dw_pageretr within w_mtrlware_trans
integer x = 2053
integer width = 1486
integer height = 1144
string dataobject = "dw_mtrlware_trans_index"
end type

event dw_pageretr::rowfocuschanged;call super::rowfocuschanged;wf_check_billfj()

wf_flagstatus_rf()
end event

type st_1 from w_publ_1ton_share_detail`st_1 within w_mtrlware_trans
integer y = 208
end type

type cb_nextpage from w_publ_1ton_share_detail`cb_nextpage within w_mtrlware_trans
integer x = 3154
end type

type dw_uc from w_publ_1ton_share_detail`dw_uc within w_mtrlware_trans
integer width = 2048
integer height = 1144
string dataobject = "dw_mtrlware_trans_edit"
end type

event dw_uc::dwnkey;Parent.TriggerEvent('user_key')
IF Key = KeyDownArrow! THEN RETURN 1
IF dw_edit_mode THEN
	IF dw_uc.GetColumnName ( ) = 'u_mtrldef_mtrlcode'  And Key = KeyEnter! THEN
		Parent.TriggerEvent('ue_f9')
		RETURN 1
	ELSEIF dw_uc.GetColumnName ( ) = 'u_mtrlware_trans_dscrp'  And Key = KeyEnter! THEN
		dw_child.SetFocus()
		dw_child.ScrollToRow(1)
		dw_child.SetColumn ('u_cust_cuscode')
		RETURN 1
	ELSE
		IF  Key = KeyEnter! THEN //
			keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
			keybd_event ( 9, 0, 2, 0 ) // 释放tab 
			RETURN 1
		END IF
	END IF
END IF

end event

event dw_uc::buttonclicked;call super::buttonclicked;IF dw_edit_mode And row > 0  THEN
	Parent.TriggerEvent('ue_f9')
END IF

end event

event dw_uc::constructor;call super::constructor;f_title_change(this)
end event

type gb_2 from w_publ_1ton_share_detail`gb_2 within w_mtrlware_trans
end type

type dw_child from w_publ_1ton_share_detail`dw_child within w_mtrlware_trans
integer y = 1448
integer width = 3543
integer height = 696
string dataobject = "dw_mtrlware_transmx_edit"
end type

event dw_child::dwnkey;call super::dwnkey;Parent.TriggerEvent('user_key')
Long child_row
Long ls_null
SetNull(ls_null)

dw_uc.AcceptText()
IF dw_edit_mode THEN
	IF KeyDown(keydownarrow!) THEN
		Long li_row
		IF dw_child.GetRow() = dw_child.RowCount() THEN
			Parent.TriggerEvent("insert_childrow")
		END IF
	ELSE
		If (KeyDown(keyenter!) Or KeyDown(keytab!)) And Not KeyDown(keycontrol!) And Not KeyDown(keyshift!)  THEN
			IF dw_child.GetColumnName() = 'u_cust_cuscode' THEN
				dw_child.AcceptText()
				child_row = dw_child.GetRow()
				IF child_row <= 0 THEN RETURN 1
				String ls_cuscode,ls_cusname
				Long li_cusid
				ls_cuscode = dw_child.Object.u_cust_cuscode[child_row]
				SELECT cusid,name INTO :li_cusid,:ls_cusname
					FROM u_cust
					Where cuscode = :ls_cuscode;
				IF sqlca.SQLCode <> 0 THEN
					Parent.TriggerEvent('ue_f8')
					RETURN 1
				END IF
				dw_child.Object.u_cust_name[child_row] = ls_cusname
				dw_child.Object.u_mtrlware_transmx_rel_cusid_sptid[child_row] = li_cusid
				IF Key = keyenter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF
			ELSEIF dw_child.GetColumnName( ) = 'u_mtrlware_transmx_plancode' And dw_child.GetRow() = dw_child.RowCount() THEN
				Parent.TriggerEvent("insert_childrow")
				RETURN 1
			ELSE
				IF Key = keyenter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF
			END IF
		END IF
	END IF
END IF



















end event

event dw_child::doubleclicked;IF dw_edit_mode THEN
	IF dwo.Name = 'u_mtrlware_transmx_addqty' THEN
		Parent.TriggerEvent('ue_f10')
	ELSE
		Parent.TriggerEvent('ue_f8')
	END IF
END IF


end event

type cb_viewprint from w_publ_1ton_share_detail`cb_viewprint within w_mtrlware_trans
end type

type cb_print from w_publ_1ton_share_detail`cb_print within w_mtrlware_trans
end type

type cb_add from w_publ_1ton_share_detail`cb_add within w_mtrlware_trans
end type

event cb_add::clicked;IF NOT f_power_ind(89) THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF

String arg_msg = ''
Long uc_row,i

IF dw_edit_mode THEN
	dw_uc.AcceptText()
	dw_child.AcceptText()
	uc_row = dw_uc.GetRow()
	IF uc_row <= 0 THEN
		MessageBox('提示','请选定当前目标单据!',information!,ok!)
		RETURN
	END IF
	IF NOT dw_uc.Object.u_mtrlware_trans_billdate[uc_row] > DateTime(2000-01-01,Now()) THEN
		MessageBox('提示','不合理发生时间!',information!,ok!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("u_mtrlware_trans_billdate")
		RETURN
	END IF
	IF NOT Len(String(dw_uc.Object.u_mtrlware_trans_inrep[uc_row])) > 0 THEN
		MessageBox('提示','请填写经手人!',information!,ok!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("u_mtrlware_trans_inrep")
		RETURN
	END IF
	                       
	
	uo_ware.mtrlwareid = dw_uc.Object.u_mtrlware_trans_mtrlwareid[uc_row]    
	uo_ware.storageid  = dw_uc.Object.u_mtrlware_trans_storageid[uc_row]      
	uo_ware.mtrlid     = dw_uc.Object.u_mtrlware_trans_mtrlid[uc_row]      
	uo_ware.relid      = dw_uc.Object.u_mtrlware_trans_relid[uc_row]      
	uo_ware.plancode   = dw_uc.Object.u_mtrlware_trans_plancode[uc_row]
	uo_ware.status     = dw_uc.Object.u_mtrlware_trans_status[uc_row]   
	uo_ware.woodcode   = dw_uc.Object.u_mtrlware_trans_woodcode[uc_row]
	uo_ware.pcode     = dw_uc.Object.u_mtrlware_trans_pcode[uc_row]
	uo_ware.billdate   = dw_uc.object.u_mtrlware_trans_billdate[uc_row]
	uo_ware.inrep      = dw_uc.Object.u_mtrlware_trans_inrep[uc_row]      
	uo_ware.part       = dw_uc.Object.u_mtrlware_trans_part[uc_row]
	uo_ware.dscrp      = dw_uc.Object.u_mtrlware_trans_dscrp[uc_row]
	uo_ware.transqty   = dw_uc.object.u_mtrlware_trans_transqty[uc_row]
	uo_ware.addqty   = dw_uc.object.u_mtrlware_trans_addqty[uc_row]
	uo_ware.cost       = dw_uc.object.u_mtrlware_trans_cost [uc_row]  
	
	FOR i = 1 TO dw_child.RowCount()
		IF dw_child.Object.u_mtrlware_transmx_mtrlid[i] > 0 THEN

			IF uo_ware.acceptmx(dw_child.Object.printid[i],&
				dw_child.Object.u_mtrlware_transmx_mtrlid[i],&
				dw_child.Object.u_mtrlware_transmx_plancode[i],&
				dw_child.Object.u_mtrlware_transmx_status[i],&
				dw_child.Object.u_mtrlware_transmx_qty[i],&
				dw_child.Object.u_mtrlware_transmx_addqty[i],&
				dw_child.Object.u_mtrlware_transmx_fprice[i],&
				1,&
				dw_child.Object.u_mtrlware_transmx_mxdscrp[i],&				
				dw_child.Object.u_mtrlware_transmx_rel_cusid_sptid[i],&
				arg_msg,&
				dw_child.Object.u_mtrlware_transmx_woodcode[i],&				
				dw_child.Object.u_mtrlware_transmx_pcode[i]) = 0 THEN
				MessageBox('错误',arg_msg,stopsign!,ok!)
				RETURN
			END IF
		END IF
	NEXT
	                
	
	IF uo_ware.save(true,arg_msg) = 0 THEN
		MessageBox('错误',arg_msg,stopsign!,ok!)
		RETURN
	END IF
//	MessageBox(publ_operator,'保存操作成功!')
	//write ini
	f_SetProfileString (sys_empid,dw_uc.DataObject, "ddlb_storageid",String(dw_uc.Object.u_mtrlware_trans_storageid[dw_uc.GetRow()]))
	//
	long ll_row
	ll_row = dw_uc.getrow()
	dw_uc.SelectRow(0,FALSE)
	dw_uc.SelectRow(ll_row,TRUE)
	wf_refresh_curuc(cur_scid,uo_ware.billid) //刷新uc
	
ELSE
	IF uo_ware.newbegin(cur_scid,arg_msg) = 0 THEN 
		MessageBox('错误',arg_msg,stopsign!,ok!)
		RETURN
	END IF
END IF

CALL SUPER::Clicked
//read ini
IF dw_edit_mode THEN
	PARENT.TriggerEvent("insert_childrow")
	dw_uc.SetRedraw(FALSE)
	String ls_storageid
	ls_storageid = f_ProfileString (sys_empid,dw_uc.DataObject, "ddlb_storageid",'0')
	IF f_find_storageid(ls_storageid) = '' THEN
		ls_storageid = '0'
	END IF
	dw_uc.Object.u_mtrlware_trans_storageid[dw_uc.GetRow()] = Long(ls_storageid)
	dw_uc.Object.u_mtrlware_trans_inrep[dw_uc.GetRow()]   = publ_operator
	dw_uc.SetColumn("u_mtrlware_trans_storageid")
	dw_uc.SetRedraw(TRUE)
ELSE
	PARENT.TriggerEvent("retrieve_childdw")
END IF
//
THIS.TriggerEvent('refresh_interface')

end event

type cb_edit from w_publ_1ton_share_detail`cb_edit within w_mtrlware_trans
end type

event cb_edit::clicked;IF NOT f_power_ind(89) THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF

string arg_msg=''
long uc_row

uc_row=dw_pageretr.getrow()
if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!',information!,ok!)
	return
end if

if not dw_edit_mode then
	if uo_ware.updatebegin(cur_scid,dw_pageretr.object.u_mtrlware_trans_billid[uc_row],arg_msg)=0 then
		messagebox('错误',arg_msg,stopsign!,ok!)
		return
	end if
end if

call super::clicked
end event

type cb_delet from w_publ_1ton_share_detail`cb_delet within w_mtrlware_trans
end type

event cb_delet::clicked;IF NOT f_power_ind(614) THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF


IF dw_edit_mode THEN RETURN


String arg_msg = ''
Long uc_row

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,ok!)
	RETURN
END IF
IF MessageBox ("询问","是否确定要删除当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN

IF uo_ware.del(cur_scid,dw_pageretr.Object.u_mtrlware_trans_billid[uc_row],arg_msg,TRUE) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
ELSE
	//日志
	Long ls_id
	String ls_code
	ls_id = dw_pageretr.Object.u_mtrlware_trans_billid[uc_row]
	ls_code = dw_pageretr.Object.u_mtrlware_trans_billcode[uc_row]
	f_setsysoplog('客户库存调整单','删除,ID:'+String(ls_id)+',code:'+ls_code,arg_msg,TRUE)
	//--
	MessageBox('提示','删除单据'+String(dw_pageretr.Object.u_mtrlware_trans_billcode[uc_row])+'成功!',information!,ok!)
	dw_pageretr.DeleteRow(uc_row)
	dw_pageretr.PostEvent(RowFocusChanged!)
END IF

end event

type cb_addzy from w_publ_1ton_share_detail`cb_addzy within w_mtrlware_trans
end type

event cb_addzy::clicked;call super::clicked;m_Dfc_Control_PopupMenu dmPopupMenu
string menustr


menustr="Text=增加备注~tEvent=ue_addzy"
menustr=menustr + "|" + "Text=-"
menustr=menustr + "|" + "Text=明细重新设定产品~tEvent=cb_resetmx"
menustr = menustr + "|" + "Text=-"
menustr = menustr + "|" + "Text=查看附件~tEvent=ue_fj_view"
menustr = menustr + "|" + "Text=添加附件~tEvent=ue_fj_edit"

if len(trim(menustr))<>0 then
	dmPopupMenu = Create m_Dfc_Control_PopupMenu
	dmPopupMenu.mf_BuildMenu(This, menustr)
	dmPopupMenu.mf_PopMenu()
	Destroy dmPopupMenu
end if
end event

type cb_auditing from w_publ_1ton_share_detail`cb_auditing within w_mtrlware_trans
end type

event cb_auditing::clicked;call super::clicked;IF NOT f_power_ind(90) THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF

IF dw_edit_mode THEN RETURN

String arg_msg = ''
Long pagerert_row

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,ok!)
	RETURN
END IF
IF MessageBox ("询问","是否确定要审核当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN

IF uo_ware.getinfo(cur_scid,dw_pageretr.Object.u_mtrlware_trans_billid[pagerert_row],arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
	RETURN
END IF

IF uo_ware.auditing(TRUE,arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
ELSE
	MessageBox('提示','审核成功!',information!,ok!)
	wf_refresh_curuc(cur_scid,dw_pageretr.Object.u_mtrlware_trans_billid[pagerert_row])
END IF

end event

type cb_xm from w_publ_1ton_share_detail`cb_xm within w_mtrlware_trans
end type

type cb_retrieve from w_publ_1ton_share_detail`cb_retrieve within w_mtrlware_trans
end type

type cb_xls from w_publ_1ton_share_detail`cb_xls within w_mtrlware_trans
end type

type cb_help from w_publ_1ton_share_detail`cb_help within w_mtrlware_trans
end type

type cb_auditing_cancel from w_publ_1ton_share_detail`cb_auditing_cancel within w_mtrlware_trans
end type

event cb_auditing_cancel::clicked;call super::clicked;IF NOT f_power_ind(917) THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF

IF dw_edit_mode THEN RETURN
String arg_msg = ''

Long pagerert_row

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,ok!)
	RETURN
END IF
IF MessageBox ("询问","是否确定要撤消审核当前单据?",question!,yesno! ) = 2 THEN RETURN

IF uo_ware.getinfo(cur_scid,dw_pageretr.Object.u_mtrlware_trans_billid[pagerert_row],arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
	RETURN
END IF

IF uo_ware.c_auditing(TRUE,arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
ELSE
	//日志
	Long ls_id
	String ls_code
	ls_id = dw_pageretr.Object.u_mtrlware_trans_billid[pagerert_row]
	ls_code = dw_pageretr.Object.u_mtrlware_trans_billcode[pagerert_row]
	f_setsysoplog('客户库存调整单','撤审,ID:'+String(ls_id)+',code:'+ls_code,arg_msg,TRUE)
	//--
	MessageBox('提示','撤消审核成功!',information!,ok!)
	wf_refresh_curuc(cur_scid,dw_pageretr.Object.u_mtrlware_trans_billid[pagerert_row])
END IF

end event

type p_msg from w_publ_1ton_share_detail`p_msg within w_mtrlware_trans
end type

type p_help from w_publ_1ton_share_detail`p_help within w_mtrlware_trans
end type

type p_encl from w_publ_1ton_share_detail`p_encl within w_mtrlware_trans
end type

type p_other from w_publ_1ton_share_detail`p_other within w_mtrlware_trans
end type

type gb_3 from w_publ_1ton_share_detail`gb_3 within w_mtrlware_trans
end type

type ln_bar from w_publ_1ton_share_detail`ln_bar within w_mtrlware_trans
end type

type ln_bar2 from w_publ_1ton_share_detail`ln_bar2 within w_mtrlware_trans
end type

type r_bar from w_publ_1ton_share_detail`r_bar within w_mtrlware_trans
end type

type ln_1 from w_publ_1ton_share_detail`ln_1 within w_mtrlware_trans
integer endx = 3264
end type

type ln_2 from w_publ_1ton_share_detail`ln_2 within w_mtrlware_trans
end type

type ddlb_status from dropdownlistbox within w_mtrlware_trans
integer x = 1714
integer y = 188
integer width = 549
integer height = 300
integer taborder = 30
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
string text = "[全部]"
boolean sorted = false
string item[] = {"[全部]","待审核","已审核"}
borderstyle borderstyle = stylelowered!
end type

event selectionchanged;if index=1 then
	cur_flag=-1
elseif index=2 then
	cur_flag= 0 
elseif index=3 then
	cur_flag= 1	
end if

parent.triggerevent("retrieve_pageretr")
end event

type st_2 from statictext within w_mtrlware_trans
integer x = 1541
integer y = 208
integer width = 219
integer height = 48
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "状  态"
boolean focusrectangle = false
end type

type st_3 from statictext within w_mtrlware_trans
integer x = 791
integer y = 200
integer width = 219
integer height = 48
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "分　部"
boolean focusrectangle = false
end type

type ddlb_scid from uo_ddlb_scid within w_mtrlware_trans
integer x = 965
integer y = 188
integer width = 549
integer height = 1120
boolean bringtotop = true
end type

event constructor;call super::constructor;cur_scid=this.uo_scid
end event

event selectionchanged;call super::selectionchanged;cur_scid=this.uo_scid
parent.triggerevent("retrieve_pageretr")
end event