Q5/ws_objects/Ew_gz.pbl.src/uo_loanwage.sru

$PBExportHeader$uo_loanwage.sru
forward
global type uo_loanwage from nonvisualobject
end type
end forward

global type uo_loanwage from nonvisualobject
end type
global uo_loanwage uo_loanwage

type variables
public protectedwrite long billid           //计件单自动增量id
public protectedwrite string billcode       //计件单的唯一编号
public protectedwrite long wagemth          //工资月份
public protectedwrite datetime opdate       //建立时间,自动
public protectedwrite string opemp          //建立人
public protectedwrite datetime moddate       //修改时间,自动
public protectedwrite string modemp          //修改人
public protectedwrite int flag=0            //审核标志
public protectedwrite datetime auditingdate //审核时间
public protectedwrite string auditingrep    //审核操作员

long empid          //人员ID
datetime billdate   //计件日期
decimal loanamt     //金额
long wageid         //工资项目id
string loanreason   //原因
string cardcode     //证件号     
string dscrp=''     //备注
long returndate   //还款日

 Int cwauditingflag = 0           //总账审核标记 
 DateTime cwauditingdate          //总账审核时间
 String cwauditingrep            //总账审核操作员



uo_wage u_wage

private:
boolean it_newbegin=false    //新建标志
boolean it_updatebegin=false//修改标志

end variables

forward prototypes
public function integer p_reset ()
public function integer newbegin (ref string arg_msg)
public function integer updatebegin (long arg_billid, ref string arg_msg)
public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer save (ref string arg_msg, boolean arg_ifcommit)
public function integer del (long arg_billid, ref string arg_msg)
public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg)
public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg)
public function integer c_audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg)
end prototypes

public function integer p_reset ();//INT p_RESET()
//清除对象及其明细
billid=0
billcode=''
opemp=''
auditingrep=''
flag=0
empid=0  
loanamt=0      
loanreason=''
wageid=0    
returndate=0
dscrp=''    
cardcode=''


it_newbegin=FALSE
it_updatebegin=FALSE
RETURN 1
end function

public function integer newbegin (ref string arg_msg);p_reset()
it_newbegin=TRUE
it_updatebegin=FALSE
return 1

end function

public function integer updatebegin (long arg_billid, ref string arg_msg);//====================================================================
// Function: updatebegin(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


int rslt = 1

if arg_billid <= 0 then
	billid = 0
	arg_msg = '错误的单据ID'
	goto ext
end if

select
u_gz_loanwage.billcode,
u_gz_loanwage.billdate,
u_gz_loanwage.wagemth,
u_gz_loanwage.wageid,
u_gz_loanwage.empid,
u_gz_loanwage.loanamt,
u_gz_loanwage.loanreason,
u_gz_loanwage.cardcode,
u_gz_loanwage.returndate,
u_gz_loanwage.dscrp,
u_gz_loanwage.flag

into
:billcode,
:billdate,
:wagemth,
:wageid,
:empid,
:loanamt,
:loanreason,
:cardcode,
:returndate,
:dscrp,
:flag
from u_gz_loanwage where u_gz_loanwage.billid = :arg_billid;
if sqlca.sqlcode <> 0 then
	rslt = 0
	if pos(lower(sqlca.SQLErrText),'more than') > 0 then
		arg_msg = '查询操作失败,查询数据返回值多于一个'
	else
		arg_msg = '查询数据操作失败(错误单据唯一码)'
	end if
	goto ext
end if

if flag = 1 then
	rslt = 0
	arg_msg = '单据已经审核,不可以修改'
	goto ext
end if

billid = arg_billid

it_newbegin = false
it_updatebegin = true

ext:
if  rslt = 0 then p_reset()
arg_msg = '借支单,'+ arg_msg
return rslt


end function

public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);
long cnt=0,i
int rslt=1
datetime null_server_dt
setnull(null_server_dt)

select count(*) into :cnt
from u_gz_loanwage 
where wagemth=:arg_wagemth
and wageid = :arg_wageid
and flag = 1;
if sqlca.sqlcode<>0 then
	rslt=0
	arg_msg='查询借支单失败'
	goto ext
end if

if cnt=0 then 
	rslt=0
	arg_msg='该月的借支单未审核,不用撤审!'
	goto ext
end if

select count(*) into :cnt from u_gz_wage
where  wagemth=:arg_wagemth and Auditingflag=1;
if sqlca.sqlcode<>0 then
	rslt=0
	arg_msg='查询工资表失败'
	goto ext
end if

if cnt>0 then 
	rslt=0
	arg_msg='该月的工资表已审核,不能撤审!'
	goto ext
end if

cnt=0
select  count(*) into :cnt from u_gz_wageitem where useflag=1 and wageid=:arg_wageid;
if sqlca.sqlcode<>0 then
	rslt=0
	arg_msg='查询工资项目失败'
	goto ext
end if 

if cnt=0 then
	rslt=0
	arg_msg='不存在该工资项目'
	goto ext
end if

SELECT flag,cwauditingflag Into :flag,:cwauditingflag From u_gz_loanwage where wagemth=:arg_wagemth
and wageid = :arg_wageid;



IF cwauditingflag = 1 THEN
	rslt = 0
	arg_msg = "单据已经总账审核，不能撤审！"
	GOTO ext
END IF





update u_gz_loanwage set 
	flag=0,
	Auditrep='',
	Auditdate=:null_server_dt,
	wagemth=0
where  wagemth=:arg_wagemth and flag=1 and  wageid=:arg_wageid;
if sqlca.sqlcode<>0 then
	ARG_msg='更新借支单失败，原因：'+sqlca.sqlerrtext
	rslt=0
	goto ext
end if	

update u_gz_wagemx set wageamt=0 where wageid=:arg_wageid and wagemth=:arg_wagemth;
if sqlca.sqlcode<>0 then
	rslt=0
	arg_Msg='更新工资表失败！原因：'+sqlca.sqlerrtext
	goto ext
end if 
	

ext:
if rslt=0 then
	rollback;
elseif  rslt=1 and arg_ifcommit then
	commit;
end if
arg_msg = '借支单,'+ arg_msg
return rslt
end function

public function integer save (ref string arg_msg, boolean arg_ifcommit);//====================================================================
// Function: save(arg_msg,arg_ifcommit)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		reference	string 	arg_msg     		
//		value    	boolean	arg_ifcommit		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


integer rslt = 1,cnt = 0,i
datetime server_dt
long ls_newid

if isnull(empid)	 then empid = 0
if isnull(loanamt)	 then loanamt = 0
if isnull(wageid)	 then wageid = 0
if isnull(loanreason)	 then loanreason = ''
if isnull(cardcode)	 then cardcode = ''
if isnull(dscrp)	 then dscrp = ''
if isnull(returndate)	 then returndate = 0


if it_newbegin = false and it_updatebegin = false then
	rslt = 0
	arg_msg = "非编辑状态不可以提交"
	goto ext
end if

select count(*) into :cnt
from u_rs_empinfo
where empid = :empid;
if sqlca.sqlcode <> 0 then
	arg_msg = '查询人员资料失败'
	rslt = 0
	goto ext
end if

if cnt = 0  then
	arg_msg = '人员资料不存在'
	rslt = 0
	goto ext
end if

cnt = 0
select count(*) into :cnt
from u_gz_wageitem
where wageid = :wageid;
if sqlca.sqlcode <> 0 then
	arg_msg = '查询工资项目资料失败'
	rslt = 0
	goto ext
end if

if cnt > 1 then
	arg_msg = '工资项目重复'
	rslt = 0
	goto ext
end if

if loanamt <= 0 then 
	arg_msg = '请输入正确的借款金额'
	rslt = 0
	goto ext
end if

select top 1 getdate() into :server_dt from u_user;
//取得系统时间,借用操作员表
if sqlca.sqlcode <> 0 then
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	goto ext
end if

if year(date(billdate)) < 2000 or isnull(billdate) then
	rslt = 0
	arg_msg = "时间不合理"
	goto ext
end if

if returndate <= 0 then
	rslt = 0 
	arg_msg = '还款月份输入错误'
	goto ext
end if

////////////////////////////////////////////////开始区分:新建/更新 处理
if billid = 0 then //新建
	ls_newid = f_sys_scidentity(0,"u_gz_loanwage","billid",arg_msg,true,sqlca)
	if ls_newid <= 0 then
		rslt = 0
		goto ext
	end if
	
	
	billcode = getid(0,"JZ",date(server_dt),true,sqlca) //取得新单据编号
	if billcode = "err" then
		billcode = ''
		rslt = 0
		arg_msg = "无法获取借支单编号"
		goto ext
	end if
	
	insert into u_gz_loanwage (
		billid,
		billcode,
		billdate,
		Wagemth,
		wageid,
		empid,
		loanamt,
		loanreason,
		cardcode,
		returndate,
		dscrp,
		opdate,
		opemp)
		values ( 
		:ls_newid,
		:billcode,
		:billdate,
		:Wagemth,
		:wageid,
		:empid,
		:loanamt,
		:loanreason,
		:cardcode,
		:returndate,
		:dscrp,
		:server_dt,
		:publ_operator);
	if sqlca.sqlcode <> 0 then
		rslt = 0
		if pos(lower(sqlca.SQLErrText),'pk_u_gz_loanwage') > 0 then
			arg_msg = '插入操作失败,关键字单据ID重复'
		elseif pos(lower(sqlca.SQLErrText),'ix_u_gz_loanwage') > 0 then
			arg_msg = '插入操作失败,单据编号重复'
		else
			arg_msg = "因网络或其它原因导致插入操作失败>>"+"~n"+sqlca.sqlerrtext
		end if
		goto ext
	end if	
	billid = ls_newid	
else //////////////////////////////////////////////////更新
	
	update u_gz_loanwage
		set billdate = :billdate,
		wageid = :wageid,
		empid = :empid,
		loanamt = :loanamt,
		loanreason = :loanreason,
		cardcode = :cardcode,
		returndate = :returndate,
		moddate = :server_dt,
		modemp = :modemp,
		dscrp = :dscrp
		where u_gz_loanwage.billid = :billid
		  and flag = 0;
	if sqlca.sqlcode <> 0 or sqlca.sqlnrows <= 0 then
		rslt = 0
		if pos(lower(sqlca.SQLErrText),'pk_u_gz_loanwage') > 0 then
			arg_msg = '插入操作失败,关键字单据ID重复'
		elseif pos(lower(sqlca.SQLErrText),'ix_u_gz_loanwage') > 0 then
			arg_msg = '插入操作失败,单据编号重复'
		else
			arg_msg = "因网络或其它原因导致插入操作失败>>"+"~n"+sqlca.sqlerrtext
		end if
		goto ext
	end if
	
	
end if

it_newbegin = false
it_updatebegin = false

ext:
if rslt = 0 then
	rollback;
elseif rslt=1 and arg_ifcommit then
	commit;
end if
arg_msg = '借支单,'+ arg_msg
return(rslt)


end function

public function integer del (long arg_billid, ref string arg_msg);//====================================================================
// Function: del(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================

int rslt = 1
if arg_billid <= 0 then
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	goto ext
end if

if it_newbegin or it_updatebegin then
	rslt=0
   arg_msg="编辑状态下不可以执行,操作取消"
	goto ext
end if

select u_gz_loanwage.flag
	into :flag
	from u_gz_loanwage
	where u_gz_loanwage.billid = :arg_billid;
if sqlca.sqlcode <> 0  then
	rslt = 0
	arg_msg = '查询借支单操作失败'
	goto ext
end if

if flag = 1 then
	rslt = 0
	arg_msg = "单据已经审核,不可以删除"
	goto ext
end if

delete from u_gz_loanwage where u_gz_loanwage.billid = :arg_billid;
if sqlca.sqlcode <> 0 then
	rslt = 0
	arg_msg = "删除借支单操作失败"+"~n"+sqlca.sqlerrtext
	goto ext
end if

commit;
it_newbegin = false
it_updatebegin = false
ext:
if rslt = 0 then 
	rollback;
	p_reset()
end if

arg_msg = '借支单,'+ arg_msg
return (rslt)

end function

public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg);//====================================================================
// Function: add_dscrp(arg_billid,arg_newdescppart,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid      		
//		value    	string	arg_newdescppart		
//		reference	string	arg_msg         		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


int rslt = 1
arg_newdescppart = trim(arg_newdescppart)

if arg_billid <= 0 then
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	goto ext
end if

if it_newbegin or it_updatebegin then
	rslt=0
   arg_msg="编辑状态下不可以执行,操作取消"
	goto ext
end if

select u_gz_loanwage.flag
	into :flag
	from u_gz_loanwage
	where u_gz_loanwage.billid = :arg_billid;
if sqlca.sqlcode <> 0  then
	rslt = 0
	if pos(lower(sqlca.SQLErrText),'more than') > 0 then
		arg_msg = '查询操作失败,查询数据返回值多于一个'
	else
		arg_msg = '查询借支单操作失败(错误单据唯一码)'
	end if
	goto ext
end if

if flag = 0 then
	rslt = 0
	arg_msg = "非审核状态下不可用"
	goto ext
end if

update u_gz_loanwage
	set dscrp = dscrp+' '+:arg_newdescppart
	where u_gz_loanwage.billid = :billid;
if sqlca.sqlcode <> 0 then
	rollback ;
	rslt = 0
	arg_msg = "因网络或其它原因导致添加单据备注操作失败"+"~n"+sqlca.sqlerrtext
	goto ext
end if

commit;
dscrp = dscrp+' '+arg_newdescppart

ext:
arg_msg = '借支单,'+ arg_msg
return (rslt)

end function

public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);//====================================================================
// Function: auditing()
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long    	arg_wageid  		
//		value    	long    	arg_wagemth 		
//		value    	datetime	arg_enddate 		
//		reference	string  	arg_msg     		
//		value    	boolean 	arg_ifcommit		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2004.10.19
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================



long cnt=0,i
int rslt=1
decimal ls_emp_sumwage
datastore ds_emp_sumloanwage

cnt=0
select count(*) into :cnt
from u_gz_loanwage
where  wagemth=:arg_wagemth 
and wageid = :arg_wageid
and flag=1;
if sqlca.sqlcode<>0 then
	rslt=0
	arg_msg='查询借支单明细失败！'
	goto ext
end if

if cnt>0 then 
	rslt=0
	arg_msg='该月的借支单已审核,审核前请先执行撤审!'
	goto ext
end if

cnt=0
select  count(*) into :cnt 
from u_gz_wageitem where useflag=1 and wageid=:arg_wageid;
if sqlca.sqlcode<>0 then
	rslt=0
	arg_msg='查询工资项目失败!'
	goto ext
end if 

if cnt=0 then
	rslt=0
	arg_msg='不存在该工资项目!'
	goto ext
end if

ds_emp_sumloanwage=create datastore
ds_emp_sumloanwage.dataobject='dw_emp_sumloanwage'
ds_emp_sumloanwage.settransobject(sqlca)

if ds_emp_sumloanwage.retrieve(arg_wagemth,arg_wageid)<=0 then 
	rslt=0
	arg_msg='本月没有借支单可审核或查询借支单失败'
	goto ext
end if

for i= 1 to ds_emp_sumloanwage.rowcount() 	
	ls_emp_sumwage=0.00
	ls_emp_sumwage=ds_emp_sumloanwage.object.sumwage[i]
	if u_wage.f_setwagemxdata(arg_wagemth,ds_emp_sumloanwage.object.empid[i],arg_wageid,ls_emp_sumwage,arg_msg,false)=0 then 
		rslt=0		
		goto ext
	end if		
next

update u_gz_loanwage set 
	flag=1,
	auditrep=:publ_operator,
	Auditdate=getdate(),
	wagemth=:arg_wagemth
where returndate = :arg_wagemth  and
  wageid = :arg_wageid and 
 flag = 0;
if sqlca.sqlcode<>0 then
	ARG_msg='更新借支单失败,原因>>'+sqlca.sqlerrtext
	rslt=0
	goto ext
end if
	
ext:
if rslt=0 then
	rollback;
elseif rslt=1 and arg_ifcommit then
	commit;
end if
arg_msg = '借支单,'+ arg_msg
return rslt
end function

public function integer audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg);
Int rslt = 1,cnt = 0

IF arg_billid = 0 THEN
	rslt = 0
	arg_msg = "没有审核对象"
	GOTO ext
END IF


//IF p_getinfo(arg_scid,arg_billid,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
SELECT flag,cwauditingflag Into :flag,:cwauditingflag From u_gz_loanwage Where billid = :arg_billid;



IF flag = 0  THEN
	rslt = 0
	arg_msg = "单据没有审核"
	GOTO ext
END IF




IF cwauditingflag = 1 THEN
	rslt = 0
	arg_msg = "单据已经总账审核"
	GOTO ext
END IF



UPDATE u_gz_loanwage
	SET cwauditingflag = 1,
	cwauditingdate = getdate(),
	cwauditingrep = :publ_operator
	WHERE ( u_gz_loanwage.billid = :arg_billid )  Using sqlca;
	
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "因网络或其它原因导致总账审核操作失败"+"~n"+sqlca.SQLErrText
	ROLLBACK Using sqlca;
	GOTO ext
END IF

ext:
IF arg_ifcommit And rslt = 1 THEN
	COMMIT Using sqlca;
END IF

Return (rslt)







end function

public function integer c_audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg);
Int rslt = 1,cnt = 0

IF arg_billid = 0 THEN
	rslt = 0
	arg_msg = "没有审核对象"
	GOTO ext
END IF


//IF p_getinfo(arg_scid,arg_billid,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
SELECT flag,cwauditingflag Into :flag,:cwauditingflag From u_gz_loanwage Where billid = :arg_billid;



IF cwauditingflag = 0 THEN
	rslt = 0
	arg_msg = "单据没有总账审核"
	GOTO ext
END IF



UPDATE u_gz_loanwage
	SET cwauditingflag = 0,
	cwauditingdate =null,
	cwauditingrep = ''
	WHERE ( u_gz_loanwage.billid = :arg_billid )  Using sqlca;
	
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "因网络或其它原因导致总账撤审操作失败"+"~n"+sqlca.SQLErrText
	ROLLBACK Using sqlca;
	GOTO ext
END IF

ext:
IF arg_ifcommit And rslt = 1 THEN
	COMMIT Using sqlca;
END IF

Return (rslt)



end function

on uo_loanwage.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_loanwage.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

event constructor; u_wage=create uo_wage
end event

event destructor;DESTROY u_wage
end event