Q5/ws_objects/Ew_gz.pbl.src/uo_award_punish.sru

$PBExportHeader$uo_award_punish.sru
forward
global type uo_award_punish from nonvisualobject
end type
end forward

global type uo_award_punish from nonvisualobject
end type
global uo_award_punish uo_award_punish

type variables
public protectedwrite long billid           //计件单自动增量id
public protectedwrite string billcode       //计件单的唯一编号
public protectedwrite datetime opdate       //建立时间,自动
public protectedwrite string opemp          //建立人
public protectedwrite datetime moddate       //修改时间,自动
public protectedwrite string modemp          //修改人
public protectedwrite int flag=0            //审核标志
public protectedwrite datetime auditingdate //审核时间
public protectedwrite string auditingrep    //审核操作员

int billtype
long empid          
datetime billdate  
decimal award_punish_amt     
long wageid         
string reason   
long deptid        
string rep='' 
long wagemth
string dealtype

 Int cwauditingflag = 0           //总账审核标记 
 DateTime cwauditingdate          //总账审核时间
 String cwauditingrep            //总账审核操作员




uo_wage u_wage

private:
boolean it_newbegin=false    //新建标志
boolean it_updatebegin=false//修改标志

end variables

forward prototypes
public function integer p_reset ()
public function integer newbegin (ref string arg_msg)
public function integer updatebegin (long arg_billid, ref string arg_msg)
public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer save (ref string arg_msg, boolean arg_ifcommit)
public function integer del (long arg_billid, ref string arg_msg)
public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit)
public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg)
public function integer audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg)
public function integer c_audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg)
end prototypes

public function integer p_reset ();//INT p_RESET()
//清除对象及其明细
billtype = 0
billid=0
billcode=''
opemp=''
auditingrep=''
flag=0
empid=0  
award_punish_amt=0      
reason=''
wageid=0    
rep=''    
deptid=0


it_newbegin=FALSE
it_updatebegin=FALSE
RETURN 1
end function

public function integer newbegin (ref string arg_msg);p_reset()
it_newbegin=TRUE
it_updatebegin=FALSE
return 1

end function

public function integer updatebegin (long arg_billid, ref string arg_msg);//====================================================================
// Function: updatebegin(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


int rslt = 1

if arg_billid <= 0 then
	billid = 0
	arg_msg = '错误的单据ID'
	goto ext
end if

select
u_gz_award_punish.billcode,
u_gz_award_punish.billdate,
u_gz_award_punish.wagemth,
u_gz_award_punish.wageid,
u_gz_award_punish.empid,
u_gz_award_punish.award_punish_amt,
u_gz_award_punish.reason,
u_gz_award_punish.deptid,
u_gz_award_punish.rep,
u_gz_award_punish.billtype,
u_gz_award_punish.flag

into
:billcode,
:billdate,
:wagemth,
:wageid,
:empid,
:award_punish_amt,
:reason,
:deptid,
:rep,
:billtype,
:flag
from u_gz_award_punish where u_gz_award_punish.billid = :arg_billid;
if sqlca.sqlcode <> 0 then
	rslt = 0
	if pos(lower(sqlca.SQLErrText),'more than') > 0 then
		arg_msg = '查询操作失败,查询数据返回值多于一个'
	else
		arg_msg = '查询数据操作失败(错误单据唯一码)'
	end if
	goto ext
end if

if flag = 1 then
	rslt = 0
	arg_msg = '单据已经审核,不可以修改'
	goto ext
end if

billid = arg_billid

it_newbegin = false
it_updatebegin = true

ext:
if  rslt = 0 then p_reset()
arg_msg = '奖罚单,'+ arg_msg
return rslt


end function

public function integer c_auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);Long cnt = 0,i
Int rslt = 1
DateTime null_server_dt
SetNull(null_server_dt)

SELECT count(*) INTO :cnt
	FROM u_gz_award_punish
	WHERE wagemth = :arg_wagemth
	AND wageid = :arg_wageid
	AND flag = 1;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询奖罚单失败'
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '该月的奖罚单未审核,不用撤审!'
	GOTO ext
END IF

SELECT count(*) INTO :cnt FROM u_gz_wage
	Where  wagemth = :arg_wagemth AND Auditingflag = 1;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资表失败'
	GOTO ext
END IF


IF cnt > 0 THEN
	rslt = 0
	arg_msg = '该月的工资表已审核,不能撤审!'
	GOTO ext
END IF

cnt = 0
SELECT  count(*) INTO :cnt FROM u_gz_wageitem Where useflag = 1 AND wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败'
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目'
	GOTO ext
END IF

SELECT flag,cwauditingflag Into :flag,:cwauditingflag From u_gz_award_punish WHERE wagemth = :arg_wagemth
	AND wageid = :arg_wageid;



IF cwauditingflag = 1 THEN
	rslt = 0
	arg_msg = "单据已经总账审核，不能撤审！"
	GOTO ext
END IF







UPDATE u_gz_award_punish SET
	flag = 0,
	Auditrep = '',
	Auditdate = :null_server_dt
	Where  wagemth = :arg_wagemth AND flag = 1 AND  wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新奖罚单失败，原因：'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

UPDATE u_gz_wagemx Set wageamt = 0 Where wageid = :arg_wageid AND wagemth = :arg_wagemth;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '更新工资表失败!原因：'+sqlca.SQLErrText
	GOTO ext
END IF


ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF  rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
arg_msg = '奖罚单,'+ arg_msg
RETURN rslt

end function

public function integer save (ref string arg_msg, boolean arg_ifcommit);//====================================================================
// Function: save(arg_msg,arg_ifcommit)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		reference	string 	arg_msg     		
//		value    	boolean	arg_ifcommit		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


Integer rslt = 1,cnt = 0,i
DateTime server_dt
Long ls_newid

IF IsNull(empid)	 THEN empid = 0
IF IsNull(award_punish_amt)	 THEN award_punish_amt = 0
IF IsNull(wageid)	 THEN wageid = 0
IF IsNull(wagemth)	 THEN wagemth = 0
IF IsNull(reason)	 THEN reason = ''
IF IsNull(deptid)	 THEN deptid = 0
IF IsNull(rep)	 THEN rep = ''
IF IsNull(billtype)	 THEN billtype = 0
IF IsNull(dealtype )	 THEN dealtype = ''

IF it_newbegin = FALSE AND it_updatebegin = FALSE THEN
	rslt = 0
	arg_msg = "非编辑状态不可以提交"
	GOTO ext
END IF

IF billtype = 0 THEN
	arg_msg = '单据类形错误,1-奖单,2-罚单'
	rslt = 0
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM u_rs_empinfo
	Where empid = :empid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询人员资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt > 1 THEN
	arg_msg = '人员资料重复'
	rslt = 0
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM u_gz_wageitem
	Where wageid = :wageid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询工资项目资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt > 1 THEN
	arg_msg = '工资项目重复'
	rslt = 0
	GOTO ext
END IF

cnt = 0
SELECT count(*) INTO :cnt
	FROM cw_department
	Where  departmentid = :deptid;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '查询部门资料失败'
	rslt = 0
	GOTO ext
END IF

IF cnt > 1 THEN
	arg_msg = '部门资料重复'
	rslt = 0
	GOTO ext
END IF

IF wagemth = 0 THEN
	arg_msg = '错误的工资月份'
	rslt = 0
	GOTO ext
END IF



IF award_punish_amt <= 0 THEN
	arg_msg = '请输入正确的金额'
	rslt = 0
	GOTO ext
END IF

SELECT Top 1 getdate() INTO :server_dt FROM u_user;
//取得系统时间,借用操作员表
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "查询操作失败,日期 "
	GOTO ext
END IF

IF Year(Date(billdate)) < 2000 OR IsNull(billdate) THEN
	rslt = 0
	arg_msg = "时间不合理"
	GOTO ext
END IF

////////////////////////////////////////////////开始区分:新建/更新 处理
IF billid = 0 THEN //新建
	ls_newid = f_sys_scidentity(0,"u_gz_award_punish","billid",arg_msg,TRUE,sqlca)
	IF ls_newid <= 0 THEN
		rslt = 0
		GOTO ext
	END IF
	
	
	billcode = getid(0,"JF",Date(server_dt),TRUE,sqlca) //取得新单据编号
	IF billcode = "err" THEN
		billcode = ''
		rslt = 0
		arg_msg = "无法获取单据编号"
		GOTO ext
	END IF
	
	INSERT INTO u_gz_award_punish (
		billid,
		billcode,
		billdate,
		Wagemth,
		wageid,
		empid,
		award_punish_amt,
		reason,
		deptid,
		rep,
		billtype,
		opdate,
		opemp,
		dealtype)
		VALUES (
		:ls_newid,
		:billcode,
		:billdate,
		:Wagemth,
		:wageid,
		:empid,
		:award_punish_amt,
		:reason,
		:deptid,
		:rep,
		:billtype,
		:server_dt,
		:publ_operator,
		:dealtype);
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		IF Pos(Lower(sqlca.SQLErrText),'pk_u_gz_award_punish') > 0 THEN
			arg_msg = '插入操作失败,关键字单据ID重复'
		ELSEIF Pos(Lower(sqlca.SQLErrText),'ix_u_gz_award_punish') > 0 THEN
			arg_msg = '插入操作失败,单据编号重复'
		ELSE
			arg_msg = "因网络或其它原因导致插入操作失败>>"+"~n"+sqlca.SQLErrText
		END IF
		GOTO ext
	END IF
	billid = ls_newid
ELSE //////////////////////////////////////////////////更新
	
	UPDATE u_gz_award_punish
		SET billdate = :billdate,
		wageid = :wageid,
		empid = :empid,
		award_punish_amt = :award_punish_amt,
		reason = :reason,
		deptid = :deptid,
		rep = :rep,
		moddate = :server_dt,
		modemp = :modemp,
		billtype = :billtype,
		Wagemth = :Wagemth,
		dealtype = :dealtype
		WHERE u_gz_award_punish.billid = :billid
		AND flag = 0;
	IF sqlca.SQLCode <> 0 OR sqlca.SQLNRows <= 0 THEN
		rslt = 0
		IF Pos(Lower(sqlca.SQLErrText),'pk_u_gz_award_punish') > 0 THEN
			arg_msg = '插入操作失败,关键字单据ID重复'
		ELSEIF Pos(Lower(sqlca.SQLErrText),'ix_u_gz_award_punish') > 0 THEN
			arg_msg = '插入操作失败,单据编号重复'
		ELSE
			arg_msg = "因网络或其它原因导致插入操作失败>>"+"~n"+sqlca.SQLErrText
		END IF
		GOTO ext
	END IF
	
	
END IF

it_newbegin = FALSE
it_updatebegin = FALSE

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
arg_msg = '奖罚单,'+ arg_msg
Return(rslt)



end function

public function integer del (long arg_billid, ref string arg_msg);//====================================================================
// Function: del(arg_billid,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid		
//		reference	string	arg_msg   		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================

Int rslt = 1
IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	GOTO ext
END IF

IF it_newbegin OR it_updatebegin THEN
	rslt = 0
	arg_msg = "编辑状态下不可以执行,操作取消"
	GOTO ext
END IF

SELECT u_gz_award_punish.flag
	INTO :flag
	FROM u_gz_award_punish
	Where u_gz_award_punish.billid = :arg_billid;
IF sqlca.SQLCode <> 0  THEN
	rslt = 0
	IF Pos(Lower(sqlca.SQLErrText),'more than') > 0 THEN
		arg_msg = '查询操作失败,查询数据返回值多于一个'
	ELSE
		arg_msg = '查询奖罚单操作失败(错误单据唯一码)'
	END IF
	GOTO ext
END IF

IF flag = 1 THEN
	rslt = 0
	arg_msg = "单据已经审核,不可以删除"
	GOTO ext
END IF

DELETE FROM u_gz_award_punish Where u_gz_award_punish.billid = :arg_billid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "删除奖罚单操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

COMMIT;
it_newbegin = FALSE
it_updatebegin = FALSE
ext:
IF rslt = 0 THEN
	ROLLBACK;
	p_reset()
END IF

arg_msg = '奖罚单,'+ arg_msg
Return (rslt)


end function

public function integer auditing (long arg_wageid, long arg_wagemth, ref string arg_msg, boolean arg_ifcommit);//====================================================================
// Function: auditing()
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long    	arg_wageid  		
//		value    	long    	arg_wagemth 		
//		value    	datetime	arg_enddate 		
//		reference	string  	arg_msg     		
//		value    	boolean 	arg_ifcommit		
//--------------------------------------------------------------------
// Returns:  integer
//--------------------------------------------------------------------
// Author:	yyx		Date: 2004.10.19
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================



Long cnt = 0,i
Int rslt = 1
Decimal ls_emp_sumwage
datastore ds_emp_sumwage

cnt = 0
SELECT count(*) INTO :cnt
	FROM u_gz_award_punish
	WHERE  wagemth = :arg_wagemth
	AND wageid = :arg_wageid
	AND flag = 1;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询奖罚单明细失败!'
	GOTO ext
END IF

IF cnt > 0 THEN
	rslt = 0
	arg_msg = '该月的奖罚单已审核,审核前请先执行撤审!'
	GOTO ext
END IF

cnt = 0
SELECT  count(*) INTO :cnt
	FROM u_gz_wageitem Where useflag = 1 AND wageid = :arg_wageid;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询工资项目失败!'
	GOTO ext
END IF

IF cnt = 0 THEN
	rslt = 0
	arg_msg = '不存在该工资项目!'
	GOTO ext
END IF

ds_emp_sumwage = CREATE datastore
ds_emp_sumwage.DataObject = 'dw_emp_sumawardpunishwage'
ds_emp_sumwage.SetTransObject(sqlca)

IF ds_emp_sumwage.Retrieve(arg_wagemth,arg_wageid) <= 0 THEN
	rslt = 0
	arg_msg = '本月没有奖罚单可审核或查询奖罚单失败'
	GOTO ext
END IF

FOR i = 1 TO ds_emp_sumwage.RowCount()
	ls_emp_sumwage = 0.00
	ls_emp_sumwage = ds_emp_sumwage.Object.sumwage[i]
	IF u_wage.f_setwagemxdata(arg_wagemth,ds_emp_sumwage.Object.empid[i],arg_wageid,ls_emp_sumwage,arg_msg,FALSE) = 0 THEN
		rslt = 0
		GOTO ext
	END IF
NEXT

UPDATE u_gz_award_punish SET
	flag = 1,
	auditrep = :publ_operator,
	Auditdate = getdate()
	WHERE wagemth = :arg_wagemth
	AND wageid = :arg_wageid
	AND flag = 0;
IF sqlca.SQLCode <> 0 THEN
	arg_msg = '更新奖罚单失败,原因>>'+sqlca.SQLErrText
	rslt = 0
	GOTO ext
END IF

ext:
IF rslt = 0 THEN
	ROLLBACK;
ELSEIF rslt = 1 AND arg_ifcommit THEN
	COMMIT;
END IF
arg_msg = '奖罚单,'+ arg_msg
RETURN rslt

end function

public function integer add_dscrp (long arg_billid, string arg_newdescppart, ref string arg_msg);//====================================================================
// Function: add_dscrp(arg_billid,arg_newdescppart,arg_msg)
//--------------------------------------------------------------------
// Description: 
//--------------------------------------------------------------------
// Arguments: 
//		value    	long  	arg_billid      		
//		value    	string	arg_newdescppart		
//		reference	string	arg_msg         		
//--------------------------------------------------------------------
// Returns:  integer 
//--------------------------------------------------------------------
// Author:	yyx		Date: 2003.11.21
//--------------------------------------------------------------------
// Modify History: 
//	
//====================================================================


Int rslt = 1
arg_newdescppart = Trim(arg_newdescppart)

IF arg_billid <= 0 THEN
	rslt = 0
	arg_msg = "没有删除对象,操作取消"
	GOTO ext
END IF

IF it_newbegin OR it_updatebegin THEN
	rslt = 0
	arg_msg = "编辑状态下不可以执行,操作取消"
	GOTO ext
END IF

SELECT u_gz_award_punish.flag
	INTO :flag
	FROM u_gz_award_punish
	Where u_gz_award_punish.billid = :arg_billid;
IF sqlca.SQLCode <> 0  THEN
	rslt = 0
	IF Pos(Lower(sqlca.SQLErrText),'more than') > 0 THEN
		arg_msg = '查询操作失败,查询数据返回值多于一个'
	ELSE
		arg_msg = '查询奖罚单操作失败(错误单据唯一码)'
	END IF
	GOTO ext
END IF

IF flag = 0 THEN
	rslt = 0
	arg_msg = "非审核状态下不可用"
	GOTO ext
END IF

UPDATE u_gz_award_punish
	SET reason = reason+' '+:arg_newdescppart
	Where u_gz_award_punish.billid = :billid;
IF sqlca.SQLCode <> 0 THEN
	ROLLBACK ;
	rslt = 0
	arg_msg = "因网络或其它原因导致添加单据备注操作失败"+"~n"+sqlca.SQLErrText
	GOTO ext
END IF

COMMIT;
reason = reason+' '+arg_newdescppart

ext:
arg_msg = '奖罚单,'+ arg_msg
Return (rslt)


end function

public function integer audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg);
Int rslt = 1,cnt = 0

IF arg_billid = 0 THEN
	rslt = 0
	arg_msg = "没有审核对象"
	GOTO ext
END IF


//IF p_getinfo(arg_scid,arg_billid,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
SELECT flag,cwauditingflag Into :flag,:cwauditingflag From u_gz_award_punish Where billid = :arg_billid;



IF flag = 0  THEN
	rslt = 0
	arg_msg = "单据没有审核"
	GOTO ext
END IF




IF cwauditingflag = 1 THEN
	rslt = 0
	arg_msg = "单据已经总账审核"
	GOTO ext
END IF



UPDATE u_gz_award_punish
	SET cwauditingflag = 1,
	cwauditingdate = getdate(),
	cwauditingrep = :publ_operator
	WHERE ( u_gz_award_punish.billid = :arg_billid )  Using sqlca;
	
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "因网络或其它原因导致总账审核操作失败"+"~n"+sqlca.SQLErrText
	ROLLBACK Using sqlca;
	GOTO ext
END IF

ext:
IF arg_ifcommit And rslt = 1 THEN
	COMMIT Using sqlca;
END IF

Return (rslt)







end function

public function integer c_audit_subject (long arg_scid, long arg_billid, boolean arg_ifcommit, ref string arg_msg);
Int rslt = 1,cnt = 0

IF arg_billid = 0 THEN
	rslt = 0
	arg_msg = "没有审核对象"
	GOTO ext
END IF


//IF p_getinfo(arg_scid,arg_billid,arg_msg) = 0 THEN
//	rslt = 0
//	GOTO ext
//END IF
SELECT flag,cwauditingflag Into :flag,:cwauditingflag From u_gz_award_punish Where billid = :arg_billid;



IF cwauditingflag = 0 THEN
	rslt = 0
	arg_msg = "单据没有总账审核"
	GOTO ext
END IF



UPDATE u_gz_award_punish
	SET cwauditingflag = 0,
	cwauditingdate =null,
	cwauditingrep = ''
	WHERE ( u_gz_award_punish.billid = :arg_billid )  Using sqlca;
	
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = "因网络或其它原因导致总账撤审操作失败"+"~n"+sqlca.SQLErrText
	ROLLBACK Using sqlca;
	GOTO ext
END IF

ext:
IF arg_ifcommit And rslt = 1 THEN
	COMMIT Using sqlca;
END IF

Return (rslt)



end function

on uo_award_punish.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_award_punish.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

event constructor; u_wage=create uo_wage
end event

event destructor;DESTROY u_wage
end event