Q5/ws_objects/Ew_machining.pbl.src/w_updatecost_wfjg.srw

$PBExportHeader$w_updatecost_wfjg.srw
forward
global type w_updatecost_wfjg from w_publ_1ton_share_detail
end type
type ddlb_status from dropdownlistbox within w_updatecost_wfjg
end type
type st_3 from statictext within w_updatecost_wfjg
end type
end forward

global type w_updatecost_wfjg from w_publ_1ton_share_detail
string title = "外协商库存成本价调整单"
boolean maxbox = true
windowstate windowstate = maximized!
long dw_child_w = 49876184
event insert_childrow ( )
event ue_import_planprice ( )
event ue_import_saleprice ( )
event ue_import_newprice ( )
ddlb_status ddlb_status
st_3 st_3
end type
global w_updatecost_wfjg w_updatecost_wfjg

type variables

int cur_flag=-1
uo_update_cost_wfjg  uo_ware

string ol_cdw_str = ''
long cur_scid
end variables

forward prototypes
public function integer wf_flagstatus_rf ()
public function integer wf_refresh_curuc (long arg_billid)
end prototypes

event insert_childrow();long li_row
li_row=dw_child.insertrow(0)
dw_child.scrolltorow(li_row)
dw_child.SetColumn ('u_mtrldef_mtrlcode')	
end event

event ue_import_planprice();IF NOT dw_edit_mode THEN
	MessageBox('系统提示',"非编辑状态下不可以使用!")
	RETURN
END IF

Long ls_row,ls_mtrlid
String ls_mtrlcode,ls_status,ls_woodcode,ls_pcode
Decimal ld_planprice
Int li_statusflag

IF MessageBox ('询问',"是否直接导入物料计划价?",Question!,YesNo! ) = 2 THEN RETURN

FOR ls_row = 1 TO dw_child.RowCount()
	ls_mtrlid = dw_child.Object.u_updatecostmx_wfjg_mtrlid[ls_row]
	ls_mtrlcode = dw_child.Object.u_mtrldef_mtrlcode[ls_row]
	ls_status = dw_child.Object.u_updatecostmx_wfjg_status[ls_row]
	ls_woodcode = dw_child.Object.u_updatecostmx_wfjg_woodcode[ls_row]
	ls_pcode = dw_child.Object.u_updatecostmx_wfjg_pcode[ls_row]
	
	
	
	SELECT planprice,statusflag
		INTO :ld_planprice,:li_statusflag
		FROM u_mtrldef
		Where mtrlid = :ls_mtrlid;
	IF sqlca.SQLCode <> 0 THEN
		MessageBox('提示','查询物料:'+ls_mtrlcode+'计划价失败')
		RETURN
	END IF
	ld_planprice = f_get_planprice(ls_mtrlid,ls_status,ls_woodcode,ls_pcode,true)
	dw_child.Object.u_updatecostmx_wfjg_newcost[ls_row] = ld_planprice
	
NEXT
end event

event ue_import_saleprice();IF NOT dw_edit_mode THEN
	MessageBox('系统提示',"非编辑状态下不可以使用!")
	return
END IF

Long ls_row,ls_mtrlid
String ls_status,ls_pcode,ls_woodcode,ls_mtrlcode
Decimal obj_price 
String err_str = ''
s_pricelist_ch s_pricelist
String arg_msg


IF MessageBox (publ_operator,"是否直接选择价格表?",Question!,YesNo! ) = 2 THEN RETURN
Open(w_sale_price_list_ch)
s_pricelist = Message.PowerObjectParm
IF s_pricelist.pricelistid <= 0 THEN RETURN
FOR ls_row = 1 TO dw_child.RowCount()
	ls_mtrlid = dw_child.Object.u_updatecostmx_wfjg_mtrlid[ls_row]
	ls_mtrlcode = dw_child.Object.u_mtrldef_mtrlcode[ls_row]
	ls_status = dw_child.Object.u_updatecostmx_wfjg_status[ls_row]
	ls_woodcode = dw_child.Object.u_updatecostmx_wfjg_woodcode[ls_row]
	ls_pcode = dw_child.Object.u_updatecostmx_wfjg_pcode[ls_row]
	
	
	IF sys_option_price_if_status = 0 THEN
		ls_status = ''
		ls_pcode = ''
		ls_woodcode = ''
	END IF
	
	          
	SELECT u_sale_price_mx.price
		INTO :obj_price
		FROM u_sale_price_mx
		WHERE (u_sale_price_mx.pricelistid = :s_pricelist.pricelistid) AND
		( u_sale_price_mx.mtrlid = :ls_mtrlid ) AND
		( u_sale_price_mx.status = :ls_status ) AND
		( u_sale_price_mx.pcode = :ls_pcode ) AND
		( u_sale_price_mx.woodcode = :ls_woodcode );
	IF sqlca.SQLCode <> 0 THEN
		err_str = err_str + "当前价格表的:"+ls_mtrlcode+" 的售价尚未设定! ~n"
	ELSE
		dw_child.Object.u_updatecostmx_wfjg_newcost[ls_row] = obj_price
	END IF
NEXT

IF err_str <> '' THEN
	MessageBox('系统提示',err_str)
END IF


end event

event ue_import_newprice();IF NOT dw_edit_mode THEN
	MessageBox('系统提示',"非编辑状态下不可以使用!")
	RETURN
END IF

Long ls_row,ls_mtrlid
String ls_mtrlcode
Decimal ld_newprice



IF MessageBox (publ_operator,"是否直接导入物料最新购价?",Question!,YesNo! ) = 2 THEN RETURN

FOR ls_row = 1 TO dw_child.RowCount()
	ls_mtrlid = dw_child.Object.u_updatecostmx_wfjg_mtrlid[ls_row]
	ls_mtrlcode = dw_child.Object.u_mtrldef_mtrlcode[ls_row]
	
	SELECT price INTO :ld_newprice
		FROM v_maxprice_sptprice
		Where mtrlid = :ls_mtrlid;
	IF sqlca.SQLCode <> 0 THEN
		MessageBox('提示','查询物料:'+ls_mtrlcode+'最新购价失败')
		RETURN
	END IF
	
	dw_child.Object.u_updatecostmx_wfjg_newcost[ls_row] = ld_newprice 

NEXT




end event

public function integer wf_flagstatus_rf ();Long pagerert_row

pagerert_row = dw_pageretr.GetRow()
IF pagerert_row <= 0 THEN
	cb_auditing.Enabled = FALSE
	GOTO ext
END IF

IF dw_edit_mode THEN
	cb_auditing.Enabled = FALSE
ELSE
	IF dw_pageretr.Object.u_updatecost_wfjg_flag[pagerert_row] = 0 THEN
		cb_auditing.Enabled = TRUE
	ELSEIF dw_pageretr.Object.u_updatecost_wfjg_flag[pagerert_row] = 1 THEN
		cb_auditing.Enabled = FALSE
	END IF
END IF

ext:
RETURN 0

end function

public function integer wf_refresh_curuc (long arg_billid);IF arg_billid <= 0 OR IsNull(arg_billid) THEN RETURN 0
Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN RETURN 0

Long billid
String sptcode
DateTime billdate
String rep
String relcode
String dscrp
Long sptid
String sptname
String billcode
DateTime opdate
DateTime moddate
DateTime auditingdate
String opemp
String modemp
String auditingrep
Long flag
Long ll_printnum

SELECT u_updatecost_wfjg.billid,
	u_spt.sptcode,
	u_updatecost_wfjg.billdate,
	u_updatecost_wfjg.rep,
	u_updatecost_wfjg.relcode,
	u_updatecost_wfjg.dscrp,
	u_updatecost_wfjg.sptid,
	u_spt.name,
	u_updatecost_wfjg.billcode,
	u_updatecost_wfjg.opdate,
	u_updatecost_wfjg.moddate,
	u_updatecost_wfjg.auditingdate,
	u_updatecost_wfjg.opemp,
	u_updatecost_wfjg.modemp,
	u_updatecost_wfjg.auditingrep,
	u_updatecost_wfjg.flag,
	u_updatecost_wfjg.printnum
	INTO
	:billid,
	:sptcode,
	:billdate,
	:rep,
	:relcode,
	:dscrp,
	:sptid,
	:sptname,
	:billcode,
	:opdate,
	:moddate,
	:auditingdate,
	:opemp,
	:modemp,
	:auditingrep,
	:flag,
	:ll_printnum
	FROM u_updatecost_wfjg INNER JOIN
	u_spt ON u_updatecost_wfjg.sptid = u_spt.sptid
	Where ( u_updatecost_wfjg.billid = :arg_billid );
IF sqlca.SQLCode <> 0 THEN
	MessageBox('系统提示',"查询操作失败(错误单据唯一码)")
	RETURN 0
END IF

dw_pageretr.Object.u_updatecost_wfjg_billid[uc_row] = billid
dw_pageretr.Object.u_spt_sptcode[uc_row] = sptcode
dw_pageretr.Object.u_updatecost_wfjg_billdate[uc_row] = billdate
dw_pageretr.Object.u_updatecost_wfjg_rep[uc_row] = rep
dw_pageretr.Object.u_updatecost_wfjg_relcode[uc_row] = relcode
dw_pageretr.Object.u_updatecost_wfjg_dscrp[uc_row] = dscrp
dw_pageretr.Object.u_updatecost_wfjg_sptid[uc_row] = sptid
dw_pageretr.Object.u_spt_name[uc_row] = sptname
dw_pageretr.Object.u_updatecost_wfjg_billcode[uc_row] = billcode
dw_pageretr.Object.u_updatecost_wfjg_opdate[uc_row] = opdate
dw_pageretr.Object.u_updatecost_wfjg_moddate[uc_row] = moddate
dw_pageretr.Object.u_updatecost_wfjg_auditingdate[uc_row] = auditingdate
dw_pageretr.Object.u_updatecost_wfjg_opemp[uc_row] = opemp
dw_pageretr.Object.u_updatecost_wfjg_modemp[uc_row] = modemp
dw_pageretr.Object.u_updatecost_wfjg_auditingrep[uc_row] = auditingrep
dw_pageretr.Object.u_updatecost_wfjg_flag[uc_row] = flag
dw_pageretr.Object.u_updatecost_wfjg_printnum[uc_row] = ll_printnum

dw_uc.Reset()
dw_pageretr.RowsCopy(dw_pageretr.GetRow(), dw_pageretr.GetRow(), Primary!, dw_uc, 1, Primary!)


dw_uc.ResetUpdate()
dw_uc.SetRedraw(TRUE)

wf_flagstatus_rf()
RETURN 1



end function

on w_updatecost_wfjg.create
int iCurrent
call super::create
this.ddlb_status=create ddlb_status
this.st_3=create st_3
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.ddlb_status
this.Control[iCurrent+2]=this.st_3
end on

on w_updatecost_wfjg.destroy
call super::destroy
destroy(this.ddlb_status)
destroy(this.st_3)
end on

event retrieve_pageretr;Boolean cb_nextpage_enabled,cb_retrieveall_enabled
Boolean cb_func_enabled,cb_retrieve_enabled

cb_nextpage_enabled = cb_nextpage.Enabled
cb_retrieveall_enabled = cb_retrieveall.Enabled
cb_func_enabled = cb_func.Enabled

cb_nextpage.Enabled = FALSE
cb_retrieveall.Enabled = FALSE
cb_func.Enabled = FALSE


dw_uc.Retrieve()
wf_flagstatus_rf()
dw_pageretr.Retrieve(cur_flag,sys_user_spttype)
IF dw_pageretr.RowCount() > 0 THEN 
	dw_pageretr.SetRow(1)
	dw_pageretr.triggerevent(rowfocuschanged!)
end if

THIS.TriggerEvent('retrieve_childdw')

cb_nextpage.Enabled = cb_nextpage_enabled
cb_retrieveall.Enabled = cb_retrieveall_enabled
cb_func.Enabled = cb_func_enabled



end event

event ue_usual_query_filt;call super::ue_usual_query_filt;string obj_expr=''  
if trim(sle_usual_query.text)<>'' then 
	IF POS(trim(sle_usual_query.text),'%')=0 THEN
		obj_expr=obj_expr+'( u_updatecost_wfjg_billcode LIKE "%'+trim(sle_usual_query.text)+'%" )'
	ELSE
		obj_expr=obj_expr+'( u_updatecost_wfjg_billcode LIKE "'+trim(sle_usual_query.text)+'" )'
	END IF 
end if

dw_pageretr.setfilter(obj_expr)

dw_pageretr.SetRedraw(False)
dw_pageretr.filter()
if dw_pageretr.rowcount()>=1 then
	dw_pageretr.selectrow(0,false)
	dw_pageretr.selectrow(1,true)
end if
dw_pageretr.SetRedraw(TRUE)
end event

event ue_usual_query_retr;call super::ue_usual_query_retr;String ls_querystrpart = ''
ls_newselect = Lower(ori_oldselect)
IF Trim(sle_usual_query.Text) <> '' THEN
	IF Pos(Trim(sle_usual_query.Text),'%') = 0 THEN
		ls_querystrpart = "(u_updatecost_wfjg.billcode like '%"+Trim(sle_usual_query.Text)+"%')"
	ELSE
		ls_querystrpart = "(u_updatecost_wfjg.billcode like '"+Trim(sle_usual_query.Text)+"')"
	END IF
	
	IF Pos(ls_newselect," where ") <> 0 THEN
		ls_newselect = ls_newselect+" AND ("+ls_querystrpart+')'
	ELSE
		ls_newselect = ls_newselect+" where ("+ls_querystrpart+')'
	END IF
END IF
wf_retrieveuc(dw_pageretr,ls_newselect,1)
THIS.TriggerEvent('retrieve_pageretr')


end event

event refresh_interface;call super::refresh_interface;wf_flagstatus_rf()
ddlb_status.enabled=not dw_edit_mode
//if dw_edit_mode then
//	ddlb_scid.enabled=false
//else
//	if sys_scid > 0 then
//		ddlb_scid.enabled=false
//	else
//		ddlb_scid.enabled=true
//	end if
//end if


end event

event close;call super::close;destroy uo_ware
end event

event ue_f8;call super::ue_f8;//用于选择明细内容,被F8[默认]\dw_child.doubleclicked调用
IF NOT dw_edit_mode THEN RETURN
Long child_row,ins_sptid = 0

ins_sptid = dw_uc.Object.u_updatecost_wfjg_sptid[dw_uc.GetRow()]
IF ins_sptid = 0 OR IsNull(ins_sptid) THEN
	MessageBox(publ_operator,'请先选择供应商')
	RETURN
END IF

child_row = dw_child.GetRow()

IF NOT IsValid(w_sptware_sptid_ch) THEN
	s_edit_index_tran s_tranf8 //传递参数使用
	s_tranf8.if_retrieve_all = FALSE  //是否一次RETRIEVE所有行
	s_tranf8.arg_pkid = 0             //目标定位PKID (备用)
	s_tranf8.arg_string_code = ''     //查询列(物料编码)部分内容,用于初步筛选 
	s_tranf8.b_long = - 1           //选择原料或产品
	s_tranf8.d_long = ins_sptid
	s_tranf8.e_long = -1	
	s_tranf8.f_long =-1
	Long chc = 1,ls_j
	
	dw_child.AcceptText()
	IF dw_child.GetRow() > 0 THEN s_tranf8.arg_string_code = Trim(dw_child.Object.u_mtrldef_mtrlcode[dw_child.GetRow()])
	OpenWithParm(w_sptware_sptid_ch,s_tranf8) //调用
	
	s_sptware_array S_INSCUST
	S_INSCUST = Message.PowerObjectParm //接受返回结构
	
	FOR ls_j = 1 TO  UpperBound(S_INSCUST.mtrlwareid)
		IF S_INSCUST.mtrlwareid[ls_j] > 0 THEN
			IF dw_child.GetRow() > 0 THEN
				IF dw_child.Object.u_updatecostmx_wfjg_mtrlid[child_row] <> 0 THEN
					child_row = dw_child.InsertRow (0)
				ELSE
					child_row = dw_child.GetRow()
				END IF
			ELSE
				child_row = dw_child.InsertRow (0)
			END IF
			
			dw_child.Object.u_updatecostmx_wfjg_mtrlwareid[child_row] = S_INSCUST.mtrlwareid[ls_j]
			dw_child.Object.u_updatecostmx_wfjg_mtrlid[child_row] = S_INSCUST.mtrlid[ls_j]
			dw_child.Object.u_mtrldef_mtrlcode[child_row]    = S_INSCUST.u_mtrldef_mtrlcode[ls_j]
			dw_child.Object.u_mtrldef_mtrlname[child_row]    = S_INSCUST.u_mtrldef_mtrlname[ls_j]
			dw_child.Object.u_mtrldef_mtrlmode[child_row]    = S_INSCUST.u_mtrldef_mtrlmode[ls_j]
			dw_child.Object.u_mtrldef_unit[child_row]        = S_INSCUST.u_mtrldef_unit[ls_j]
//			dw_child.Object.u_mtrldef_mtrlsectype[child_row]    = S_INSCUST.u_mtrldef_mtrlsectype[ls_j]
//			dw_child.Object.u_mtrldef_zxmtrlmode[child_row]    = S_INSCUST.u_mtrldef_zxmtrlmode[ls_j]
			
			dw_child.Object.u_updatecostmx_wfjg_noallocqty[child_row]       = S_INSCUST.noallocqty[ls_j]
			dw_child.Object.u_updatecostmx_wfjg_cost[child_row]     = S_INSCUST.cost[ls_j]
			dw_child.Object.u_updatecostmx_wfjg_plancode[child_row] = S_INSCUST.plancode[ls_j]
			
			dw_child.Object.u_updatecostmx_wfjg_status[child_row] = S_INSCUST.status[ls_j]
			dw_child.Object.u_updatecostmx_wfjg_woodcode[child_row]  = S_INSCUST.woodcode[ls_j]
			dw_child.Object.u_updatecostmx_wfjg_pcode[child_row]  = S_INSCUST.pcode[ls_j]
			
			dw_child.SetColumn('u_updatecostmx_wfjg_newcost')
		END IF
	NEXT
END IF


end event

event retrieve_childdw;call super::retrieve_childdw;Long row,uc_relid
row = dw_pageretr.GetRow()

IF row > 0 THEN
	uc_relid = dw_pageretr.Object.u_updatecost_wfjg_billid[row]
	dw_child.SetRedraw (FALSE)
	dw_child.Retrieve(uc_relid)
	dw_child.SetRedraw (TRUE)
ELSE
	dw_child.Reset()
END IF


end event

event open;THIS.TriggerEvent('ue_before_open')
wf_movetocenter()

OLD_TITLE = THIS.Title

s_tran = Message.PowerObjectParm
IF NOT IsNull(s_tran) THEN
	retrieve_all = s_tran.if_retrieve_all
	mode = s_tran.work_mode
	arg_pkid = s_tran.arg_pkid
	arg_string_code = s_tran.arg_string_code
	if_sharedata = s_tran.if_sharedata //是否应用sharedata，当retrieve_all＝true是生效
	ds_share = s_tran.ds_share
END IF

dw_pageretr.RBUTTON_FILTER_USE = TRUE //右键查询功能开关
dw_pageretr.titleclick_sort_use = TRUE  //单击标题排序功能开关

dw_pageretr.SetTransObject (sqlca)
pkcolumndbtname = wf_get_pkcolumndbtname(dw_pageretr) //取第一列为关键字

ori_oldselect = dw_pageretr.Describe("DataWindow.Table.Select")

ls_newselect = ori_oldselect
ds_curquery = CREATE DATASTORE
ds_curquery.DataObject = 'd_extr_find'
ds_curquery.SetTransObject (sqlca)

wf_editindex_lockf()

sle_usual_query.Text = Trim(arg_string_code)
IF NOT retrieve_all THEN
	THIS.TriggerEvent("ue_usual_query_RETR") //修改ls_newselect,retrieve
ELSE
	IF  if_sharedata THEN
		ds_share.ShareData(dw_pageretr)
	ELSE
		wf_retrieveuc(dw_pageretr,ls_newselect,1)
		THIS.TriggerEvent('RETRIEVE_pageretr')
	END IF
END IF

IF retrieve_all THEN
	THIS.TriggerEvent("ue_usual_query_filt")
END IF



uc_column_int = 6 //uc dw前6列可以编辑
child_column_int = 3 //子dw前8列可以编辑
uo_ware = CREATE uo_update_cost_wfjg
uo_ware.commit_transaction = sqlca


end event

event ue_addzy;call super::ue_addzy;IF dw_edit_mode THEN
	MessageBox('系统提示',"编辑状态下不可以使用!")
	RETURN
END IF

IF NOT f_power_ind(1670) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

String arg_msg = ''
String ls_str
Long uc_row
s_inputbox s_sreu

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('系统提示','请选定当前目标单据!')
	RETURN
END IF
s_sreu.Title = '请输入要补充到备注的内容'
s_sreu.old_text = ''
OpenWithParm(w_inputbox,s_sreu)
ls_str = Message.StringParm
IF Trim(ls_str) = '' OR IsNull(ls_str) THEN RETURN

IF uo_ware.add_dscrp(dw_pageretr.Object.u_updatecost_wfjg_billid[uc_row],ls_str,arg_msg) = 0 THEN
	MessageBox('error!',arg_msg)
	RETURN
ELSE
	MessageBox(publ_operator,'添加备注操作成功!')
	wf_refresh_curuc(dw_pageretr.Object.u_updatecost_wfjg_billid[uc_row])
END IF


end event

event ue_viewprint;call super::ue_viewprint;
Long LS_ROW
Long ll_funcid = 1671
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('NO','没有打印目标单据!')
	RETURN
END IF

S_print_MSG LS_PRMSG

IF ls_powerid = 0 THEN
	ls_powerid = ll_funcid
END IF

IF ls_newname <> '' THEN
	IF NOT f_power_ind(ls_powerid) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF
	
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('NO','目标单据还未审核,不能打印!')
			RETURN
		END IF
	END IF
	
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	IF NOT f_power_ind(ll_funcid) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF
	
	LS_PRMSG.obj_dwNAME = 'dw_rp_updatecost_wfjg_edit'
END IF

IF LS_PRMSG.obj_dwNAME = '' THEN RETURN

LS_PRMSG.printrow = ll_prownum
LS_PRMSG.TAG_TEXT = '外协商库存成本价调整单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.retr_pram_falg = 2
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_updatecost_wfjg_billid[LS_ROW]
LS_PRMSG.rowcnt = dw_child.RowCount()
OpenWithParm(w_publ_preview,LS_PRMSG)

//更新打印次数
String arg_msg
printnum = Message.DoubleParm
Long ll_scid
String ls_code

ll_scid = 0
ls_code = dw_pageretr.Object.u_updatecost_wfjg_billcode[dw_pageretr.GetRow()]

//f_update_printnum(ll_scid,ls_code,FALSE,printnum,arg_msg,TRUE)

end event

event ue_print;call super::ue_print;//--直接打印
uo_print_preview uo_print
IF MessageBox ("IF","是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN


S_print_MSG LS_PRMSG

Long LS_ROW
Long ll_funcid = 1671
LS_ROW = dw_pageretr.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('NO','没有打印目标单据!')
	RETURN
END IF

IF ls_powerid = 0 THEN
	ls_powerid = ll_funcid
END IF

IF ls_newname <> '' THEN
	IF Not f_power_ind(ls_powerid) THEN
		MessageBox(publ_operator,sys_msg_pow)
		RETURN
	END IF
	
	IF li_auditprint = 1 THEN
		IF dw_pageretr.Object.u_updatecost_wfjg_flag[dw_pageretr.GetRow()] = 0 THEN
			MessageBox('NO','目标单据还未审核,不能打印!')
			RETURN
		END IF
	END IF
	
	LS_PRMSG.obj_dwNAME = ls_newname
ELSE
	
	IF Not f_power_ind(ll_funcid) THEN
		MessageBox(publ_operator,sys_msg_pow)
		RETURN
	END IF
	
	LS_PRMSG.obj_dwNAME = 'dw_rp_updatecost_wfjg_edit'
END IF

IF LS_PRMSG.obj_dwNAME = '' THEN RETURN

LS_PRMSG.retr_pram_falg = 2
LS_PRMSG.printrow = ll_prownum
LS_PRMSG.TAG_TEXT = '外协商库存成本价调整单'
LS_PRMSG.FILTER_STRING = ''
LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_updatecost_wfjg_billid[LS_ROW]
LS_PRMSG.rowcnt = dw_child.RowCount()
uo_print.FACT_PRINT_MSG = LS_PRMSG


String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("系统提示",arg_msg)
	RETURN
END IF
uo_print.ds_print()

//更新打印次数
printnum = 1
Long ll_scid
String ls_code

ll_scid = 0
ls_code = dw_pageretr.Object.u_updatecost_wfjg_billcode[dw_pageretr.GetRow()]

//f_update_printnum(ll_scid,ls_code,FALSE,printnum,arg_msg,TRUE)



end event

event ue_rpt_viewprint;call super::ue_rpt_viewprint;Long row,uc_relid,ll_scid
row = dw_pageretr.GetRow()
IF row = 0 THEN RETURN


IF ls_rpname = '' THEN RETURN

IF li_auditprint = 1 THEN
	IF dw_pageretr.Object.u_updatecost_wfjg_flag[row] = 0 THEN
		MessageBox('NO','目标单据还未审核,不能打印!')
		RETURN
	END IF
END IF

s_rpt_print_msg s_print
s_print.retr_pram_falg = 2
s_print.rpid = ls_msgprintid_rpt
s_print.retr_flag = TRUE
s_print.tag_text = THIS.Title

s_print.rpname  = ls_rpname
s_print.retr_pramnmb = dw_pageretr.Object.u_updatecost_wfjg_billid[row]
s_print.rowcnt = dw_child.RowCount()
OpenWithParm(w_rpt_preview,s_print)

//**更新打印次料
String arg_msg
printnum = Message.DoubleParm

String ls_code

ll_scid = 0
ls_code = dw_pageretr.Object.u_updatecost_wfjg_billcode[row]

//f_update_printnum(ll_scid,ls_code,TRUE,printnum,arg_msg,TRUE)


end event

event ue_rpt_print;call super::ue_rpt_print;Long row,uc_relid,ll_scid
row = dw_pageretr.GetRow()
IF row = 0 THEN RETURN


uo_rpt_print_preview uo_print
S_rpt_print_MSG LS_PRMSG

IF dw_pageretr.RowCount() = 0 THEN
	MessageBox('系统信息','没有可打印的单据！')
	RETURN
END IF

IF ls_rpname = '' THEN RETURN

IF li_auditprint = 1 THEN
	IF dw_pageretr.Object.u_updatecost_wfjg_flag[row] = 0 THEN
		MessageBox('NO','目标单据还未审核,不能打印!')
		RETURN
	END IF
END IF

IF MessageBox ("IF","是否确定要打印当前单据吗?",Question!,YesNo! ) = 2 THEN RETURN

LS_PRMSG.retr_pram_falg = 2
LS_PRMSG.TAG_TEXT = THIS.Title
LS_PRMSG.rpname = ls_rpname
LS_PRMSG.FILTER_STRING = ''

LS_PRMSG.PAGECH_FLAG = 0
LS_PRMSG.rpid = ls_msgprintid_rpt
LS_PRMSG.retr_pramnmb = dw_pageretr.Object.u_updatecost_wfjg_billid[row]
LS_PRMSG.rowcnt = dw_child.RowCount()


uo_print.FACT_PRINT_MSG = LS_PRMSG

String arg_msg
IF uo_print.uof_print_begin(arg_msg) = 0 THEN
	MessageBox("系统提示",arg_msg)
	RETURN
END IF
uo_print.ds_print()


//**更新打印次料
printnum = Message.DoubleParm

String ls_code

ll_scid = 0
ls_code = dw_pageretr.Object.u_updatecost_wfjg_billcode[row]

//f_update_printnum(ll_scid,ls_code,TRUE,printnum,arg_msg,TRUE)

end event

event ue_f9;call super::ue_f9;//用于选择明细内容,被F9[默认]
IF NOT dw_edit_mode THEN RETURN

Long uc_row
Long ll_ori_sptid
Long ll_i
Int li_ifrel


uc_row = dw_uc.GetRow()
IF uc_row = 0 THEN
	MessageBox('系统提示','请选定单据')
	RETURN
END IF



dw_uc.AcceptText()

ll_ori_sptid = dw_uc.Object.u_updatecost_wfjg_sptid[uc_row]


IF NOT IsValid(W_spt_edit) THEN
	s_edit_index_tran s_ch_tran //传递参数使用
	s_ch_tran.if_retrieve_all = FALSE //是否一次RETRIEVE所有行
	s_ch_tran.work_mode = 1 //0-单纯编辑模式 1-选择\编辑模式
	s_ch_tran.arg_pkid = 0 //目标定位PKID (备用)
	//查询列(物料编码)部分内容,用于初步筛选
	s_ch_tran.arg_string_code = Upper(Trim(dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()]))
	
	THIS.Enabled = FALSE
	OpenWithParm(W_spt_edit,s_ch_tran) //调用
	THIS.Enabled = TRUE
	
	S_spt S_INSCUST
	S_INSCUST = Message.PowerObjectParm //接受返回结构
	
	
	
	IF S_INSCUST.sptid > 0 THEN //正常返回值则可以取以下值
		IF S_INSCUST.sptid <> ll_ori_sptid AND ll_ori_sptid <> 0 THEN
			FOR ll_i = 1 TO dw_child.RowCount()
				IF dw_child.Object.u_updatecostmx_wfjg_mtrlwareid[ll_i] > 0 THEN
					li_ifrel = 1
					EXIT
				END IF
			NEXT
			
			IF li_ifrel = 1 THEN
				IF MessageBox('询问','供应商将要改变,明细内容将会清空,是否断续?',Question!,YesNo!) = 2 THEN
					RETURN
				ELSE
					dw_child.Reset()
					dw_child.InsertRow(0)
				END IF
			END IF
		END IF
		
		
		dw_uc.SetRedraw(FALSE)
		dw_uc.Object.u_updatecost_wfjg_sptid[uc_row] = S_INSCUST.sptid
		dw_uc.Object.u_spt_name[uc_row] = S_INSCUST.Name
		dw_uc.Object.u_spt_sptcode[uc_row] = S_INSCUST.sptcode
		dw_uc.SetRedraw(TRUE)
		dw_uc.SetColumn("u_updatecost_wfjg_rep")
	END IF
END IF



end event

type cb_func from w_publ_1ton_share_detail`cb_func within w_updatecost_wfjg
end type

type cb_exit from w_publ_1ton_share_detail`cb_exit within w_updatecost_wfjg
integer x = 2368
end type

type sle_usual_query from w_publ_1ton_share_detail`sle_usual_query within w_updatecost_wfjg
integer x = 183
integer width = 549
end type

type cb_retrieveall from w_publ_1ton_share_detail`cb_retrieveall within w_updatecost_wfjg
integer x = 2839
end type

type em_pagerowno from w_publ_1ton_share_detail`em_pagerowno within w_updatecost_wfjg
integer x = 2519
integer width = 320
end type

type dw_pageretr from w_publ_1ton_share_detail`dw_pageretr within w_updatecost_wfjg
integer x = 1728
integer width = 1815
integer height = 776
string dataobject = "dw_updatecost_wfjg_index"
end type

event dw_pageretr::rowfocuschanged;call super::rowfocuschanged;wf_flagstatus_rf()


end event

type st_1 from w_publ_1ton_share_detail`st_1 within w_updatecost_wfjg
end type

type cb_nextpage from w_publ_1ton_share_detail`cb_nextpage within w_updatecost_wfjg
integer x = 2990
end type

type dw_uc from w_publ_1ton_share_detail`dw_uc within w_updatecost_wfjg
integer width = 1723
integer height = 776
string dataobject = "dw_updatecost_wfjg_edit"
end type

event dw_uc::dwnkey;PARENT.TriggerEvent('user_key')
IF Key = KeyDownArrow! THEN RETURN 1

Long ll_i
Long ll_ori_sptid
String ls_ori_sptcode
Int li_ifrel

li_ifrel = 0

ls_ori_sptcode = dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()]


IF dw_edit_mode THEN
	IF dw_uc.GetColumnName ( ) = 'u_updatecost_wfjg_dscrp'  AND Key = KeyEnter! THEN
		dw_child.SetFocus()
		dw_child.ScrollToRow(1)
		dw_child.SetColumn ('u_mtrldef_mtrlcode')
		RETURN 1
	ELSEIF dw_uc.GetColumnName ( ) = 'u_spt_sptcode' AND Key = KeyEnter! THEN
		String ls_code
		
		dw_uc.AcceptText()
		ls_code = Trim(dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()])
		ll_ori_sptid = dw_uc.Object.u_updatecost_wfjg_sptid[dw_uc.GetRow()]
		
		s_spt arg_s_spt
		
		IF f_find_spt(ls_code,arg_s_spt) = 0 THEN
			PARENT.TriggerEvent('ue_f9')
			RETURN 1
		ELSE
			IF arg_s_spt.sptid <> ll_ori_sptid AND ll_ori_sptid <> 0 THEN
				FOR ll_i = 1 TO dw_child.RowCount()
					IF dw_child.Object.u_updatecostmx_wfjg_mtrlwareid[ll_i] > 0 THEN
						li_ifrel = 1
						EXIT
					END IF
				NEXT
				
				IF li_ifrel = 1 THEN
					IF MessageBox('询问','供应商将要改变,明细内容将清空,是否断续?',Question!,YesNo!) = 2 THEN
						dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()] = ls_ori_sptcode
						RETURN
					ELSE
						dw_child.Reset()
						dw_child.InsertRow(0)
					END IF
				END IF
			END IF
			
			dw_uc.SetRedraw(FALSE)
			dw_uc.Object.u_updatecost_wfjg_sptid[dw_uc.GetRow()] = arg_s_spt.sptid
			dw_uc.Object.u_spt_sptcode[dw_uc.GetRow()] = arg_s_spt.sptcode
			dw_uc.Object.u_spt_name[dw_uc.GetRow()] = arg_s_spt.Name
			
			dw_uc.SetRedraw(TRUE)
			
			dw_uc.SetColumn("u_updatecost_wfjg_rep")
			RETURN 1
		END IF
	ELSE
		IF Key = KeyEnter! THEN //
			keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
			keybd_event ( 9, 0, 2, 0 ) // 释放tab 
			RETURN 1
		END IF
	END IF
END IF


end event

type gb_2 from w_publ_1ton_share_detail`gb_2 within w_updatecost_wfjg
end type

type dw_child from w_publ_1ton_share_detail`dw_child within w_updatecost_wfjg
integer y = 1076
integer width = 3543
integer height = 1104
string dataobject = "dw_updatecostmx_wfjg_edit"
end type

event dw_child::dwnkey;call super::dwnkey;PARENT.TriggerEvent('user_key')

String ls_mtrlcode,ls_mtrlname,ls_unit,ls_mtrlmode
String ls_plancode,ls_woodcode,ls_pcode,ls_status
Long ls_mtrlid,ls_storageid,ll_mtrlwareid,ll_mtrlwarescid
Decimal ls_cost,ls_noallocqty
String ls_mtrlsectype,ls_zxmtrlmode,ls_mtrlcuscode,ls_location
String ls_usermtrlmode
Long child_row
Long ll_sptid

s_sptware_array arg_s_mtrlware

IF dw_edit_mode THEN
	
	dw_uc.AcceptText()
	ll_sptid = dw_uc.Object.u_updatecost_wfjg_sptid[dw_uc.GetRow()]
	IF ll_sptid = 0 OR IsNull(ll_sptid) THEN
		MessageBox(publ_operator,'请先选择供应商')
		RETURN
	END IF
	IF KeyDown(Keydownarrow!) THEN
		Long li_row
		IF dw_child.GetRow() = dw_child.RowCount() THEN
			PARENT.TriggerEvent("insert_childrow")
		END IF
	ELSE
		If (KeyDown(KeyEnter!) OR KeyDown(KeyTab!)) AND NOT KeyDown(KeyControl!) AND NOT KeyDown(KeyShift!)  THEN
			IF dw_child.GetColumnName() = 'u_mtrldef_mtrlcode' THEN
				dw_child.AcceptText()
				child_row = dw_child.GetRow()
				
				ls_mtrlcode = dw_child.Object.u_mtrldef_mtrlcode[child_row]
				
				IF f_find_mtrlware_spt(ls_mtrlcode,ll_sptid,arg_s_mtrlware) = 0 THEN
					PARENT.TriggerEvent('ue_f8')
					RETURN 1
				ELSE
					ll_mtrlwareid = arg_s_mtrlware.mtrlwareid[1]
					ls_mtrlid = arg_s_mtrlware.mtrlid[1]
					ls_mtrlcode = arg_s_mtrlware.u_mtrldef_mtrlcode[1]
					ls_mtrlname = arg_s_mtrlware.u_mtrldef_mtrlname[1]
					ls_unit = arg_s_mtrlware.u_mtrldef_unit[1]
					ls_mtrlmode = arg_s_mtrlware.u_mtrldef_mtrlmode[1]
					ls_noallocqty = arg_s_mtrlware.noallocqty[1]
					ls_plancode = arg_s_mtrlware.plancode[1]
					ls_cost = arg_s_mtrlware.cost[1]
					ls_status = arg_s_mtrlware.status[1]
					ls_woodcode = arg_s_mtrlware.woodcode[1]
					ls_pcode = arg_s_mtrlware.pcode[1]
//					ls_usermtrlmode =  arg_s_mtrlware.u_mtrldef_usermtrlmode[1]
					
					ls_mtrlsectype = arg_s_mtrlware.u_mtrldef_mtrlsectype[1]
					ls_zxmtrlmode = arg_s_mtrlware.u_mtrldef_zxmtrlmode[1]
				END IF
				
				dw_child.Object.u_updatecostmx_wfjg_mtrlwareid[child_row] = ll_mtrlwareid
				dw_child.Object.u_updatecostmx_wfjg_mtrlid[child_row] = ls_mtrlid
				dw_child.Object.u_mtrldef_mtrlcode[child_row]    = ls_mtrlcode
				dw_child.Object.u_mtrldef_mtrlname[child_row]    = ls_mtrlname
				dw_child.Object.u_mtrldef_mtrlmode[child_row]    = ls_mtrlmode
				dw_child.Object.u_mtrldef_unit[child_row]        = ls_unit
				dw_child.Object.u_mtrldef_mtrlsectype[child_row]    = ls_mtrlsectype
				dw_child.Object.u_mtrldef_zxmtrlmode[child_row]    = ls_zxmtrlmode
//				dw_child.Object.u_mtrldef_usermtrlmode[child_row]    = ls_usermtrlmode
				
				dw_child.Object.u_updatecostmx_wfjg_noallocqty[child_row]       = ls_noallocqty
				dw_child.Object.u_updatecostmx_wfjg_cost[child_row]     = ls_cost
				dw_child.Object.u_updatecostmx_wfjg_plancode[child_row] = ls_plancode
				dw_child.Object.u_updatecostmx_wfjg_status[child_row] = ls_status
				
				dw_child.Object.u_updatecostmx_wfjg_woodcode[child_row]  = ls_woodcode
				dw_child.Object.u_updatecostmx_wfjg_pcode[child_row]  = ls_pcode
				
				IF Key = KeyEnter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF
			ELSEIF dw_child.GetColumnName( ) = 'u_updatecostmx_mxdscrp' AND dw_child.GetRow() = dw_child.RowCount() THEN
				PARENT.TriggerEvent("insert_childrow")
				RETURN 1
			ELSE
				IF Key = KeyEnter!  THEN
					keybd_event ( 9, 0, 0 , 0 ) // 按下tab 
					keybd_event ( 9, 0, 2, 0 ) // 释放tab 	
					RETURN 1
				END IF
			END IF
		END IF
	END IF
END IF

//u_mtrldef_mtrlcode
//u_mtrldef_unit
//u_inwaremx_mtrlid
//u_inwaremx_planprice
//u_inwaremx_price
//u_mtrldef_mtrlname










end event

event dw_child::doubleclicked;IF dw_edit_mode THEN
	PARENT.TriggerEvent('ue_f8')
END IF



end event

type cb_viewprint from w_publ_1ton_share_detail`cb_viewprint within w_updatecost_wfjg
integer x = 1723
end type

type cb_print from w_publ_1ton_share_detail`cb_print within w_updatecost_wfjg
integer x = 1531
end type

type cb_add from w_publ_1ton_share_detail`cb_add within w_updatecost_wfjg
end type

event cb_add::clicked;IF NOT f_power_ind(1667) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

String arg_msg = ''
Long uc_row,i

IF dw_edit_mode THEN
	dw_uc.AcceptText()
	dw_child.AcceptText()
	uc_row = dw_uc.GetRow()
	IF uc_row <= 0 THEN
		MessageBox('系统提示','请选定当前目标单据!')
		RETURN
	END IF
	IF NOT dw_uc.Object.u_updatecost_wfjg_billdate[uc_row] > DateTime(2000-01-01,Now()) THEN
		MessageBox('系统提示','不合理发生时间!')
		dw_uc.SetFocus()
		dw_uc.SetColumn("u_updatecost_wfjg_billdate")
		RETURN
	END IF
	IF NOT Len(String(dw_uc.Object.u_updatecost_wfjg_rep[uc_row])) > 0 THEN
		MessageBox('系统提示','请填写经手人!')
		dw_uc.SetFocus()
		dw_uc.SetColumn("u_updatecost_wfjg_rep")
		RETURN
	END IF
	
	uo_ware.billdate = dw_uc.Object.u_updatecost_wfjg_billdate[uc_row] // 发生时间
	uo_ware.rep  = dw_uc.Object.u_updatecost_wfjg_rep[uc_row]      // 经手人
	uo_ware.relcode   = dw_uc.Object.u_updatecost_wfjg_relcode[uc_row]       //相关部门
	uo_ware.dscrp  = dw_uc.Object.u_updatecost_wfjg_dscrp[uc_row]      //备注
	uo_ware.sptid  = dw_uc.Object.u_updatecost_wfjg_sptid[uc_row]
	
	FOR i = 1 TO dw_child.RowCount()
		IF dw_child.Object.u_updatecostmx_wfjg_newcost[i] < 0 THEN
			MessageBox("系统提示","成本价不能为负数!")
			RETURN
		END IF
		
		IF dw_child.Object.u_updatecostmx_wfjg_mtrlid[i] > 0 THEN
			IF uo_ware.acceptmx(i,&
				dw_child.Object.u_updatecostmx_wfjg_mtrlwareid[i],&
				dw_child.Object.u_mtrldef_mtrlcode[i],&
				dw_child.Object.u_updatecostmx_wfjg_newcost[i],&
				dw_child.Object.u_updatecostmx_wfjg_mxdscrp[i],&
				arg_msg) = 0 THEN
				MessageBox('Error!',arg_msg)
				RETURN
			END IF
		END IF
	NEXT
	
	IF uo_ware.Save(TRUE,arg_msg) = 0 THEN
		MessageBox('Error!',arg_msg)
		RETURN
	END IF
	MessageBox(publ_operator,'保存操作成功!')
	//write ini
	long ll_row
	ll_row = dw_pageretr.getrow()
	dw_pageretr.SelectRow(0,FALSE)
	dw_pageretr.SelectRow(ll_row,TRUE)	


	wf_refresh_curuc(uo_ware.billid) //刷新uc
ELSE
	IF uo_ware.newbegin() = 0 THEN //
		MessageBox('Error!',arg_msg)
		RETURN
	END IF
END IF

CALL SUPER::Clicked
//read ini
IF dw_edit_mode THEN
	PARENT.TriggerEvent("insert_childrow")
	dw_uc.SetRedraw(FALSE)

	dw_uc.SetColumn("u_spt_sptcode")
	dw_uc.SetRedraw(TRUE)
ELSE
	PARENT.TriggerEvent("retrieve_childdw")
END IF
//
THIS.TriggerEvent('refresh_interface')


end event

type cb_edit from w_publ_1ton_share_detail`cb_edit within w_updatecost_wfjg
end type

event cb_edit::clicked;IF NOT f_power_ind(1667) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

String arg_msg = ''
Long uc_row

uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('系统提示','请选定当前目标单据!')
	RETURN
END IF

IF NOT dw_edit_mode THEN
	IF uo_ware.updatebegin(dw_pageretr.Object.u_updatecost_wfjg_billid[uc_row],arg_msg) = 0 THEN
		MessageBox('Error!',arg_msg)
		RETURN
	END IF
	
		wf_refresh_curuc(dw_pageretr.Object.u_updatecost_wfjg_billid[uc_row])
	PARENT.TriggerEvent("retrieve_childdw")
	
END IF

CALL SUPER::Clicked

end event

type cb_delet from w_publ_1ton_share_detail`cb_delet within w_updatecost_wfjg
end type

event cb_delet::clicked;call super::clicked;IF NOT f_power_ind(1668) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

String arg_msg = ''

IF dw_edit_mode THEN RETURN

Long uc_row
uc_row = dw_pageretr.GetRow()
IF uc_row <= 0 THEN
	MessageBox('系统提示','请选定当前目标单据!')
	RETURN
END IF
IF MessageBox ("if","是否确定要删除当前单据?",question!,yesno! ) = 2 THEN RETURN


IF uo_ware.del(dw_pageretr.Object.u_updatecost_wfjg_billid[uc_row],arg_msg,TRUE) = 0 THEN
	MessageBox('error!',arg_msg)
ELSE
	//日志
	Long ls_id
	String ls_code
	ls_id = dw_pageretr.Object.u_updatecost_wfjg_billid[uc_row]
	ls_code = dw_pageretr.Object.u_updatecost_wfjg_billcode[uc_row]
	f_setsysoplog('成本价调整单','删除,id:'+String(ls_id)+',code:'+ls_code,arg_msg,TRUE)
	//--
	MessageBox(publ_operator,'删除单据'+String(dw_pageretr.Object.u_updatecost_wfjg_billcode[uc_row])+'成功!')
	
	
	dw_pageretr.DeleteRow(uc_row)
	dw_pageretr.Triggerevent(rowfocuschanged!)
END IF

end event

type cb_addzy from w_publ_1ton_share_detail`cb_addzy within w_updatecost_wfjg
integer x = 1029
end type

event cb_addzy::clicked;call super::clicked;m_Dfc_Control_PopupMenu dmPopupMenu
String menustr

IF NOT dw_edit_mode THEN
	menustr = "Text=增加备注~tEvent=ue_addzy"
END IF
IF Len(Trim(menustr)) <> 0 THEN
	dmPopupMenu = CREATE m_Dfc_Control_PopupMenu
	dmPopupMenu.mf_BuildMenu(THIS, menustr)
	dmPopupMenu.mf_PopMenu()
	DESTROY dmPopupMenu
END IF



end event

type cb_auditing from w_publ_1ton_share_detail`cb_auditing within w_updatecost_wfjg
end type

event cb_auditing::clicked;call super::clicked;IF NOT f_power_ind(1669) THEN
	MessageBox(publ_operator,sys_msg_pow)
	RETURN
END IF

IF dw_edit_mode THEN RETURN
String arg_msg = ''


IF NOT KeyDown(KeyControl!) THEN
	
	Long pagerert_row
	
	pagerert_row = dw_pageretr.GetRow()
	IF pagerert_row <= 0 THEN
		MessageBox('系统提示','请选定当前目标单据!')
		RETURN
	END IF
	IF MessageBox ("if","是否确定要审核当前单据?",question!,yesno! ) = 2 THEN RETURN
		
	IF uo_ware.auditing(dw_pageretr.Object.u_updatecost_wfjg_billid[pagerert_row],TRUE,arg_msg) = 0 THEN
		MessageBox('error!',arg_msg)
	ELSE
		MessageBox(publ_operator,'审核成功!')
		wf_refresh_curuc(dw_pageretr.Object.u_updatecost_wfjg_billid[pagerert_row])
		PARENT.TriggerEvent("retrieve_childdw")
	END IF
ELSE
	IF MessageBox ("if","是否确定要批审核列表中未审核的单据?",question!,yesno! ) = 2 THEN RETURN
	
	Long ll_i,ll_billid
	Int li_flag
	Long ll_suc,ll_fail
	dw_pageretr.AcceptText()
	
	Open(w_sys_wait_jdt) //初始化进度条
	w_sys_wait_jdt.Show()
	w_sys_wait_jdt.wf_accepttol(dw_pageretr.RowCount())
	
	FOR ll_i = 1 TO dw_pageretr.RowCount()
		w_sys_wait_jdt.st_msg.Text = dw_pageretr.Object.warecode[ll_i] + " 正在审核..." //进度信息
		
		li_flag = dw_pageretr.Object.u_updatecost_wfjg_flag[ll_i]
		IF li_flag = 1 THEN CONTINUE
		ll_billid = dw_pageretr.Object.u_updatecost_wfjg_billid[ll_i]

		IF uo_ware.auditing(ll_billid,TRUE,arg_msg) = 0 THEN
			ll_fail++
			CONTINUE  
		END IF
		ll_suc++
		w_sys_wait_jdt.wf_inc(ll_i) //进度
	NEXT
	Close(w_sys_wait_jdt)
	MessageBox(publ_operator,'批审核成功!成功:'+String(ll_suc)+',失败:'+String(ll_fail))
	PARENT.TriggerEvent('retrieve_pageretr')
END IF


end event

type cb_xm from w_publ_1ton_share_detail`cb_xm within w_updatecost_wfjg
integer x = 1280
end type

event cb_xm::clicked;is_mx_menustr = ''
IF dw_edit_mode THEN
	is_mx_menustr = is_mx_menustr + "|" + "Text=导入计划价~tEvent=ue_import_planprice"
	is_mx_menustr = is_mx_menustr + "|" + "Text=导入最新购价~tEvent=ue_import_newprice"
	is_mx_menustr = is_mx_menustr + "|" + "Text=导入价格表~tEvent=ue_import_saleprice"
END IF

CALL SUPER::Clicked

	
end event

type cb_retrieve from w_publ_1ton_share_detail`cb_retrieve within w_updatecost_wfjg
end type

type cb_xls from w_publ_1ton_share_detail`cb_xls within w_updatecost_wfjg
integer x = 1915
end type

type cb_help from w_publ_1ton_share_detail`cb_help within w_updatecost_wfjg
integer x = 2217
end type

type cb_auditing_cancel from w_publ_1ton_share_detail`cb_auditing_cancel within w_updatecost_wfjg
boolean visible = false
integer x = 3131
boolean enabled = false
end type

type p_msg from w_publ_1ton_share_detail`p_msg within w_updatecost_wfjg
end type

type p_help from w_publ_1ton_share_detail`p_help within w_updatecost_wfjg
end type

type p_encl from w_publ_1ton_share_detail`p_encl within w_updatecost_wfjg
end type

type p_other from w_publ_1ton_share_detail`p_other within w_updatecost_wfjg
end type

type gb_3 from w_publ_1ton_share_detail`gb_3 within w_updatecost_wfjg
end type

type ln_bar from w_publ_1ton_share_detail`ln_bar within w_updatecost_wfjg
end type

type ln_bar2 from w_publ_1ton_share_detail`ln_bar2 within w_updatecost_wfjg
end type

type r_bar from w_publ_1ton_share_detail`r_bar within w_updatecost_wfjg
end type

type ln_1 from w_publ_1ton_share_detail`ln_1 within w_updatecost_wfjg
end type

type ln_2 from w_publ_1ton_share_detail`ln_2 within w_updatecost_wfjg
end type

type ddlb_status from dropdownlistbox within w_updatecost_wfjg
integer x = 887
integer y = 192
integer width = 384
integer height = 300
integer taborder = 30
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
string text = "[全部]"
boolean sorted = false
string item[] = {"[全部]","待审核","已审核"}
borderstyle borderstyle = stylelowered!
end type

event selectionchanged;if index=1 then 
	cur_flag=-1
elseif index=2 then 
	cur_flag=0
elseif index=3 then 
	cur_flag=1
end if
parent.triggerevent('retrieve_pageretr')
end event

type st_3 from statictext within w_updatecost_wfjg
integer x = 750
integer y = 204
integer width = 114
integer height = 48
boolean bringtotop = true
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
long textcolor = 33554432
long backcolor = 134217739
string text = "状态"
alignment alignment = center!
boolean focusrectangle = false
end type