Q5/ws_objects/Ew_price.pbl.src/w_planprice_changed.srw

$PBExportHeader$w_planprice_changed.srw
forward
global type w_planprice_changed from w_publ_1ton_share_detail
end type
end forward

global type w_planprice_changed from w_publ_1ton_share_detail
integer height = 2520
string title = "产品计划价调整单"
boolean maxbox = true
windowstate windowstate = maximized!
event insert_childrow ( )
end type
global w_planprice_changed w_planprice_changed

type variables
long cur_flag = -1,flag
 
uo_changed_planprice uo_changed 
int cur_editfocus=0 //1:新建2:修改
end variables

forward prototypes
public function integer wf_refresh_curuc (long arg_billid)
public function integer wf_flagstatus_rf ()
end prototypes

event insert_childrow();long li_row
li_row=dw_child.insertrow(0)
dw_child.scrolltorow(li_row)
dw_child.SetColumn ('u_mtrldef_mtrlcode')	
end event

public function integer wf_refresh_curuc (long arg_billid);//====================================================================
// Function: wf_refresh_curuc(arg_scid,arg_inwareid)
//--------------------------------------------------------------------
// Description: 刷新dw_uc
//--------------------------------------------------------------------
// Arguments: 
//		value	long	arg_scid    		
//		value	long	arg_inwareid		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.14
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================
if arg_billid<=0 or isnull(arg_billid) then return 0
long uc_row
uc_row=dw_pageretr.getrow()
if uc_row<=0 then return 0

datetime billdate
string   billrep   
string   dscrp   
int      ll_flag   
string   billcode
datetime opdate   
string   opemp
string 	modemp
datetime moddate  
datetime Auditdate   
string   Auditemp

select u_planprice_changed.billcode,
		 u_planprice_changed.billdate,
		 u_planprice_changed.billrep,
		 u_planprice_changed.dscrp,
		 u_planprice_changed.opdate,
		 u_planprice_changed.opemp,
		 u_planprice_changed.modemp,
		 u_planprice_changed.moddate,
		 u_planprice_changed.flag,
		 u_planprice_changed.auditemp,
		 u_planprice_changed.auditdate
into   :billcode,
		 :billdate,
		 :billrep,
		 :dscrp,
		 :opdate,
		 :opemp,
		 :modemp,
		 :moddate,
		 :ll_flag,
		 :auditemp,
		 :auditdate
from   u_planprice_changed
 where  ( u_planprice_changed.billid = :arg_billid );
if sqlca.sqlcode<>0 then 
   messagebox('错误',"查询操作失败(错误单据唯一码)",stopsign!,ok!)
	return 0
end if

dw_pageretr.object.billcode[uc_row] = billcode
dw_pageretr.object.billdate[uc_row] = billdate
dw_pageretr.object.billrep[uc_row]  = billrep
dw_pageretr.object.dscrp[uc_row]    = dscrp
dw_pageretr.object.opdate[uc_row]   = opdate
dw_pageretr.object.opemp[uc_row]    = opemp
dw_pageretr.object.modemp[uc_row]   = modemp
dw_pageretr.object.moddate[uc_row]  = moddate
dw_pageretr.object.flag[uc_row]     = ll_flag
dw_pageretr.object.auditemp[uc_row] = auditemp
dw_pageretr.object.auditdate[uc_row]= auditdate
dw_pageretr.object.billid[uc_row]   = arg_billid


dw_pageretr.resetupdate()
dw_pageretr.setredraw(true)


dw_uc.Reset()
dw_pageretr.RowsCopy(dw_pageretr.GetRow(), dw_pageretr.GetRow(), Primary!, dw_uc, 1, Primary!)

dw_uc.ResetUpdate()
dw_uc.SetRedraw(TRUE)
wf_flagstatus_rf()
return 1
end function

public function integer wf_flagstatus_rf ();//====================================================================
// Function: wf_flagstatus_rf()
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments:(None)
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.12.26
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


long pagerert_row

pagerert_row=dw_pageretr.getrow()
if pagerert_row<=0 then	
	cb_auditing.enabled=false
	goto ext
end if

if dw_edit_mode then
	cb_auditing.enabled=false
	cb_auditing_cancel.enabled=false
else
	if dw_pageretr.object.flag[pagerert_row]=0 then
		cb_auditing.enabled=true
		cb_auditing_cancel.enabled=false
	elseif dw_pageretr.object.flag[pagerert_row]=1 then
		cb_auditing.enabled=false
		cb_auditing_cancel.enabled=true
	end if
end if

ext:
return 0
end function

on w_planprice_changed.create
call super::create
end on

on w_planprice_changed.destroy
call super::destroy
end on

event open;THIS.TriggerEvent('ue_before_open')
wf_movetocenter()

OLD_TITLE = THIS.Title

s_tran = Message.PowerObjectParm
IF NOT IsNull(s_tran) THEN
	retrieve_all = s_tran.if_retrieve_all
	mode = s_tran.work_mode
	arg_pkid = s_tran.arg_pkid
	arg_string_code = s_tran.arg_string_code
	if_sharedata = s_tran.if_sharedata //是否应用sharedata，当retrieve_all＝true是生效
	ds_share = s_tran.ds_share
END IF

dw_pageretr.RBUTTON_FILTER_USE = TRUE //右键查询功能开关
dw_pageretr.titleclick_sort_use = TRUE  //单击标题排序功能开关

dw_pageretr.SetTransObject (sqlca)
pkcolumndbtname = wf_get_pkcolumndbtname(dw_pageretr) //取第一列为关键字

ori_oldselect = dw_pageretr.Describe("DataWindow.Table.Select")
//====================================================================
// Script - w_outware_sale inherited from w_publ_1ton_share_detail for open 
// Reason: 
//--------------------------------------------------------------------
// Modified By: yyx		Date: 2003.12.01
//--------------------------------------------------------------------
//ori_oldselect = f_modify_selectstr(ori_oldselect)//只显示所管的仓库单据
//====================================================================

ls_newselect = ori_oldselect
ds_curquery = CREATE DATASTORE
ds_curquery.DataObject = 'd_extr_find'
ds_curquery.SetTransObject (sqlca)

wf_editindex_lockf()

sle_usual_query.Text = Trim(arg_string_code)
IF NOT retrieve_all THEN
	THIS.TriggerEvent("ue_usual_query_RETR") //修改ls_newselect,retrieve
ELSE
	IF  if_sharedata THEN
		ds_share.ShareData(dw_pageretr)
	ELSE
		wf_retrieveuc(dw_pageretr,ls_newselect,1)
		THIS.TriggerEvent('RETRIEVE_pageretr')
	END IF
END IF 

IF retrieve_all THEN
	THIS.TriggerEvent("ue_usual_query_filt")
END IF


uc_column_int = 4 //uc dw前7列可以编辑
child_column_int = 9 //子dw前8列可以编辑
uo_changed = CREATE uo_changed_planprice
uo_changed.commit_transaction = sqlca


end event

event ue_usual_query_filt;call super::ue_usual_query_filt;string obj_expr=''  
if trim(sle_usual_query.text)<>'' then 
	IF POS(trim(sle_usual_query.text),'%')=0 THEN
		obj_expr=obj_expr+'( billcode LIKE "%'+trim(sle_usual_query.text)+'%" )'
	ELSE
		obj_expr=obj_expr+'( billcode LIKE "'+trim(sle_usual_query.text)+'" )'
	END IF 
end if

dw_pageretr.setfilter(obj_expr)

dw_pageretr.SetRedraw(False)
dw_pageretr.filter()
if dw_pageretr.rowcount()>=1 then
	dw_pageretr.selectrow(0,false)
	dw_pageretr.selectrow(1,true)
end if
dw_pageretr.SetRedraw(TRUE)
end event

event ue_usual_query_retr;call super::ue_usual_query_retr;string ls_querystrpart=''
ls_newselect=lower(ori_oldselect)
if trim(sle_usual_query.text)<>'' then
	if pos(trim(sle_usual_query.text),'%')=0 then
		ls_querystrpart="(billcode like '%"+trim(sle_usual_query.text)+"%')"
	else
		ls_querystrpart="(billcode like '"+trim(sle_usual_query.text)+"')"
	end if

	if Pos(ls_newselect," where ") <> 0 then
	   ls_newselect=ls_newselect+" AND ("+ls_querystrpart+')'
	else
		ls_newselect=ls_newselect+" where ("+ls_querystrpart+')'
	end if
end if
wf_retrieveuc(dw_pageretr,ls_newselect,1)  
this.triggerevent('retrieve_pageretr')

end event

event retrieve_pageretr;Boolean cb_firstpage_enabled,cb_nextpage_enabled,cb_retrieveall_enabled
Boolean cb_priorpage_enabled,cb_func_enabled,cb_retrieve_enabled
 
cb_nextpage_enabled = cb_nextpage.Enabled
cb_retrieveall_enabled = cb_retrieveall.Enabled 
cb_func_enabled = cb_func.Enabled
 
cb_nextpage.Enabled = FALSE
cb_retrieveall.Enabled = FALSE 
cb_func.Enabled = FALSE

dw_pageretr.ShareDataOff()

dw_uc.Retrieve() //dw_uc的dw改左select top 0 并肯不带参数
dw_pageretr.Retrieve(cur_flag)
IF dw_pageretr.RowCount() > 0 THEN 
	dw_pageretr.SetRow(1)
	dw_pageretr.triggerevent(rowfocuschanged!)
end if
THIS.TriggerEvent('retrieve_childdw')
 
cb_nextpage.Enabled = cb_nextpage_enabled
cb_retrieveall.Enabled = cb_retrieveall_enabled 
cb_func.Enabled = cb_func_enabled
end event

event retrieve_childdw;call super::retrieve_childdw;long row,ll_billid
row=dw_pageretr.getrow()

if row>0 then	
	ll_billid=dw_pageretr.object.billid[row]
	dw_child.SetRedraw (false)
	dw_child.retrieve(ll_billid)
	dw_child.SetRedraw (true)
else
	dw_child.reset()
end if

end event

event ue_f8;call super::ue_f8;//用于选择明细内容,被f8[默认]\dw_child.doubleclicked调用
IF NOT dw_edit_mode THEN RETURN
Long child_row,ls_null
Long ins_storageid = 0
Long ls_sptid
Dec ls_lastprice,ls_rebate
Long chc = 1,ls_j
SetNull(ls_null)

s_edit_index_tran s_tranf8
s_tranf8.if_retrieve_all = FALSE
s_tranf8.arg_pkid = 0
s_tranf8.arg_string_code = ''
s_tranf8.b_long = -1

child_row = dw_child.GetRow()

IF NOT IsValid(w_mtrldef_edit) THEN
	s_edit_index_tran s_ch_tran
	s_ch_tran.if_retrieve_all = FALSE
	s_ch_tran.work_mode = 1
	s_ch_tran.arg_pkid = 0
	s_ch_tran.arg_string_code = ''
	s_ch_tran.b_long = -1
	s_ch_tran.c_long = ins_storageid
	s_ch_tran.if_select_all = TRUE
	
	dw_child.AcceptText()
	IF dw_child.GetRow() > 0 THEN s_ch_tran.arg_string_code = Trim(dw_child.Object.u_mtrldef_mtrlcode[dw_child.GetRow()])
	
	OpenWithParm(w_mtrldef_edit,s_ch_tran) //调用
	
	s_mtrldef_array s_inscust
	s_inscust = Message.PowerObjectParm //接受返回结构
	FOR ls_j = 1 TO  UpperBound(s_inscust.mtrlid)
		IF s_inscust.mtrlid[ls_j] > 0 THEN //正常返回值则可以取以下值
			
			IF dw_child.GetRow() > 0 THEN
				IF dw_child.Object.u_planprice_changedmx_mtrlid[child_row] <> 0 THEN
					child_row = dw_child.InsertRow (0)
				ELSE
					child_row = dw_child.GetRow()
				END IF
			ELSE
				child_row = dw_child.InsertRow (0)
			END IF
			
			dw_child.Object.u_mtrldef_mtrlcode[child_row]    = s_inscust.mtrlcode[ls_j]
			dw_child.Object.u_mtrldef_unit[child_row]        = s_inscust.unit[ls_j]
			dw_child.Object.u_planprice_changedmx_mtrlid[child_row]     = s_inscust.mtrlid[ls_j]
			dw_child.Object.u_mtrldef_mtrlname[child_row] = s_inscust.mtrlname[ls_j]
			dw_child.Object.u_mtrldef_mtrlmode[child_row] = s_inscust.mtrlmode[ls_j]
			dw_child.Object.u_mtrldef_zxmtrlmode[child_row] = s_inscust.zxmtrlmode[ls_j]
			dw_child.Object.u_mtrldef_mtrlsectype[child_row]  = s_inscust.mtrlsectype[ls_j]
			dw_child.Object.u_planprice_changedmx_lastprice[child_row] = s_inscust.planprice[ls_j]
			
			keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
			keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
		END IF
	NEXT
END IF

dw_child.SetRedraw(TRUE)
dw_child.SetFocus()





end event

event ue_addzy;call super::ue_addzy;IF Not f_power_ind(855)  THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF

IF dw_edit_mode THEN RETURN
String arg_msg = ''
String ls_str
Long uc_row
s_inputbox s_sreu

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,ok!)
	RETURN
END IF
s_sreu.Title = '请输入要补充到备注的内容'
s_sreu.old_text = ''
OpenWithParm(w_inputbox,s_sreu)
ls_str = Message.StringParm
IF Trim(ls_str) = '' OR IsNull(ls_str) THEN RETURN

IF uo_changed.add_dscrp(dw_pageretr.Object.billid[uc_row],ls_str,arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
	RETURN
ELSE
	MessageBox('提示','添加备注操作成功!',information!,ok!)
	wf_refresh_curuc(dw_pageretr.Object.billid[uc_row])
END IF


end event

event ue_viewprint;call super::ue_viewprint;IF Not f_power_ind(856)  THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF

s_print_msg ls_prmsg
ls_prmsg.retr_pram_falg = 16


IF dw_uc.RowCount() = 0 THEN
	MessageBox('提示','没有可打印的单据！',information!,ok!)
	RETURN
END IF

IF ls_newname <> '' THEN
	ls_prmsg.obj_dwNAME = ls_newname
ELSE
	ls_prmsg.obj_dwNAME = 'dw_rp_planprice_changed'
END IF

ls_prmsg.tag_text = '产品计划价调整单'
ls_prmsg.filter_string = ''
ls_prmsg.pagech_flag = 0
//ls_prmsg.retr_scid = dw_uc.Object.u_outware_scid[dw_uc.GetRow()]
ls_prmsg.retr_pramnmb = dw_pageretr.Object.billid[dw_pageretr.GetRow()]
ls_prmsg.rowcnt = dw_child.RowCount()

OpenWithParm(w_publ_preview,ls_prmsg)

//**更新打印次料
//String arg_msg
//printnum = Message.DoubleParm
//f_update_printnum('u_outware',printnum,dw_uc.Object.u_outware_scid[dw_uc.GetRow()],dw_uc.Object.u_outware_outwareid[dw_uc.GetRow()],'','',arg_msg,TRUE)

end event

event refresh_interface;call super::refresh_interface;IF sys_option_planprice_configure =  0 THEN
	dw_child.Modify('u_planprice_changedmx_status.Protect = 1')
	dw_child.Modify('u_planprice_changedmx_woodcode.Protect = 1')
	dw_child.Modify('u_planprice_changedmx_pcode.Protect = 1')
ELSE
	dw_child.Modify('u_planprice_changedmx_status.Protect = 0')
	dw_child.Modify('u_planprice_changedmx_woodcode.Protect = 0')
	dw_child.Modify('u_planprice_changedmx_pcode.Protect = 0')
END IF

end event

type cb_func from w_publ_1ton_share_detail`cb_func within w_planprice_changed
end type

type cb_exit from w_publ_1ton_share_detail`cb_exit within w_planprice_changed
integer x = 2368
end type

type sle_usual_query from w_publ_1ton_share_detail`sle_usual_query within w_planprice_changed
integer x = 197
integer y = 188
end type

type cb_retrieveall from w_publ_1ton_share_detail`cb_retrieveall within w_planprice_changed
integer x = 2816
end type

type em_pagerowno from w_publ_1ton_share_detail`em_pagerowno within w_planprice_changed
integer x = 2519
end type

type dw_pageretr from w_publ_1ton_share_detail`dw_pageretr within w_planprice_changed
integer x = 1751
integer y = 300
integer width = 1783
integer height = 856
string dataobject = "dw_planprice_changed_index"
end type

event dw_pageretr::rowfocuschanged;call super::rowfocuschanged;if currentrow <= 0 then return
wf_flagstatus_rf()

end event

type st_1 from w_publ_1ton_share_detail`st_1 within w_planprice_changed
integer x = 5
integer y = 208
end type

type cb_nextpage from w_publ_1ton_share_detail`cb_nextpage within w_planprice_changed
integer x = 2967
end type

type dw_uc from w_publ_1ton_share_detail`dw_uc within w_planprice_changed
integer y = 300
integer width = 1746
integer height = 856
string dataobject = "dw_planprice_changed_edit"
end type

event dw_uc::dwnkey;

parent.triggerevent('user_key')
if key = KeyDownArrow! then return 1
if dw_edit_mode then
	if dw_uc.GetColumnName ( )='dscrp'  and key = KeyEnter! then 
		dw_child.setfocus()
		dw_child.scrolltorow(1)
		dw_child.SetColumn ('u_mtrldef_mtrlcode')		
		return 1	
	else
		if  key = KeyEnter! Then //
			keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
			keybd_event ( 9, 0, 2, 0 ) // 释放tab 
			Return 1
		end If
	end if
end if

if keydown(KeyF4!)  then //read layout
//	uf_read_profile_filter()
//	uf_read_profile_sort()
	//uf_read_profile_layout()
elseif keydown(KeyF5!)  then //save layout 不含列显示
//	uf_save_profile_filter()
//	uf_save_profile_sort()
	//uf_save_profile_layout()
elseif keydown(KeyF9!)  then //reset layout 不含列显示
//	uf_reset_layout()

end if
	

end event

type gb_2 from w_publ_1ton_share_detail`gb_2 within w_planprice_changed
end type

type dw_child from w_publ_1ton_share_detail`dw_child within w_planprice_changed
integer y = 1160
integer height = 1264
string dataobject = "dw_planprice_changedmx_edit"
end type

event dw_child::dwnkey;call super::dwnkey;PARENT.TriggerEvent('user_key')

String ls_mtrlcode,ls_mtrlname,ls_unit,ls_mtrlmode,ls_prdpackcode,ls_mtrlsectype,ls_zxmtrlmode
Long ls_mtrlid,ls_orderid,ls_storageid
String ls_order_relcode
Decimal ls_planprice,ls_packqty,ls_nofinishqty

s_mtrldef_array arg_s_mtrldef

Long child_row
Long ls_null
SetNull(ls_null)



IF dw_edit_mode THEN
	dw_uc.AcceptText()

	IF KeyDown(keydownarrow!) THEN
		Long li_row
		IF dw_child.GetRow() = dw_child.RowCount() THEN
			PARENT.TriggerEvent("insert_childrow")
		END IF
	ELSE
		IF KeyDown(keyenter!) AND NOT KeyDown(keycontrol!) AND NOT KeyDown(keyshift!)  THEN
			IF dw_child.GetColumnName() = 'u_mtrldef_mtrlcode' THEN
				dw_child.AcceptText()
				child_row = dw_child.GetRow()
				
				ls_mtrlcode = dw_child.Object.u_mtrldef_mtrlcode[child_row]
				
				IF f_find_mtrl(ls_mtrlcode,-1,arg_s_mtrldef) = 0 THEN
					PARENT.TriggerEvent('ue_f8')
					RETURN 1
				ELSE
					ls_mtrlid = arg_s_mtrldef.mtrlid[1]
					ls_mtrlcode = arg_s_mtrldef.mtrlcode[1]
					ls_mtrlname = arg_s_mtrldef.mtrlname[1]
					ls_unit = arg_s_mtrldef.unit[1]
					ls_mtrlmode = arg_s_mtrldef.mtrlmode[1]
					ls_planprice = arg_s_mtrldef.planprice[1]
					ls_mtrlsectype=arg_s_mtrldef.mtrlsectype[1]
					ls_zxmtrlmode=arg_s_mtrldef.zxmtrlmode[1]
					ls_mtrlsectype=arg_s_mtrldef.mtrlsectype[1]
					ls_zxmtrlmode=arg_s_mtrldef.zxmtrlmode[1] 
				END IF
				
				dw_child.Object.u_planprice_changedmx_mtrlid[child_row]    = ls_mtrlid
				dw_child.Object.u_mtrldef_mtrlname[child_row]   = ls_mtrlname
				dw_child.Object.u_mtrldef_mtrlmode[child_row]   = ls_mtrlmode
				dw_child.Object.u_mtrldef_unit[child_row]       = ls_unit 
				dw_child.Object.u_mtrldef_mtrlcode[child_row]  = ls_mtrlcode
				dw_child.Object.u_mtrldef_zxmtrlmode[child_row] = ls_zxmtrlmode
				dw_child.Object.u_mtrldef_mtrlsectype[child_row]  = ls_mtrlsectype
				dw_child.Object.u_planprice_changedmx_lastprice[child_row] = ls_planprice
				IF Key = keyenter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF
			
			ELSEIF dw_child.GetColumnName( ) = 'u_planprice_changedmx_mxdscrp'  AND dw_child.GetRow() = dw_child.RowCount() THEN
				PARENT.TriggerEvent("insert_childrow")
				RETURN 1
	
			ELSE
				IF Key = keyenter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF
			END IF
		END IF
	END IF
END IF
















end event

type cb_viewprint from w_publ_1ton_share_detail`cb_viewprint within w_planprice_changed
end type

type cb_print from w_publ_1ton_share_detail`cb_print within w_planprice_changed
end type

type cb_add from w_publ_1ton_share_detail`cb_add within w_planprice_changed
end type

event cb_add::clicked;IF Not f_power_ind(852)  THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF
 
String arg_msg = ''
Long uc_row,pagerert_row
Long relid_pageretr,reld_uc,j,i
Long ll_printid,ll_scid
Int li_flag,li_secflag,li_priceflag 
long ll_billid

IF dw_edit_mode THEN
	dw_uc.AcceptText()
	dw_child.AcceptText()
	uc_row = dw_uc.GetRow()
	IF uc_row <= 0 THEN
		MessageBox('提示','请选定当前目标单据!',information!,ok!)
		RETURN
	END IF
	
	IF NOT dw_uc.Object.billdate[uc_row] > DateTime(2000-01-01,Now()) THEN
		MessageBox('提示','不合理发生时间',information!,ok!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("billdate")
		RETURN
	END IF
	
	IF trim(dw_uc.Object.billrep[uc_row]) = '' THEN
		MessageBox('提示','请填写经手人',information!,ok!)
		dw_uc.SetFocus()
		dw_uc.SetColumn("billrep")
		RETURN
	END IF
	
	uo_changed.billdate = dw_uc.Object.billdate[uc_row]
	uo_changed.billrep = dw_uc.Object.billrep[uc_row]
	uo_changed.dscrp = dw_uc.Object.dscrp[uc_row]
	
	FOR i = 1 TO dw_child.RowCount()
		IF dw_child.Object.u_planprice_changedmx_mtrlid[i] > 0 THEN
			IF uo_changed.acceptmx(dw_child.Object.u_planprice_changedmx_mtrlid[i],&
				dw_child.Object.u_planprice_changedmx_lastprice[i],&
				dw_child.Object.u_planprice_changedmx_planprice[i],&
				dw_child.Object.u_planprice_changedmx_reason[i],&
				dw_child.Object.u_planprice_changedmx_mxdscrp[i],&
				arg_msg,&
				dw_child.Object.u_planprice_changedmx_status[i],&
				dw_child.Object.u_planprice_changedmx_woodcode[i],&
				dw_child.Object.u_planprice_changedmx_pcode[i],&
				dw_child.Object.row[i]) = 0 THEN
				MessageBox('错误',arg_msg,stopsign!,ok!)
				RETURN
			END IF
		END IF
	NEXT
	
	IF uo_changed.Save(TRUE,arg_msg) = 0 THEN
		MessageBox('错误',arg_msg,stopsign!,ok!)
		RETURN
	END IF
	MessageBox('提示','保存操作成功!',information!,ok!)

	long ll_row
	ll_row = dw_pageretr.getrow()
	dw_pageretr.SelectRow(0,FALSE)
	dw_pageretr.SelectRow(ll_row,TRUE)
	wf_refresh_curuc(uo_changed.billid) //刷新uc	
ELSE
	IF uo_changed.newbegin(arg_msg) = 0 THEN
		MessageBox('错误',arg_msg,stopsign!,ok!)
		RETURN
	END IF
	
	cur_editfocus = 1
	flag = -1
END IF

CALL SUPER::Clicked

IF dw_edit_mode THEN
	PARENT.TriggerEvent("insert_childrow")
	dw_uc.SetRedraw(FALSE)
	dw_uc.SetColumn("billdate")
	dw_uc.SetRedraw(TRUE)
ELSE
	PARENT.TriggerEvent("retrieve_childdw")
END IF





end event

type cb_edit from w_publ_1ton_share_detail`cb_edit within w_planprice_changed
end type

event cb_edit::clicked;IF Not f_power_ind(852)  THEN
	messagebox('提示','你没有使用权限！',information!,ok!)
	return
end if

string arg_msg=''
long uc_row

uc_row=dw_pageretr.getrow()
if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!',information!,ok!)
	return
end if

if not dw_edit_mode then
	if uo_changed.updatebegin(dw_pageretr.object.billid[uc_row],arg_msg)=0 then
		messagebox('错误',arg_msg,information!,ok!)
		return
	end if
	cur_editfocus=2
else
	cur_editfocus=0
end if

call super::clicked
this.triggerevent('refresh_interface')
end event

type cb_delet from w_publ_1ton_share_detail`cb_delet within w_planprice_changed
end type

event cb_delet::clicked;call super::clicked;IF Not f_power_ind(853)  THEN
	messagebox('提示','你没有使用权限！',information!,ok!)
	return
end if


string arg_msg=''

if dw_edit_mode then return

long uc_row
uc_row=dw_pageretr.getrow()
if uc_row<=0 then
	messagebox('提示','请选定当前目标单据!',information!,ok!)
	return
end if

if messagebox ("询问","是否确定要删除当前单据?",question!,yesno! ) = 2 then return

if uo_changed.del(dw_pageretr.object.billid[uc_row],true,arg_msg)=0 then
	messagebox('错误',arg_msg,stopsign!,ok!)
else
	//日志
	long ls_id
	string ls_code
	ls_id=dw_pageretr.object.billid[uc_row]
	ls_code=dw_pageretr.object.billcode[uc_row]
	f_setsysoplog('计划价调整单','删除,id:'+string(ls_id)+',code:'+ls_code,arg_msg,true)
	//--
	messagebox('提示','删除单据'+ls_code+'成功!',information!,ok!)

	
	dw_pageretr.deleterow(uc_row)
	dw_pageretr.postevent(rowfocuschanged!)
end if
end event

type cb_addzy from w_publ_1ton_share_detail`cb_addzy within w_planprice_changed
integer x = 1029
end type

event cb_addzy::clicked;call super::clicked;m_Dfc_Control_PopupMenu dmPopupMenu
string menustr


menustr="Text=增加备注~tEvent=ue_addzy"

if len(trim(menustr))<>0 then
	dmPopupMenu = Create m_Dfc_Control_PopupMenu
	dmPopupMenu.mf_BuildMenu(This, menustr)
	dmPopupMenu.mf_PopMenu()
	Destroy dmPopupMenu
end if
end event

type cb_auditing from w_publ_1ton_share_detail`cb_auditing within w_planprice_changed
end type

event cb_auditing::clicked;call super::clicked;IF dw_edit_mode THEN RETURN

String arg_msg = '',ls_code
Long pagerert_row,ls_id
	
pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	MessageBox('提示','请选定当前目标单据!',information!,ok!)
	RETURN
END IF

IF Not f_power_ind(854)  THEN
	MessageBox('提示','你没有使用权限！',information!,ok!)
	RETURN
END IF

IF MessageBox ("询问","是否确定要"+THIS.Text+"当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN
		
IF uo_changed.getinfo(dw_pageretr.Object.billid[pagerert_row],arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
	RETURN
END IF

IF uo_changed.auditing(TRUE,arg_msg) = 0 THEN
	MessageBox('错误',arg_msg,stopsign!,ok!)
ELSE
	MessageBox('提示','单据审核成功!',information!,ok!)
	wf_refresh_curuc(dw_pageretr.Object.billid[pagerert_row])
	cb_auditing.enabled = false
END IF
end event

type cb_xm from w_publ_1ton_share_detail`cb_xm within w_planprice_changed
integer x = 1280
end type

type cb_retrieve from w_publ_1ton_share_detail`cb_retrieve within w_planprice_changed
end type

type cb_xls from w_publ_1ton_share_detail`cb_xls within w_planprice_changed
end type

type cb_help from w_publ_1ton_share_detail`cb_help within w_planprice_changed
integer x = 1531
end type

type cb_auditing_cancel from w_publ_1ton_share_detail`cb_auditing_cancel within w_planprice_changed
boolean visible = false
end type

type p_msg from w_publ_1ton_share_detail`p_msg within w_planprice_changed
end type

type p_help from w_publ_1ton_share_detail`p_help within w_planprice_changed
end type

type p_encl from w_publ_1ton_share_detail`p_encl within w_planprice_changed
end type

type p_other from w_publ_1ton_share_detail`p_other within w_planprice_changed
end type

type gb_3 from w_publ_1ton_share_detail`gb_3 within w_planprice_changed
end type

type ln_bar from w_publ_1ton_share_detail`ln_bar within w_planprice_changed
end type

type ln_bar2 from w_publ_1ton_share_detail`ln_bar2 within w_planprice_changed
end type

type r_bar from w_publ_1ton_share_detail`r_bar within w_planprice_changed
end type

type ln_1 from w_publ_1ton_share_detail`ln_1 within w_planprice_changed
integer endx = 3296
end type

type ln_2 from w_publ_1ton_share_detail`ln_2 within w_planprice_changed
integer endx = 3232
end type