$PBExportHeader$w_aifmb_addcuscomm_request.srw
forward
global type w_aifmb_addcuscomm_request from window
end type
type cb_4 from commandbutton within w_aifmb_addcuscomm_request
end type
type cb_3 from commandbutton within w_aifmb_addcuscomm_request
end type
type cb_2 from commandbutton within w_aifmb_addcuscomm_request
end type
type cb_1 from commandbutton within w_aifmb_addcuscomm_request
end type
type dw_1 from u_dw_rbtnfilter within w_aifmb_addcuscomm_request
end type
end forward

global type w_aifmb_addcuscomm_request from window
integer width = 3214
integer height = 2028
windowtype windowtype = child!
long backcolor = 67108864
string icon = "AppIcon!"
boolean center = true
cb_4 cb_4
cb_3 cb_3
cb_2 cb_2
cb_1 cb_1
dw_1 dw_1
end type
global w_aifmb_addcuscomm_request w_aifmb_addcuscomm_request

on w_aifmb_addcuscomm_request.create
this.cb_4=create cb_4
this.cb_3=create cb_3
this.cb_2=create cb_2
this.cb_1=create cb_1
this.dw_1=create dw_1
this.Control[]={this.cb_4,&
this.cb_3,&
this.cb_2,&
this.cb_1,&
this.dw_1}
end on

on w_aifmb_addcuscomm_request.destroy
destroy(this.cb_4)
destroy(this.cb_3)
destroy(this.cb_2)
destroy(this.cb_1)
destroy(this.dw_1)
end on

event resize;
dw_1.Width = This.WorkSpaceWidth() - dw_1.X
dw_1.Height = This.WorkSpaceHeight() - dw_1.Y

end event

type cb_4 from commandbutton within w_aifmb_addcuscomm_request
integer x = 73
integer y = 16
integer width = 261
integer height = 100
integer taborder = 40
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
string text = "刷新"
end type

event clicked;Int rslt = 1
String arg_msg = ''

uo_aifmbproxy ll_proxyfactory
ll_proxyfactory = Create uo_aifmbproxy


Long ll_userid
SELECT top 1 userid
	INTO :ll_userid
	FROM LJFIEB_ComInfo
	Using sys_email_sqlca;
IF sys_email_sqlca.SQLCode <> 0 THEN
	rslt = 0
	arg_msg = '查询企业注册信息失败,' + sys_email_sqlca.SQLErrText
	GOTO ext
END IF

IF ll_userid <= 0 THEN
	rslt  = 0
	arg_msg = '企业未注册'
	GOTO ext
END IF

oleobject lo_proxy

IF ll_proxyfactory.getproxy(lo_proxy, arg_msg) <> 1 THEN
	rslt = 0
	GOTO ext
END IF

oleobject request
request = lo_proxy.NewGetAddCusCommRequest()

request.UserID = ll_userid

oleobject response
response = lo_proxy.GetAddCusComm(request)

IF Not IsNull(response.ErrMsg) THEN
	rslt = 0
	arg_msg = response.ErrMsg
	GOTO ext
END IF

Long ll_cnt
ll_cnt = response.Requests.Count

Long i, ll_row
oleobject lo_request, lo_ent
dw_1.Reset()
FOR i = 0 To ll_cnt - 1
	lo_request = response.Requests.GetItem(i)
	ll_row = dw_1.InsertRow(0)
	dw_1.Object.custype[ll_row] = lo_request.custype
	dw_1.Object.addtime[ll_row] = lo_request.addtime
	lo_ent = lo_request.Ent
	dw_1.Object.UserID[ll_row] = lo_ent.UserID
	dw_1.Object.CusID[ll_row] = lo_ent.CusID
	dw_1.Object.usercode[ll_row] = lo_ent.usercode
	dw_1.Object.username[ll_row] = lo_ent.username
	dw_1.Object.tele[ll_row] = lo_ent.tele
	dw_1.Object.phone[ll_row] = lo_ent.phone
	dw_1.Object.Address[ll_row] = lo_ent.Address
	dw_1.Object.email[ll_row] = lo_ent.email
	dw_1.Object.dscrp[ll_row] = lo_ent.dscrp
	dw_1.Object.comcode[ll_row] = lo_ent.comcode
NEXT

ext:
Destroy ll_proxyfactory
IF rslt = 0 THEN
	MessageBox('ERROR', arg_msg)
END IF


end event

type cb_3 from commandbutton within w_aifmb_addcuscomm_request
integer x = 951
integer y = 16
integer width = 261
integer height = 100
integer taborder = 30
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
string text = "退出"
end type

event clicked;close(parent)
end event

type cb_2 from commandbutton within w_aifmb_addcuscomm_request
integer x = 658
integer y = 16
integer width = 261
integer height = 100
integer taborder = 20
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
string text = "拒绝"
end type

type cb_1 from commandbutton within w_aifmb_addcuscomm_request
integer x = 366
integer y = 16
integer width = 261
integer height = 100
integer taborder = 10
integer textsize = -9
integer weight = 400
fontcharset fontcharset = gb2312charset!
fontpitch fontpitch = variable!
string facename = "宋体"
string text = "接受"
end type

event clicked;Int rslt = 1
String arg_msg

Long ll_row
ll_row = dw_1.GetRow()

IF ll_row <= 0 THEN
	MessageBox('提示', '请选择接受对象')
	RETURN
END IF

s_aifmb_addcuscomm s_parm
s_parm.cusid = dw_1.Object.cusid[ll_row]
s_parm.cuscode = dw_1.Object.usercode[ll_row]
s_parm.cusname = dw_1.Object.username[ll_row]
s_parm.lb_readonly = False

IF dw_1.Object.custype[ll_row] = 1 THEN // 供应商
	s_parm.custype = 2
ELSEIF dw_1.Object.custype[ll_row] = 2 THEN // 客户
	s_parm.custype = 1
ELSEIF dw_1.Object.custype[ll_row] = 3 THEN
	s_parm.custype = 3
END IF

IF s_parm.cusid = '' THEN
	MessageBox('提示', '对方唯一码为空不能添加')
	RETURN
END IF

IF s_parm.cusid = '00000000-0000-0000-0000-000000000000' THEN
	MessageBox('提示', '对方唯一码为零不能添加')
	RETURN
END IF

//查询是否已经绑定客户
Long ll_cnt
SELECT COUNT(0)
	INTO :ll_cnt
	FROM LJFIEB_CusComm
	WHERE CusID = :s_parm.cusid
	Using sys_email_sqlca;
IF sys_email_sqlca.SQLCode <> 0 THEN
	MessageBox('提示', '查询企业是否有本地信息失败,' + sys_email_sqlca.SQLErrText)
	RETURN
END IF

String ls_cuscode
String ls_cusname

IF ll_cnt > 0 THEN
	
	SELECT top 1 cuscode, cusname
		INTO :ls_cuscode, :ls_cusname
		FROM LJFIEB_CusComm
		WHERE CusID = :s_parm.cusid
		Using sys_email_sqlca;
	IF sys_email_sqlca.SQLCode <> 0 THEN
		MessageBox('提示', '查询本地企业信息失败,' + sys_email_sqlca.SQLErrText)
		RETURN
	END IF
	
	s_parm.cuscode = ls_cuscode
	s_parm.cusname = ls_cusname
	s_parm.lb_readonly = True
	
	IF s_parm.custype = 2 Or s_parm.custype = 3 THEN
		
		SELECT COUNT(0)
			INTO :ll_cnt
			FROM u_cust
			Where commcode = :ls_cuscode;
		IF sqlca.SQLCode <> 0 THEN
			MessageBox('提示', '查询已绑定客户个数失败,' + sys_email_sqlca.SQLErrText)
			RETURN
		END IF
		
		IF ll_cnt > 0 THEN
			IF MessageBox('提问', '本企业已经绑定了' + String(ll_cnt) + '个客户,是否继续?', Question!, YesNo!, 1) <> 1 THEN
				RETURN
			END IF
		END IF
		
	END IF
	
	IF s_parm.custype = 1 Or s_parm.custype = 3 THEN
		
		SELECT COUNT(0)
			INTO :ll_cnt
			FROM u_spt
			Where commcode = :ls_cuscode;
		IF sqlca.SQLCode <> 0 THEN
			MessageBox('提示', '查询已绑定供应商个数失败,' + sys_email_sqlca.SQLErrText)
			RETURN
		END IF
		
		IF ll_cnt > 0 THEN
			IF MessageBox('提问', '本企业已经绑定了' + String(ll_cnt) + '个供应商,是否继续?', Question!, YesNo!, 1) <> 1 THEN
				RETURN
			END IF
		END IF
		
	END IF
	
END IF

IF s_parm.custype = 2 Or s_parm.custype = 3 THEN
	
	s_custom s_cust
	s_cust.cuscode = dw_1.Object.usercode[ll_row]
	s_cust.Name = dw_1.Object.username[ll_row]
	s_cust.tele = dw_1.Object.tele[ll_row]
	s_cust.tele1 = dw_1.Object.phone[ll_row]
	s_cust.Address = dw_1.Object.Address[ll_row]
	s_cust.email = dw_1.Object.email[ll_row]
	s_cust.dscrp = dw_1.Object.dscrp[ll_row]
	
	s_edit_index_tran s_tran
	s_tran.if_retrieve_all = False //是否一次RETRIEVE所有行
	s_tran.work_mode = 1 //0-单纯编辑模式 1-选择\编辑模式
	s_tran.arg_pkid = 0 //目标定位PKID (备用)
	s_tran.e_long = 1
	s_tran.a_any = s_cust
	
	OpenWithParm(w_cust_edit, s_tran)
	
	s_custom S_INSCUST
	S_INSCUST = Message.PowerObjectParm //接受返回结构
	
	IF S_INSCUST.cusid <= 0 THEN RETURN
	
	s_parm.ll_cusid = S_INSCUST.cusid
	s_parm.ls_cuscode = S_INSCUST.cuscode
	s_parm.ls_cusname = S_INSCUST.Name
	
END IF

IF s_parm.custype = 1 Or s_parm.custype = 3 THEN
	
	s_spt s_spt_tran
	s_spt_tran.sptcode = dw_1.Object.usercode[ll_row]
	s_spt_tran.Name = dw_1.Object.username[ll_row]
	s_spt_tran.tele = dw_1.Object.tele[ll_row]
	s_spt_tran.tele1 = dw_1.Object.phone[ll_row]
	s_spt_tran.Address = dw_1.Object.Address[ll_row]
	s_spt_tran.email = dw_1.Object.email[ll_row]
	s_spt_tran.dscrp = dw_1.Object.dscrp[ll_row]
	
	s_edit_index_tran s_tran_spt
	s_tran_spt.if_retrieve_all = False //是否一次RETRIEVE所有行
	s_tran_spt.work_mode = 1 //0-单纯编辑模式 1-选择\编辑模式
	s_tran_spt.arg_pkid = 0 //目标定位PKID (备用)
	s_tran_spt.e_long = 1
	s_tran_spt.a_any = s_spt_tran
	
	OpenWithParm(w_spt_edit, s_tran_spt)
	
	s_spt S_INSSPT
	S_INSSPT = Message.PowerObjectParm //接受返回结构
	
	IF S_INSSPT.sptid <= 0 THEN RETURN
	
	s_parm.ll_sptid = S_INSSPT.sptid
	s_parm.ls_sptcode = S_INSSPT.sptcode
	s_parm.ls_sptname = S_INSSPT.Name
	
END IF

OpenWithParm(w_aifmb_addcuscomm_accept,s_parm)

end event

type dw_1 from u_dw_rbtnfilter within w_aifmb_addcuscomm_request
integer y = 140
integer width = 2638
integer height = 1732
string dataobject = "dw_aifmb_addcuscomm_request"
boolean hscrollbar = true
boolean vscrollbar = true
boolean hsplitscroll = true
boolean rbutton_filter_use = true
boolean rbutton_setposition_use = true
boolean titleclick_sort_use = true
end type

event clicked;call super::clicked;if row > 0 then
	this.setrow(row)
end if
end event

event rowfocuschanged;call super::rowfocuschanged;this.selectrow(0, false)
if currentrow > 0 then
	this.selectrow(currentrow,true)
end if
end event