$PBExportHeader$w_currency_edit.srw
forward
global type w_currency_edit from w_publ_edit_choice
end type
type cb_view from uo_imflatbutton within w_currency_edit
end type
end forward

global type w_currency_edit from w_publ_edit_choice
integer width = 1819
integer height = 1640
string title = "币种"
boolean minbox = true
windowtype windowtype = popup!
boolean if_ue_retr = true
boolean if_ue_filter = true
boolean if_ue_sort = true
boolean if_ue_sentdataout = true
cb_view cb_view
end type
global w_currency_edit w_currency_edit

type variables
s_currency INS_RT_STRU
end variables

on w_currency_edit.create
int iCurrent
call super::create
this.cb_view=create cb_view
iCurrent=UpperBound(this.Control)
this.Control[iCurrent+1]=this.cb_view
end on

on w_currency_edit.destroy
call super::destroy
destroy(this.cb_view)
end on

event close;call super::close;CloseWithReturn(This,INS_RT_STRU)

end event

type cb_func from w_publ_edit_choice`cb_func within w_currency_edit
end type

type cb_exit from w_publ_edit_choice`cb_exit within w_currency_edit
integer x = 987
end type

type cb_add from w_publ_edit_choice`cb_add within w_currency_edit
end type

event cb_add::clicked;call super::clicked;IF NOT f_power_ind(247) THEN
	MessageBox('提示','你没有使用权限！', Information!, OK! )
	RETURN
END IF
Long ll_newid,i
String errmsg
IF dw_edit_mode THEN
	dw_uc.AcceptText()
	IF dw_uc.GetNextModified(0, Primary!) = 0 THEN
		MessageBox('提示','没有任何修改，不可以保存!', Information!, OK! )
		RETURN
	END IF
	dw_uc.Object.code[dw_uc.GetRow()] = Trim(dw_uc.Object.code[dw_uc.GetRow()])
	dw_uc.Object.name[dw_uc.GetRow()] = Trim(dw_uc.Object.name[dw_uc.GetRow()])
		
	
	IF dw_uc.Object.code[dw_uc.GetRow()] = '' THEN
		MessageBox('提示','请输入代号!', Information!, OK! )
		RETURN
	END IF
	
	IF dw_uc.Object.name[dw_uc.GetRow()] = '' THEN
		MessageBox('提示','请输入币种名称!', Information!, OK! )
		RETURN
	END IF
	
	IF dw_uc.Object.rate[dw_uc.GetRow()] = 0 THEN
		MessageBox('提示','请输入币种对人民币汇率!', Information!, OK! )
		RETURN
	END IF
	
	IF dw_uc.Object.moneyid[dw_uc.GetRow()] = 0 THEN
		ll_newid = f_sys_scidentity(0,"cw_currency","moneyid",errmsg,FALSE,sqlca)
		IF ll_newid <= 0 THEN
			MessageBox('提示',errmsg, Information!, OK! )
			RETURN
		ELSE
			dw_uc.Object.moneyid[dw_uc.GetRow()] = ll_newid
		END IF
	END IF
	if dw_uc.object.cmp[1]>1 then
		Messagebox('','本位币已存在,不能设定多个.', Information!, OK! )
		return
	end if
END IF



IF dw_edit_mode THEN
	String ls_errmsg
	IF dw_uc.Update() = -1 THEN
		IF Pos(ins_sqlerrtext,"Cannot insert duplicate key row") > 0 THEN
			ls_errmsg = "关键内容重复"
		ELSE
			ls_errmsg = "因为网络或其他原因>"+ins_sqlerrtext
		END IF
		ROLLBACK;
		MessageBox ('提示',ls_errmsg+",保存操作失败!", Information!, OK! )
		LS_UPDATE_FLAG = FALSE
		RETURN
	ELSE
		COMMIT;
		FOR i = 1 TO 5
			dw_uc.SetTabOrder ( i, 0 )
		NEXT
		LS_UPDATE_FLAG = TRUE
	END IF
	ins_sqlerrtext = ""
ELSE
	Long	li_row, li_cur_row
	li_cur_row = dw_uc.GetRow()
	li_row = dw_uc.InsertRow (0)
	FOR i = 1 TO 5
		dw_uc.SetTabOrder ( i, i*10 )
	NEXT
	dw_uc.SelectRow(0,FALSE)
	dw_uc.ScrollToRow (li_row)
	dw_uc.SelectRow(li_row,TRUE)
	dw_uc.SetFocus()
	modifyrow_no = li_row
END IF

dw_edit_mode = NOT dw_edit_mode
WF_FACE_CHANGE()

end event

type cb_edit from w_publ_edit_choice`cb_edit within w_currency_edit
end type

event cb_edit::clicked;call super::clicked;if not f_power_ind(247) then
	messagebox('提示','你没有使用权限！', Information!, OK! )
	return
end if

Long i
IF dw_edit_mode THEN
	IF dw_uc.GetItemStatus(dw_uc.GetRow(), 0, Primary!) = NewModified! OR dw_uc.GetItemStatus(dw_uc.GetRow(), 0, Primary!) = New! THEN
		dw_uc.DeleteRow(dw_uc.GetRow())
	ELSE
		dw_uc.ReselectRow(dw_uc.GetRow())
	END IF
	FOR i = 1 TO 5
		dw_uc.SetTabOrder ( i, 0 )
	NEXT
	modifyrow_no = 0
ELSE
	modifyrow_no = dw_uc.GetRow()
	FOR i = 1 TO 5
		dw_uc.SetTabOrder ( i, i*10 )
	NEXT
	dw_uc.SetFocus()
	
	dw_uc.SelectRow(0,FALSE)
	dw_uc.ScrollToRow (modifyrow_no)
	dw_uc.SelectRow(modifyrow_no,TRUE)
	
END IF

dw_edit_mode = NOT dw_edit_mode
WF_FACE_CHANGE()

end event

type cb_delet from w_publ_edit_choice`cb_delet within w_currency_edit
end type

event cb_delet::clicked;call super::clicked;if not f_power_ind(24) then
	messagebox('提示','你没有使用权限！', Information!, OK! )
	return
end if

IF MessageBox ('询问',"是否确定要删除当前记录?(选择确定后记录将不可恢复)",Question!,YesNo! ) = 2 THEN
RETURN
END IF 

string arg_msg
long LS_id,LS_LONG
IF DW_UC.GETROW()<=0 THEN 
	MESSAGEBOX('提示','没有操作目标记录!', Information!, OK! )
	RETURN
END IF

LS_id = DW_UC.object.moneyid[DW_UC.GETROW()]

LS_LONG = 0
select COUNT(*) into :LS_LONG from u_saletask where u_saletask.moneyid=:LS_id ;
if SQLCA.SQLCode<>0 and sqlca.sqlcode<>100  then 
	rollback;
	MessageBox ("错误","数据查询操作失败!(请重试!)",Exclamation!,OK!)
	return 
end if
IF LS_LONG>0 THEN 
	MessageBox ("提示","该资料已经使用于销售订单,不可以删除!", Information!, OK! )
	RETURN
END IF

LS_LONG = 0
select COUNT(*) into :LS_LONG from u_outware 
where u_outware.relint_2=:LS_id
  and u_outware.billtype = 1;
if SQLCA.SQLCode<>0 and sqlca.sqlcode<>100  then 
	rollback;
	MessageBox ("错误","数据查询操作失败!(请重试!)",Exclamation!,OK!)
	return 
end if
IF LS_LONG>0 THEN 
	MessageBox ("提示","该资料已经使用于销售单,不可以删除!", Information!, OK! )
	RETURN
END IF

dw_uc.SetRedraw (false)
dw_UC.DeleteRow (0)
dw_UC.TriggerEvent (rowfocuschanged!)

if dw_UC.Update() = -1 then
	rollback;
	MessageBox ('提示',"删除记录操作失败!", Information!, OK! )
else
	commit;
end if
dw_uc.SetRedraw (true)
end event

type cb_choice from w_publ_edit_choice`cb_choice within w_currency_edit
boolean enabled = false
end type

event cb_choice::clicked;call super::clicked;Long ll_row

ll_row = dw_uc.GetRow()

IF ll_row <= 0 THEN
	messagebox('提示','请先选择目标行!', Information!, OK! )
	RETURN
END IF

INS_RT_STRU.moneyid = dw_uc.Object.moneyid[ll_row]
INS_RT_STRU.rate = dw_uc.Object.rate[ll_row]
INS_RT_STRU.name = dw_uc.Object.name[ll_row]

Close(Parent)
end event

type dw_uc from w_publ_edit_choice`dw_uc within w_currency_edit
integer width = 1792
integer height = 1360
string dataobject = "dw_currency_index"
end type

event dw_uc::doubleclicked;call super::doubleclicked;if cb_choice.Enabled then
	IF row <= 0 then return 
	cb_choice.triggerevent(clicked!)
end if
end event

type cb_rtr from w_publ_edit_choice`cb_rtr within w_currency_edit
end type

type cb_help from w_publ_edit_choice`cb_help within w_currency_edit
boolean visible = false
end type

type ln_bar from w_publ_edit_choice`ln_bar within w_currency_edit
integer endx = 1792
end type

type ln_bar2 from w_publ_edit_choice`ln_bar2 within w_currency_edit
integer endx = 1792
end type

type r_bar from w_publ_edit_choice`r_bar within w_currency_edit
end type

type cb_view from uo_imflatbutton within w_currency_edit
boolean visible = false
integer x = 837
integer width = 151
integer height = 164
integer taborder = 30
boolean bringtotop = true
string text = "预览"
string normalpicname = "preview.bmp"
integer picsize = 16
toolbaralignment pic_align = alignattop!
boolean border = false
end type

event clicked;call super::clicked;S_print_MSG LS_PRMSG

LS_PRMSG.obj_dwNAME = 'dw_rp_currency_index'
LS_PRMSG.SHARE_DW = DW_UC
LS_PRMSG.TAG_TEXT = parent.title
LS_PRMSG.SETUP_FLAG = 0
LS_PRMSG.PAGECH_FLAG = 1

OpenWithParm(w_publ_preview,LS_PRMSG)
end event