$PBExportHeader$w_packet_mtrl_receive_ch.srw
forward
global type w_packet_mtrl_receive_ch from w_publ_choice
end type
end forward 

global type w_packet_mtrl_receive_ch from w_publ_choice
integer width = 3611
integer height = 2080
string title = "资料推送记录选择"
end type
global w_packet_mtrl_receive_ch w_packet_mtrl_receive_ch

type variables
s_packet_ljfieb INS_RT_STRU

Transaction tr_eb_sqlca
end variables

on w_packet_mtrl_receive_ch.create
call super::create
end on

on w_packet_mtrl_receive_ch.destroy
call super::destroy
end on

event open;tr_eb_sqlca = sys_email_sqlca // 电子商务连接

this.triggerevent('ue_before_open')
wf_movetocenter()

if_ue_sort=true
dw_CH.SetTransObject (tr_eb_sqlca) //

cb_retrieve.TRIGGEREVENT(CLICKED!)
end event

event close;call super::close;CLOSEWITHRETURN(THIS,INS_RT_STRU)
end event

type cb_func from w_publ_choice`cb_func within w_packet_mtrl_receive_ch
end type

type cb_exit from w_publ_choice`cb_exit within w_packet_mtrl_receive_ch
end type

event cb_exit::clicked;INS_RT_STRU.sptid = 0
close(parent)
end event

type sle_ch from w_publ_choice`sle_ch within w_packet_mtrl_receive_ch
boolean visible = false
end type

type dw_ch from w_publ_choice`dw_ch within w_packet_mtrl_receive_ch
integer y = 176
integer width = 3589
integer height = 1808
string dataobject = "dw_packet_mtrl_receive_ch"
end type

type st_1 from w_publ_choice`st_1 within w_packet_mtrl_receive_ch
boolean visible = false
end type

type cb_retrieve from w_publ_choice`cb_retrieve within w_packet_mtrl_receive_ch
end type

event cb_retrieve::clicked;Long ll_CusCommID
Long ll_sendcuscommid
Long ll_i
String ls_cuscode,ls_sccode
String ls_sptcode,ls_sptname
Long ll_sptid

SELECT CusCommID
	INTO :ll_CusCommID
	FROM LJFIEB_CusComm
	Where CusType = 0 Using tr_eb_sqlca;
IF tr_eb_sqlca.SQLCode <> 0 THEN
	dw_ch.Reset()
	MessageBox('Error','查询本公司企业编号失败,请先设置,'+tr_eb_sqlca.SQLErrText)
	RETURN
END IF

dw_ch.SetRedraw(False)
dw_ch.Retrieve(ll_CusCommID)

//查询本地数据库得到对应企业信息
dw_ch.AcceptText()
FOR ll_i = 1 To dw_ch.RowCount()
	ll_sendcuscommid = dw_ch.Object.sendcuscommid[ll_i]
	ls_sccode =  dw_ch.Object.sendsccode[ll_i]
	SELECT CusCode
		INTO :ls_cuscode
		FROM LJFIEB_CusComm
		Where CusCommID = :ll_sendcuscommid Using tr_eb_sqlca;
	IF tr_eb_sqlca.SQLCode <> 0 THEN
		ls_cuscode = ''
	END IF
	
	IF Trim(ls_cuscode) <> '' THEN
		SELECT sptid, name, sptcode
			INTO :ll_sptid,:ls_sptname,:ls_sptcode
			FROM u_spt
			WHERE commcode = :ls_cuscode
			And commsccode = :ls_sccode;
		IF sqlca.SQLCode <> 0 THEN
			ll_sptid = 0
			ls_sptname = ''
			ls_sptcode = ''
		END IF
	ELSE
		ll_sptid = 0
		ls_sptname = ''
		ls_sptcode = ''
	END IF
	
	dw_ch.Object.sptid[ll_i] = ll_sptid
	dw_ch.Object.sptcode[ll_i] = ls_sptcode
	dw_ch.Object.sptname[ll_i] = ls_sptname
	dw_ch.Object.cuscode[ll_i] = ls_cuscode
	
	
NEXT

dw_ch.SetRedraw(true)






end event

type cb_choice from w_publ_choice`cb_choice within w_packet_mtrl_receive_ch
end type

event cb_choice::clicked;call super::clicked;dw_ch.AcceptText()

String ls_sn
Long LS_ROW
Long ll_sendcuscommid
LS_ROW = dw_ch.GetRow()
IF LS_ROW <= 0 THEN
	MessageBox('系统提示','请先选择目标行!',StopSign!)
	RETURN
END IF

ll_sendcuscommid = dw_ch.Object.sendcuscommid[LS_ROW]

SELECT top 1 SerialNum
	INTO :ls_sn
	FROM LJFIEB_packet
	WHERE BillType = 9
	AND status = 5
	AND Complete = 0
	AND sendcuscommid = :ll_sendcuscommid
	Order By AddTime Using sys_email_sqlca;
IF sys_email_sqlca.SQLCode <> 0 THEN
	MessageBox('Error','查询最早待处理的同步数据失败,'+sys_email_sqlca.SQLErrText)
	RETURN
END IF

IF ls_sn <> dw_ch.Object.SerialNum[LS_ROW] THEN
	LS_ROW = dw_ch.Find('serialnum = "'+ls_sn+'"',1,dw_ch.RowCount())
	
	IF LS_ROW = 0 THEN 
		messagebox('Error','查找最早同步数据失败')
		RETURN
	end if
	
	MessageBox('系统提示','同一供应商资料同步严格按照推送时间顺序,当前选中的资料不是最早,将自动转到最早的资料作同步')
	
END IF

IF dw_ch.Object.sptid[LS_ROW] = 0 THEN
	MessageBox('系统提示','当前选中记录中的发送企业不明确,请先设置!',StopSign!)
	RETURN
END IF

INS_RT_STRU.sendcuscommid = dw_ch.Object.sendcuscommid[LS_ROW]
INS_RT_STRU.sendsccode = dw_ch.Object.sendsccode[LS_ROW]
INS_RT_STRU.adduser = dw_ch.Object.adduser[LS_ROW]
INS_RT_STRU.AddTime = dw_ch.Object.AddTime[LS_ROW]
INS_RT_STRU.postscript = dw_ch.Object.postscript[LS_ROW]
INS_RT_STRU.remark = dw_ch.Object.remark[LS_ROW]
INS_RT_STRU.SerialNum = dw_ch.Object.SerialNum[LS_ROW]

INS_RT_STRU.tablename = dw_ch.Object.tablename[LS_ROW]
INS_RT_STRU.sptcode = dw_ch.Object.sptcode[LS_ROW]
INS_RT_STRU.sptname = dw_ch.Object.sptname[LS_ROW]
INS_RT_STRU.sptid = dw_ch.Object.sptid[LS_ROW]
INS_RT_STRU.cuscode = dw_ch.Object.cuscode[LS_ROW]

Close(Parent)



end event

type ln_bar from w_publ_choice`ln_bar within w_packet_mtrl_receive_ch
end type

type ln_bar2 from w_publ_choice`ln_bar2 within w_packet_mtrl_receive_ch
end type

type r_bar from w_publ_choice`r_bar within w_packet_mtrl_receive_ch
end type

type ln_1 from w_publ_choice`ln_1 within w_packet_mtrl_receive_ch
boolean visible = false
end type

type ln_2 from w_publ_choice`ln_2 within w_packet_mtrl_receive_ch
boolean visible = false
end type