Q5/ws_objects/Ew_eb_import.pbl.src/w_taobao_directsend.srw

$PBExportHeader$w_taobao_directsend.srw
forward
global type w_taobao_directsend from w_publ_base
end type
type cb_reflash from uo_imflatbutton within w_taobao_directsend
end type
type dw_1 from u_dw_rbtnfilter within w_taobao_directsend
end type
type cbx_1 from checkbox within w_taobao_directsend
end type
type cb_edit from uo_imflatbutton within w_taobao_directsend
end type
type cb_del from uo_imflatbutton within w_taobao_directsend
end type
type cb_upload from uo_imflatbutton within w_taobao_directsend
end type
type cb_edit_relstr_1 from commandbutton within w_taobao_directsend
end type
type cb_export from uo_imflatbutton within w_taobao_directsend
end type
type cb_fy from uo_imflatbutton within w_taobao_directsend
end type
type cb_print_dir from uo_imflatbutton within w_taobao_directsend
end type
type cb_amt_edit from uo_imflatbutton within w_taobao_directsend
end type
type cb_amt_cancel from uo_imflatbutton within w_taobao_directsend
end type
type ln_bar from line within w_taobao_directsend
end type
type ln_bar2 from line within w_taobao_directsend
end type
type r_bar from rectangle within w_taobao_directsend
end type
type ln_1 from line within w_taobao_directsend
end type
type ln_2 from line within w_taobao_directsend
end type
end forward

global type w_taobao_directsend from w_publ_base
integer width = 3063
integer height = 2084
string title = "淘宝直接发货"
boolean maxbox = true
boolean resizable = true
windowstate windowstate = maximized!
event ue_taobao_upload ( )
event ue_print ( )
event ue_p_edit_relstr_1 ( )
event ue_xls_export ( )
event ue_input_fy ( )
event ue_input_fy_order ( )
event ue_retrieve_mx ( )
event ue_import_fy_xls ( )
cb_reflash cb_reflash
dw_1 dw_1
cbx_1 cbx_1
cb_edit cb_edit
cb_del cb_del
cb_upload cb_upload
cb_edit_relstr_1 cb_edit_relstr_1
cb_export cb_export
cb_fy cb_fy
cb_print_dir cb_print_dir
cb_amt_edit cb_amt_edit
cb_amt_cancel cb_amt_cancel
ln_bar ln_bar
ln_bar2 ln_bar2
r_bar r_bar
ln_1 ln_1
ln_2 ln_2
end type
global w_taobao_directsend w_taobao_directsend

type variables
long ins_child = 3
long ins_child_min = 2

///////////////////////////////////////////////

boolean ins_print_flag = false
boolean ins_print_hz = false

boolean dw_amt_edit_mode = false
end variables

forward prototypes
public subroutine wf_face ()
public subroutine wf_selectall ()
public function integer wf_save (ref string arg_msg)
public function integer wf_save_amt (ref string arg_msg)
public function integer wf_save_tran (string arg_tid, string arg_transcom, string arg_transcode, ref string arg_msg, boolean arg_ifcommit)
end prototypes

event ue_taobao_upload();// DONE: 修改上传

IF Not uo_power_spi.f_taobao_directsend_upload(sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF
Int rslt = 1
String arg_msg = ''

String arr_outwarecode[], ls_lastcode = ''
Long cnt = 0

Long i

FOR i = 1 To dw_1.RowCount()
	IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
	IF dw_1.Object.tb_trade_tid[i] = ls_lastcode THEN CONTINUE
	
	cnt++
	arr_outwarecode[cnt] = dw_1.Object.tb_trade_tid[i]
NEXT

IF cnt <= 0 THEN
	MessageBox('提示', '请选择要淘宝发货的对象')
	RETURN
END IF

FOR i = 1 To cnt
	UPDATE eb_saletask_import
		SET out_freight = CASE WHEN ISNULL(u_station.taobao_code, '') <> '' THEN u_station.taobao_code ELSE eb_saletask_import.transcom END,
		out_freight_code = eb_saletask_import.transcode, sendflag = 1
		FROM eb_saletask_import LEFT OUTER JOIN
		u_station ON eb_saletask_import.transcom = u_station.stationname
		WHERE (eb_saletask_import.directSend = 1)
		AND (eb_saletask_import.im_type = 5)
		AND (eb_saletask_import.t_sendflag = 0)
		AND (eb_saletask_import.transcom <> '')
		And (eb_saletask_import.tid = :arr_outwarecode[i]);
	IF sqlca.SQLCode <> 0 THEN
		rslt = 0
		arg_msg = '提交上传淘宝发货单信息失败,' + sqlca.SQLErrText
		GOTO ext
	END IF
NEXT

ext:
IF rslt = 1 THEN
	COMMIT;
	MessageBox('OK', '淘宝发货单信息更新成功,后台将自动上传淘宝')
	cb_reflash.TriggerEvent(clicked!)
ELSE
	ROLLBACK;
	MessageBox('ERROR', arg_msg)
END IF





end event

event ue_print();//--直接打印
// DONE: 修改打印参数传送
Long ls_msgprintid
String ls_newname
Long ls_powerid
Long pcnt = 0
String ls_dwname = ''
String ls_chname
Long i
s_taobao_outware_print s_tran
s_taobao_outware_print_rslt s_rslt
uo_print_preview uo_print
String arg_msg

s_print_msg ls_prmsg
Boolean lb_first = True

String arr_outwarecode[], ls_parm
Long cnt = 0
Long Pos = 0
String ls_tid

ls_msgprintid = Message.LongParm

IF Not uo_power_spi.f_taobao_directsend_print_save(sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

SELECT dft_new_dwname,powerid,chnname
	INTO :ls_newname,:ls_powerid,:ls_chname
	FROM sys_dft_dwprint_dynamic
	Where sys_dft_dwprint_dynamic.dwprintid = :ls_msgprintid Using sqlca;
IF sqlca.SQLCode <> 0 THEN
	ls_newname = ''
	ls_powerid = 0
END IF

IF ls_newname <> '' THEN
	IF Not uo_power_spi.uf_power_ind(ls_powerid,sys_msg_pow) THEN
		MessageBox(publ_operator,sys_msg_pow)
		RETURN
	END IF
	
	ls_dwname = ls_newname
ELSE
	// DONE: 默认打印格式
	ls_dwname = ''
END IF

IF ins_print_hz THEN
	
	IF ls_dwname = '' THEN
		MessageBox('提示', '请定义自定义打印格式，所属窗口:'+ClassName ( )+'_hz')
		RETURN
	END IF
	
	FOR i = 1 To dw_1.RowCount()
		IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
		cnt++
		arr_outwarecode[cnt] = dw_1.Object.tb_trade_tid[i]
	NEXT
	
	IF cnt <= 0 THEN
		MessageBox('提示', '请勾选汇总打印的发货单')
		RETURN
	END IF
	ls_parm = ''
	FOR i = 1 To UpperBound(arr_outwarecode)
		ls_parm += ',' + arr_outwarecode[i]
	NEXT
	ls_parm += ','
	
	ls_prmsg.retr_pram_falg = 1
	
	ls_prmsg.obj_dwNAME = ls_dwname
	ls_prmsg.printrow = 0
	ls_prmsg.tag_text = '淘宝发货汇总'
	ls_prmsg.filter_string = ''
	ls_prmsg.pagech_flag = 0
	ls_prmsg.retr_pramstr = ls_parm
	ls_prmsg.rowcnt = 0
	OpenWithParm(w_publ_preview,ls_prmsg)
	printnum = Message.DoubleParm
	
ELSE
	
	IF ls_dwname = '' THEN
		MessageBox('提示', '请定义自定义打印格式，所属窗口:' + ClassName ( ))
		ls_dwname = 'dw_rp_taobao_direct_trans'
	END IF
	
	cnt = 0
	FOR i = 1 To dw_1.RowCount()
		IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
		cnt++
	NEXT
	
	IF ins_print_flag THEN // 直接打印	
		FOR i = 1 To dw_1.RowCount()
			IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
			ls_prmsg.retr_pram_falg = 1
			
			ls_prmsg.obj_dwNAME = ls_dwname
			ls_prmsg.printrow = 0
			ls_prmsg.tag_text = '淘宝直接发货快递单'
			ls_prmsg.filter_string = ''
			ls_prmsg.pagech_flag = 0
			//			ls_prmsg.retr_scid = dw_1.Object.scid[i]
			//			ls_prmsg.retr_pramnmb = dw_1.Object.outwareid[i]
			ls_prmsg.retr_pramstr = dw_1.Object.tb_trade_tid[i]
			ls_prmsg.rowcnt = 0
			
			ls_tid = dw_1.Object.tb_trade_tid[i]
			
			IF lb_first THEN
				OpenWithParm(w_publ_preview,ls_prmsg)
				printnum = Message.DoubleParm
				IF printnum <= 0 THEN
					RETURN
				END IF
				
				//**更新打印次料
				UPDATE eb_saletask_import
					SET printnum = printnum + :printnum
					WHERE im_type = 5
					And tid = :ls_tid;
				COMMIT;
				dw_1.Object.eb_saletask_import_printnum[i] = dw_1.Object.eb_saletask_import_printnum[i] + printnum
				
				
				lb_first = False
				cnt --
				IF cnt > 0 THEN
					Open(w_sys_wait_jdt) //初始化进度条
					w_sys_wait_jdt.Show()
					w_sys_wait_jdt.wf_accepttol(cnt)
					w_sys_wait_jdt.wf_inc(0)
					w_sys_wait_jdt.st_msg.Text = "正在打印快递单..."
				END IF
			ELSE
				Pos++
				w_sys_wait_jdt.wf_inc(Pos)
				w_sys_wait_jdt.st_msg.Text = "正在打印快递单["+dw_1.GetItemString(i, 'eb_saletask_import_transcode')+"]..."
				
				uo_print.FACT_PRINT_MSG = ls_prmsg
				IF uo_print.uof_print_begin(arg_msg) = 0 THEN
					MessageBox("系统提示",arg_msg)
					RETURN
				END IF
				uo_print.ds_print()
				
				//**更新打印次料
				printnum = Message.DoubleParm
				UPDATE eb_saletask_import
					SET printnum = printnum + :printnum
					WHERE im_type = 5
					And tid = :ls_tid;
				COMMIT;
				dw_1.Object.eb_saletask_import_printnum[i] = dw_1.Object.eb_saletask_import_printnum[i] + printnum
			END IF
		NEXT
		
		IF cnt > 0 THEN
			Close(w_sys_wait_jdt)
		END IF
		
	ELSE
		FOR i = 1 To dw_1.RowCount()
			IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
			dw_1.SetRow(i)
			dw_1.ScrollToRow(i)
			s_tran.outwarecode = dw_1.Object.u_outware_outwarecode[i]
			s_tran.dwname = ls_dwname
			s_tran.chname = ls_chname
			OpenWithParm(w_taobao_outware_print, s_tran)
			s_rslt = Message.PowerObjectParm
			IF s_rslt.ifcontinue <> 1 THEN
				EXIT
			END IF
			dw_1.Object.u_outware_relstr_1[i] = s_rslt.relstr_1
			dw_1.Object.u_outware_transcode[i] = s_rslt.transcode
		NEXT
	END IF
	
END IF




end event

event ue_p_edit_relstr_1();IF Not dw_edit_mode THEN RETURN

Long i
Long cnt = 0
s_outware_rel_str_ch s_tran

FOR i = 1 To dw_1.RowCount()
	IF dw_1.Object.ch[i] = 1 THEN
		cnt++
		s_tran.rel_str1 = dw_1.Object.eb_saletask_import_transcom[i]
		EXIT
	END IF
NEXT

IF cnt <= 0 THEN
	MessageBox('提示', '请选择批修改的发货单')
	RETURN
END IF

OpenWithParm(w_outware_rel_str_ch, s_tran)

s_tran = Message.PowerObjectParm
IF s_tran.ifok <> 1 THEN RETURN

longlong ll_pos = 0

FOR i = 1 To dw_1.RowCount()
	IF dw_1.Object.ch[i] = 1 THEN
		dw_1.Object.eb_saletask_import_transcom[i] = s_tran.rel_str1
		IF Not IsNull(s_tran.fcode) THEN
			IF ll_pos = 0 THEN
				ll_pos = Long(s_tran.fcode)
				s_tran.fcode = Fill("0", Len(s_tran.fcode))
			END IF
			dw_1.Object.eb_saletask_import_transcode[i] = f_cmpl_trancode(s_tran.rel_str1, s_tran.pre_str, String(ll_pos,s_tran.fcode), s_tran.post_str)
			ll_pos++
		END IF
	END IF
NEXT



end event

event ue_xls_export();IF Not uo_power_spi.f_taobao_directsend_export(sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF


Integer i
String Pathname,Filename
String arg_filename,arg_msg
Blob arg_blob


IF GetFileSaveName("选择备份文件",Pathname,Filename,'xls',"Excel,*.xls") <> 1 THEN RETURN

arg_filename = Trim(Pathname)
IF arg_filename = '' THEN
	MessageBox('提示','请输入文件名称', Information!, OK! )
	RETURN
END IF

IF FileExists(arg_filename) THEN
	IF MessageBox("询问","指定文件已经存在，是否覆盖该文件?",question!,yesno!,2) = 2 THEN
		RETURN
	END IF
END IF
//gf_dw_to_excel(dw_1, arg_filename)
dw_1.SaveAsAscii(arg_filename)
MessageBox('OK', '导出成功!')

end event

event ue_input_fy();IF Not uo_power_spi.uf_power_ind(3795,sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

Open(w_taobao_fy_input)
cb_reflash.TriggerEvent(Clicked!)

end event

event ue_input_fy_order();IF Not uo_power_spi.uf_power_ind(3795,sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

Long i
s_taobao_fy_order_input_parm s_parm
s_taobao_fy_order_input_rslt s_rslt

FOR i = 1 To dw_1.RowCount()
	IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
	dw_1.SetRow(i)
	dw_1.ScrollToRow(i)
	s_parm.scid = dw_1.Object.scid[i]
	s_parm.outwareid = dw_1.Object.outwareid[i]
	OpenWithParm(w_taobao_fy_order_input, s_parm)
	s_rslt = Message.PowerObjectParm
	IF s_rslt.ifcontinue <> 1 THEN
		EXIT
	END IF
NEXT

cb_reflash.TriggerEvent(Clicked!)

end event

event ue_retrieve_mx();//Long ll_row
//ll_row = dw_1.GetRow()
//
//IF ll_row <= 0 THEN
//	dw_2.Reset()
//	RETURN
//END IF
//
//dw_2.Retrieve(dw_1.Object.scid[ll_row], dw_1.Object.outwareid[ll_row])
//
end event

event ue_import_fy_xls();// DONE: 导入xls
String ls_path, ls_filename
IF GetFileOpenName("请选择要导入的Excel文件", ls_path, ls_filename, "XLS","Excel文件(*.XLS),*.XLS") <> 1 THEN
	RETURN
END IF

Long itemid
String itemcode,itemname, itemtype
String arg_msg = ''

IF uo_saletask_spi.wf_itemdef_ch(Ref itemid, Ref itemcode, Ref itemname, Ref itemtype, Ref arg_msg) <> 1 THEN
	RETURN
END IF


Int rslt = 1
arg_msg = ''

DataStore ds_import
ds_import = Create DataStore
ds_import.DataObject = 'ds_taobao_outware_amt_import'
uo_taobao_outware uo_taobao
uo_taobao = Create uo_taobao_outware

IF f_xls_import_to_dw(ls_path, ds_import, arg_msg) <> 1 THEN
	rslt = 0
	GOTO ext
END IF

Long i
String ls_transcode
Long scid, outwareid, cnt
Decimal amt
String ls_msg
FOR i = 1 To ds_import.RowCount()
	ls_transcode = Trim(ds_import.Object.transcode[i], True)
	amt = ds_import.Object.amt[i]
	IF ls_transcode = '' THEN CONTINUE
	SELECT count(0)
		INTO :cnt
		FROM u_outware
		Where transcode = :ls_transcode;
	IF sqlca.SQLCode <> 0 THEN
		IF arg_msg <> '' THEN arg_msg += '~r~n'
		arg_msg += '第'+String(i)+'行,货运单号:'+ls_transcode+',查询对应发货单数失败,' + sqlca.SQLErrText
		CONTINUE
	END IF
	
	IF cnt = 0 THEN
		IF arg_msg <> '' THEN arg_msg += '~r~n'
		arg_msg += '第'+String(i)+'行,货运单号:'+ls_transcode+',找不能对应发货单'
		CONTINUE
	END IF
	
	IF cnt > 1 THEN
		IF arg_msg <> '' THEN arg_msg += '~r~n'
		arg_msg += '第'+String(i)+'行,货运单号:'+ls_transcode+',找到多条发货单记录'
		CONTINUE
	END IF
	
	SELECT top 1 scid, outwareid
		INTO :scid, :outwareid
		FROM u_outware
		Where transcode = :ls_transcode;
	IF sqlca.SQLCode <> 0 THEN
		IF arg_msg <> '' THEN arg_msg += '~r~n'
		arg_msg += '第'+String(i)+'行,货运单号:'+ls_transcode+',查询对应发货单信息失败,' + sqlca.SQLErrText
		CONTINUE
	END IF
	
	IF uo_taobao.add_tranfy(scid, outwareid, itemid, amt, ls_msg, True) <> 1 THEN
		IF arg_msg <> '' THEN arg_msg += '~r~n'
		arg_msg += '第'+String(i)+'行,货运单号:'+ls_transcode+',' + ls_msg
		CONTINUE
	END IF
	
NEXT

ext:
Destroy ds_import
Destroy uo_taobao
IF rslt = 0 Or arg_msg <> '' THEN
	MessageBox('ERROR', arg_msg)
ELSE
	MessageBox('OK', '导入成功')
END IF

end event

public subroutine wf_face ();// DONE: 刷新界面
Long i
//ddlb_im_type.Enabled = Not (dw_edit_mode Or dw_amt_edit_mode)
//cb_selectuser.Enabled = Not (dw_edit_mode Or dw_amt_edit_mode)
cb_reflash.Enabled = Not (dw_edit_mode Or dw_amt_edit_mode)
cb_del.Enabled = dw_edit_mode
cb_amt_cancel.Enabled = dw_amt_edit_mode
cb_upload.Enabled = Not (dw_edit_mode Or dw_amt_edit_mode)
//cb_print.Enabled = Not (dw_edit_mode Or dw_amt_edit_mode)
cb_export.Enabled = Not (dw_edit_mode Or dw_amt_edit_mode)
cb_fy.Enabled = False // Not (dw_edit_mode Or dw_amt_edit_mode)
cb_edit_relstr_1.Enabled = dw_edit_mode

cb_edit.Enabled = Not dw_amt_edit_mode
cb_amt_edit.Enabled = False // Not dw_edit_mode
cb_print_dir.Enabled = Not dw_edit_mode
IF dw_amt_edit_mode THEN
	//	dw_1.SetTabOrder('inputamt', 10)
	cb_amt_edit.Text = '保存'
	cb_amt_edit.normalpicname = 'Save.bmp'
ELSE
	//	dw_1.SetTabOrder('inputamt', 0)
	cb_amt_edit.Text = '修改'
	cb_amt_edit.normalpicname = 'OPEN.bmp'
END IF

IF dw_edit_mode THEN
	
	FOR i = 1 To ins_child
		dw_1.SetTabOrder(i, i * 10)
	NEXT
	
	cb_edit.Text = '保存'
	cb_edit.normalpicname = 'Save.bmp'
ELSE
	
	FOR i = 1 To ins_child_min - 1
		dw_1.SetTabOrder(i, i * 10)
	NEXT
	FOR i = ins_child_min To ins_child
		dw_1.SetTabOrder(i, 0)
	NEXT
	
	cb_edit.Text = '修改'
	cb_edit.normalpicname = 'OPEN.bmp'
END IF

cb_edit.of_init_draw()
cb_edit.of_paint()
cb_edit.TriggerEvent('ue_textchange')
cb_amt_edit.of_init_draw()
cb_amt_edit.of_paint()
cb_amt_edit.TriggerEvent('ue_textchange')



end subroutine

public subroutine wf_selectall ();Long ll_check
IF cbx_1.Checked THEN
	ll_check = 1
ELSE
	ll_check = 0
END IF

Long i
FOR i = 1 To dw_1.RowCount()
	dw_1.Object.ch[i] = ll_check
NEXT


end subroutine

public function integer wf_save (ref string arg_msg);Int rslt = 1
// DONE: 保存货运单号
Long i, j

String arr_tid[], arr_relstr_1[], arr_transcode[]
Long cnt = 0

String ls_tid


FOR i = 1 To dw_1.RowCount()
	IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
	
	ls_tid = dw_1.Object.tb_trade_tid[i]
	FOR j = 1 To cnt
		IF arr_tid[j] = ls_tid THEN
			EXIT
		END IF
	NEXT
	
	IF j > cnt THEN
		cnt++
		arr_tid[cnt] = dw_1.Object.tb_trade_tid[i]
		arr_relstr_1[cnt] = dw_1.Object.eb_saletask_import_transcom[i]
		arr_transcode[cnt] = dw_1.Object.eb_saletask_import_transcode[i]
	END IF
NEXT

IF cnt <= 0 THEN
	rslt = 0
	arg_msg = '请选择要保存的单据'
	GOTO ext
END IF

FOR i = 1 To cnt
	IF wf_save_tran(arr_tid[i], arr_relstr_1[i], arr_transcode[i], arg_msg, False) <> 1 THEN
		rslt = 0
		GOTO ext
	END IF
NEXT

ext:
IF rslt = 1 THEN
	COMMIT;
ELSE
	ROLLBACK;
END IF
RETURN rslt


end function

public function integer wf_save_amt (ref string arg_msg);Int rslt = 1
uo_taobao_outware = Create uo_taobao_outware
// DONE: 保存货运单号
Long i, j, cnt = 0

Long itemid
String itemcode,itemname, itemtype
arg_msg = ''

IF uo_saletask_spi.wf_itemdef_ch(Ref itemid, Ref itemcode, Ref itemname, Ref itemtype, Ref arg_msg) <> 1 THEN
	rslt = 0
	goto ext
END IF

Long ll_itemid
ll_itemid = itemid

String arr_outwarecode[]
Long arr_scid[], arr_outwareid[]
Long arr_itemid[]
Decimal arr_amt[]

FOR i = 1 To dw_1.RowCount()
	IF dw_1.Object.ch[i] <> 1 THEN CONTINUE
	
	FOR j = 1 To cnt
		IF arr_scid[j] = dw_1.Object.scid[i] And arr_outwareid[j] = dw_1.Object.outwareid[i] THEN
			EXIT
		END IF
	NEXT
	
	IF j > cnt THEN
		cnt++
		arr_scid[cnt] = dw_1.Object.scid[i]
		arr_outwareid[cnt] = dw_1.Object.outwareid[i]
		arr_itemid[cnt] = ll_itemid
		arr_amt[cnt] = dw_1.Object.inputamt[i]
		arr_outwarecode[cnt] = dw_1.Object.u_outware_outwarecode[i]
	END IF
NEXT

IF cnt <= 0 THEN
	rslt = 0
	arg_msg = '请选择要保存的发货单'
	GOTO ext
END IF

FOR i = 1 To cnt
	IF uo_taobao_outware.add_tranfy(arr_scid[i], arr_outwareid[i], ll_itemid, arr_amt[i], arg_msg, False) <> 1 THEN
		rslt = 0
		arg_msg = '发货单' + arr_outwarecode[i] + ':' + arg_msg
		GOTO ext
	END IF
NEXT

ext:
Destroy uo_taobao_outware
IF rslt = 1 THEN
	COMMIT;
ELSE
	ROLLBACK;
END IF
RETURN rslt


end function

public function integer wf_save_tran (string arg_tid, string arg_transcom, string arg_transcode, ref string arg_msg, boolean arg_ifcommit);Int rslt = 1

UPDATE eb_saletask_import
	SET transcom = :arg_transcom,
	transcode = :arg_transcode
	WHERE im_type = 5
	AND tid = :arg_tid
	AND directSend = 1
	And sendflag = 0;
IF sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '更新订单['+arg_tid+']货运部与货运单号失败,' + sqlca.SQLErrText
	GOTO ext
END IF

IF sqlca.sqlnrows = 0 THEN
	rslt = 0
	arg_msg = '更新订单['+arg_tid+']货运部与货运单号失败,订单当前状态不允许'
	GOTO ext
END IF

ext:
IF arg_ifcommit THEN
	IF rslt = 1 THEN
		COMMIT;
	ELSE
		ROLLBACK;
	END IF
END IF
RETURN rslt


end function

on w_taobao_directsend.create
int iCurrent
call super::create
this.cb_reflash=create cb_reflash
this.dw_1=create dw_1
this.cbx_1=create cbx_1
this.cb_edit=create cb_edit
this.cb_del=create cb_del
this.cb_upload=create cb_upload
this.cb_edit_relstr_1=create cb_edit_relstr_1
this.cb_export=create cb_export
this.cb_fy=create cb_fy
this.cb_print_dir=create cb_print_dir
this.cb_amt_edit=create cb_amt_edit
this.cb_amt_cancel=create cb_amt_cancel
this.ln_bar=create ln_bar
this.ln_bar2=create ln_bar2
this.r_bar=create r_bar
this.ln_1=create ln_1
this.ln_2=create ln_2
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.cb_reflash
this.Control[iCurrent+2]=this.dw_1
this.Control[iCurrent+3]=this.cbx_1
this.Control[iCurrent+4]=this.cb_edit
this.Control[iCurrent+5]=this.cb_del
this.Control[iCurrent+6]=this.cb_upload
this.Control[iCurrent+7]=this.cb_edit_relstr_1
this.Control[iCurrent+8]=this.cb_export
this.Control[iCurrent+9]=this.cb_fy
this.Control[iCurrent+10]=this.cb_print_dir
this.Control[iCurrent+11]=this.cb_amt_edit
this.Control[iCurrent+12]=this.cb_amt_cancel
this.Control[iCurrent+13]=this.ln_bar
this.Control[iCurrent+14]=this.ln_bar2
this.Control[iCurrent+15]=this.r_bar
this.Control[iCurrent+16]=this.ln_1
this.Control[iCurrent+17]=this.ln_2
end on

on w_taobao_directsend.destroy
call super::destroy
destroy(this.cb_reflash)
destroy(this.dw_1)
destroy(this.cbx_1)
destroy(this.cb_edit)
destroy(this.cb_del)
destroy(this.cb_upload)
destroy(this.cb_edit_relstr_1)
destroy(this.cb_export)
destroy(this.cb_fy)
destroy(this.cb_print_dir)
destroy(this.cb_amt_edit)
destroy(this.cb_amt_cancel)
destroy(this.ln_bar)
destroy(this.ln_bar2)
destroy(this.r_bar)
destroy(this.ln_1)
destroy(this.ln_2)
end on

event open;call super::open;String arg_msg

dw_1.SetTransObject(sqlca)
//dw_2.SetTransObject(sqlca)

cb_reflash.TriggerEvent(Clicked!)
wf_face()


end event

event resize;call super::resize;r_bar.Width = this.width

ln_bar.endx = this.width
ln_bar2.endx = this.width
ln_1.endx = this.width
ln_2.endx = this.width

dw_1.height = this.WorkSpaceHeight() - dw_1.Y// - dw_2.Height
dw_1.Width = this.WorkSpaceWidth() - dw_1.X

//dw_2.Y = dw_1.Y + dw_1.height
//dw_2.Width = this.WorkSpaceWidth() - dw_2.X
end event

type cb_func from w_publ_base`cb_func within w_taobao_directsend
boolean visible = false
end type

type cb_exit from w_publ_base`cb_exit within w_taobao_directsend
integer x = 1522
integer width = 151
integer height = 164
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

type cb_reflash from uo_imflatbutton within w_taobao_directsend
integer width = 151
integer height = 164
integer taborder = 30
boolean bringtotop = true
string text = "刷新"
string normalpicname = "refresh.BMP"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;dw_1.Retrieve()
wf_selectall()
end event

type dw_1 from u_dw_rbtnfilter within w_taobao_directsend
integer y = 296
integer width = 2862
integer height = 1068
integer taborder = 30
boolean bringtotop = true
string dataobject = "dw_taobao_directsend"
boolean hscrollbar = true
boolean vscrollbar = true
boolean hsplitscroll = true
boolean rbutton_filter_use = true
boolean rbutton_setposition_use = true
boolean titleclick_sort_use = true
end type

event clicked;call super::clicked;IF row > 0 THEN
	dw_1.SetRow(row)
END IF

Long ll_row
String lpo_object


IF  dwo.Name = "u_outware_relstr_1" And dw_edit_mode And row > 0 THEN
	s_edit_index_tran s_ch_tran //传递参数使用
	s_ch_tran.if_retrieve_all = False //是否一次RETRIEVE所有行
	s_ch_tran.work_mode = 1 //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid = 0 //目标定位PKID (备用)
	
	OpenWithParm(w_station_edit,s_ch_tran) //调用
	
	s_station S_INSCUST
	S_INSCUST = Message.PowerObjectParm //接受返回结构
	
	IF S_INSCUST.stationid > 0 THEN //正常返回值则可以取以下值
		dw_1.SetRedraw(False)
		dw_1.Object.u_outware_relstr_1[row] = S_INSCUST.stationname
		
		dw_1.SetRedraw(True)
	END IF
	
	
END IF

end event

event rowfocuschanged;call super::rowfocuschanged;This.SelectRow(0, False)
IF currentrow > 0 THEN
	This.SelectRow(currentrow, True)
END IF
Parent.TriggerEvent('ue_retrieve_mx')

end event

event itemchanged;call super::itemchanged;//IF Not dw_edit_mode THEN RETURN
//IF row <= 0 THEN RETURN
//IF dw_1.AcceptText() <> 1 THEN RETURN
//
//String ls_outwarecode
//String ls_type
//String ls_name
//Any ll_value
//Long i
//
//ls_outwarecode = dw_1.Object.u_outware_outwarecode[row]
//ls_name = dwo.Name
//
//ls_type = Lower(dw_1.Describe(ls_name + ".ColType"))
//IF ls_type = 'date' THEN
//	ll_value = dw_1.GetItemDate(row, ls_name)
//ELSEIF ls_type = 'datetime' THEN
//	ll_value = dw_1.GetItemDateTime(row, ls_name)
//ELSEIF ls_type = 'time' Or Pos(ls_type, 'time') > 0 THEN
//	ll_value = dw_1.GetItemTime(row, ls_name)
//ELSEIF Pos(ls_type, 'dec') > 0 THEN
//	ll_value = dw_1.GetItemDecimal(row, ls_name)
//ELSEIF Pos(ls_type, 'char') > 0 THEN
//	ll_value = dw_1.GetItemString(row, ls_name)
//ELSE
//	ll_value = dw_1.GetItemNumber(row, ls_name)
//END IF
//
//FOR i = 1 To dw_1.RowCount()
//	IF i = row THEN CONTINUE
//	IF dw_1.Object.u_outware_outwarecode[i] <> ls_outwarecode THEN CONTINUE
//	dw_1.SetItem(i, ls_name, ll_value)
//NEXT
//
//
//
end event

type cbx_1 from checkbox within w_taobao_directsend
integer y = 196
integer width = 402
integer height = 60
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 67108864
string text = "全部"
end type

event constructor;this.backcolor = 14215660
end event

event clicked;wf_selectall()
end event

type cb_edit from uo_imflatbutton within w_taobao_directsend
integer x = 155
integer width = 151
integer height = 164
integer taborder = 70
boolean bringtotop = true
string text = "修改"
string normalpicname = "OPEN.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;IF Not uo_power_spi.f_taobao_directsend_print_save(sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

String arg_msg
IF dw_edit_mode THEN
	
	IF dw_1.AcceptText() <> 1 THEN RETURN
	
	IF wf_save(arg_msg) <> 1 THEN
		MessageBox('错误', arg_msg)
		RETURN
	END IF
END IF

dw_edit_mode = Not dw_edit_mode
IF dw_edit_mode THEN
	cbx_1.Checked = True
	wf_selectall()
ELSE
	cb_reflash.TriggerEvent(Clicked!)
END IF
wf_face()


end event

type cb_del from uo_imflatbutton within w_taobao_directsend
integer x = 311
integer width = 151
integer height = 164
integer taborder = 60
boolean bringtotop = true
string text = "放弃"
string normalpicname = "Undo.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;String ls_msg
IF dw_edit_mode THEN
	dw_edit_mode = Not dw_edit_mode
	cb_reflash.TriggerEvent(Clicked!)
	wf_face()
END IF



end event

type cb_upload from uo_imflatbutton within w_taobao_directsend
integer x = 745
integer width = 151
integer height = 164
integer taborder = 80
boolean bringtotop = true
string text = "上传"
string normalpicname = "imexport.BMP"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;parent.triggerevent('ue_taobao_upload')

end event

type cb_edit_relstr_1 from commandbutton within w_taobao_directsend
integer x = 439
integer y = 180
integer width = 430
integer height = 92
integer taborder = 40
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
string text = "批修改货运部"
end type

event clicked;parent.triggerevent('ue_p_edit_relstr_1')
end event

type cb_export from uo_imflatbutton within w_taobao_directsend
integer x = 901
integer width = 151
integer height = 164
integer taborder = 40
boolean bringtotop = true
string text = "导出"
string normalpicname = "excel.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;parent.triggerevent('ue_xls_export')
end event

type cb_fy from uo_imflatbutton within w_taobao_directsend
integer x = 1056
integer width = 151
integer height = 164
integer taborder = 50
boolean bringtotop = true
string text = "运费"
string normalpicname = "imexport.BMP"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;IF Not uo_power_spi.uf_power_ind(3795,sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF


m_Dfc_Control_PopupMenu dmPopupMenu
String menustr

menustr = "Text=按运输单号录入~tEvent=ue_input_fy"
menustr = menustr + "|" + "Text=按顺序录入~tEvent=ue_input_fy_order"
menustr = menustr + "|" + "Text=xls导入~tEvent=ue_import_fy_xls"

IF Len(Trim(menustr)) <> 0 THEN
	dmPopupMenu = Create m_Dfc_Control_PopupMenu
	dmPopupMenu.mf_BuildMenu(This, menustr)
	dmPopupMenu.mf_PopMenu()
	Destroy dmPopupMenu
END IF

end event

type cb_print_dir from uo_imflatbutton within w_taobao_directsend
integer x = 466
integer width = 274
integer height = 164
integer taborder = 40
boolean bringtotop = true
string text = "多选打印"
string normalpicname = "print.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;String ls_dft_old_dwname, ls_dft_new_dwname,ls_chnname,ls_dwtype
Long ls_dwprintid
String ls_windowname
Int ls_i
Long ll_billid
Int li_ifuse
Long ll_row
String Name,ll_rpname
Long ll_RpID,ll_flag,ll_ifuse

ins_print_flag = True
ins_print_hz = False
w_curwin = Parent
ls_windowname = Parent.ClassName ( )

SELECT billid,ifuse
	INTO :ll_billid,
	:li_ifuse
	FROM u_report_bill
	Where winName = :ls_windowname;
IF sqlca.SQLCode <> 0 THEN
	li_ifuse = 0
END IF

IF li_ifuse = 0 THEN
	DECLARE dft_dwprint CURSOR FOR
		SELECT dwprintid,dft_old_dwname, dft_new_dwname, chnname, dwtype
		FROM sys_dft_dwprint_dynamic
		WHERE dwtype = :ls_windowname
		And ptype = 0;
		
	OPEN dft_dwprint;
	FETCH dft_dwprint Into  :ls_dwprintid,:ls_dft_old_dwname, :ls_dft_new_dwname,:ls_chnname, :ls_dwtype;
	IF sqlca.SQLCode <> 0 THEN
		Parent.TriggerEvent('ue_print',0,0)
	ELSE
		m_dft_dwprint_print_item m_1
		m_1 = Create m_dft_dwprint_print_item
		ls_i = 1
		DO WHILE sqlca.SQLCode = 0
			f_add_menuitem_print_dft(m_1,ls_i,ls_chnname,String(ls_dwprintid))
			FETCH dft_dwprint Into  :ls_dwprintid,:ls_dft_old_dwname, :ls_dft_new_dwname,:ls_chnname, :ls_dwtype;
			ls_i++
		LOOP
		CLOSE dft_dwprint;
		m_1.PopMenu(This.X+50,This.Y+50)
	END IF
ELSE
	DECLARE rpt_dwprint CURSOR FOR
		SELECT RpID,RpName,Flag,Ifuse
		FROM U_report_list
		WHERE billid = :ll_billid
		Order By RpName;
		
	OPEN rpt_dwprint;
	FETCH rpt_dwprint Into  :ll_RpID,:ll_rpname,:ll_flag,:ll_ifuse;
	IF sqlca.SQLCode <> 0 THEN
		Parent.TriggerEvent('ue_print',0,0)
	ELSE
		m_rpt_dwprint_print_item m_2
		m_2 = Create m_rpt_dwprint_print_item
		ls_i = 1
		DO WHILE sqlca.SQLCode = 0
			
			IF ll_ifuse = 1 And ll_flag = 1 And f_pow_rpt(ll_RpID) THEN //需添加权限
				f_add_menuItem_print_rpt(m_2,ls_i,ll_rpname,String(ll_RpID))
			END IF
			
			FETCH rpt_dwprint Into   :ll_RpID,:ll_rpname,:ll_flag,:ll_ifuse;
			ls_i++
		LOOP
		CLOSE rpt_dwprint;
		m_2.Item[1].Visible = False
		m_2.PopMenu(This.X+50,This.Y+50)
		
	END IF
END IF



end event

type cb_amt_edit from uo_imflatbutton within w_taobao_directsend
integer x = 1211
integer width = 151
integer height = 164
integer taborder = 80
boolean bringtotop = true
string text = "修改"
string normalpicname = "OPEN.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;IF Not uo_power_spi.uf_power_ind(3793,sys_msg_pow) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

String arg_msg
IF dw_amt_edit_mode THEN
	
	IF dw_1.AcceptText() <> 1 THEN RETURN
	
	IF wf_save_amt(arg_msg) <> 1 THEN
		MessageBox('错误', arg_msg)
		RETURN
	END IF
END IF

dw_amt_edit_mode = Not dw_amt_edit_mode
IF dw_amt_edit_mode THEN
	cbx_1.Checked = True
	wf_selectall()
ELSE
	cb_reflash.TriggerEvent(Clicked!)
END IF
wf_face()


end event

type cb_amt_cancel from uo_imflatbutton within w_taobao_directsend
integer x = 1367
integer width = 151
integer height = 164
integer taborder = 70
boolean bringtotop = true
string text = "放弃"
string normalpicname = "Undo.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;String ls_msg
IF dw_amt_edit_mode THEN
	dw_amt_edit_mode = Not dw_amt_edit_mode
	cb_reflash.TriggerEvent(Clicked!)
	wf_face()
END IF



end event

type ln_bar from line within w_taobao_directsend
long linecolor = 268435456
integer linethickness = 4
integer beginy = 280
integer endx = 2007
integer endy = 280
end type

type ln_bar2 from line within w_taobao_directsend
long linecolor = 16777215
integer linethickness = 4
integer beginy = 284
integer endx = 2039
integer endy = 284
end type

type r_bar from rectangle within w_taobao_directsend
long linecolor = 16777215
integer linethickness = 4
long fillcolor = 1073741824
integer x = 1874
integer width = 146
integer height = 68
end type

event constructor;this.fillcolor = 14215660
this.linecolor = 14215660
this.x = -1
this.y = -1
this.height = ln_bar.beginy - 5

end event

type ln_1 from line within w_taobao_directsend
long linecolor = 268435456
integer linethickness = 4
integer beginy = 168
integer endx = 2007
integer endy = 168
end type

type ln_2 from line within w_taobao_directsend
long linecolor = 16777215
integer linethickness = 4
integer beginy = 172
integer endx = 2039
integer endy = 172
end type